PLAG_InCellTestRobust.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: Perform in cell test based on robust search algorithm
!
! Description: none.
!
! Input: 
!   region = data of current region
!   posPlag = particle position vector
!   indexCurr = indices for current cell
!        
! Output: indexNew = new cell index
!          cellLocate = logical variable set to TRUE if test successful
!
! Notes: 
!   1. compute distance between posPlag and face centroids
!       for dummy cells and take minimum distance
!   2. if such distance does not exist, search fails
!
!******************************************************************************
!
! $Id: PLAG_InCellTestRobust.F90,v 1.3 2008/12/06 08:44:33 mtcampbe Exp $
!
! Copyright: (c) 2004 by the University of Illinois
!
!******************************************************************************

SUBROUTINE plag_incelltestrobust( region, posPlag, indexCurr, &
                                  indexnew,celllocate )

  USE moddatatypes
  USE moddatastruct, ONLY : t_region
  USE modglobal, ONLY     : t_global
  USE modpartlag, ONLY    : t_plag
  USE moderror  
  USE modparameters
  
  USE modinterfaces, ONLY : rflo_getcelloffset, &
                            rflo_getnodeoffset, &
                            rflo_getdimensphys, &
                            rflo_getdimensphysnodes

  IMPLICIT NONE

#include "Indexing.h"

! *****************************************************************************
! Declarations
! *****************************************************************************

! =============================================================================  
! Arguments 
! =============================================================================  

  TYPE(t_region) :: region

  INTEGER,      DIMENSION(4), INTENT(IN ) :: indexcurr
  INTEGER,      DIMENSION(4), INTENT(OUT) :: indexnew
  
  LOGICAL,                    INTENT(OUT) :: celllocate  
  
  REAL(RFREAL), DIMENSION(3), INTENT(IN ) :: posplag  

! =============================================================================  
! Locals
! =============================================================================  

  CHARACTER(CHRLEN) :: rcsidentstring

  INTEGER :: i,icoff,ijcoff,ijkc,inoff,ijnoff,ijknr,ijknri,ijknrj,ijknrk,    &
             ilev,ipcbeg,ipcend,ipnbeg,ipnend,j,jpcbeg,jpcend,jpnbeg,jpnend, &
             k,kpcbeg,kpcend,kpnbeg,kpnend,nsearch
  INTEGER,      DIMENSION(4) :: indexsearch
  
  REAL(RFREAL)               :: distpos,distposmin
  REAL(RFREAL), DIMENSION(3) :: facecentroid
  
  REAL(RFREAL), POINTER, DIMENSION(:,:,:) :: pfc
  
  TYPE(t_global), POINTER :: global

! *****************************************************************************
! Start
! *****************************************************************************

  rcsidentstring = '$RCSfile: PLAG_InCellTestRobust.F90,v $ $Revision: 1.3 $'

  global => region%global
  
  CALL registerfunction( global, 'PLAG_InCellTestRobust',&
  'PLAG_InCellTestRobust.F90' )

! *****************************************************************************
! Set variables and pointers
! *****************************************************************************
    
  celllocate = .false.
  distposmin = huge(1.0_rfreal)
  nsearch    = 0
  indexnew(1:4) = crazy_value_int

  ilev = region%currLevel

  pfc => region%levels(ilev)%plag%fc

! *****************************************************************************
! Get extent of physical cells and nodes
! *****************************************************************************
   
  CALL rflo_getdimensphys( region,ilev,ipcbeg,ipcend,  &
                           jpcbeg,jpcend,kpcbeg,kpcend )
  CALL rflo_getcelloffset( region,ilev,icoff,ijcoff )
  CALL rflo_getnodeoffset( region,ilev,inoff,ijnoff )
  
  CALL rflo_getdimensphysnodes( region,ilev,ipnbeg,ipnend,  &
                                jpnbeg,jpnend,kpnbeg,kpnend )

! *****************************************************************************
! Load indices for nodes and cells
! *****************************************************************************
   
  i = indexcurr(2)
  j = indexcurr(3)
  k = indexcurr(4)
   
  ijknr  = indijk(i,  j  ,k  ,inoff,ijnoff)              
  ijknri = indijk(i+1,j  ,k  ,inoff,ijnoff)
  ijknrj = indijk(i,j+1  ,k  ,inoff,ijnoff)
  ijknrk = indijk(i  ,j  ,k+1,inoff,ijnoff)   

  ijkc   = indijk(i,j,k,icoff,ijcoff)

! *****************************************************************************
! Perform search for indices of dummy cells
! *****************************************************************************
   
  IF ( i-1 < ipcbeg ) THEN
    facecentroid(1:3) = pfc(xcoord:zcoord,icoord,ijknr)
    distpos = sum( (facecentroid(1:3)-posplag(1:3))**2 )

    IF ( distpos < distposmin ) THEN
      distposmin = distpos
      ijkc = indijk(i-1,j  ,k  ,icoff,ijcoff)
      indexsearch(1:4) = (/ijkc,i-1,j,k/)
      nsearch = nsearch+1
    ENDIF ! distPos 

  ENDIF ! i-1
  
  IF ( i+1 > ipcend ) THEN
    facecentroid(1:3) = pfc(xcoord:zcoord,icoord,ijknri)
    distpos = sum( (facecentroid(1:3)-posplag(1:3))**2 )

    IF ( distpos < distposmin ) THEN
      distposmin = distpos
      ijkc = indijk(i+1,j  ,k  ,icoff,ijcoff)
      indexsearch(1:4) = (/ijkc,i+1,j,k/)
      nsearch = nsearch+1
    ENDIF ! distPos 

  ENDIF ! i+1

  IF ( j-1 < jpcbeg ) THEN
    facecentroid(1:3) = pfc(xcoord:zcoord,jcoord,ijknr)
    distpos = sum( (facecentroid(1:3)-posplag(1:3))**2 )

    IF ( distpos < distposmin ) THEN
      distposmin = distpos
      ijkc = indijk(i  ,j-1,k  ,icoff,ijcoff)
      indexsearch(1:4) = (/ijkc,i,j-1,k/)
      nsearch = nsearch+1
    ENDIF ! distPos 

  ENDIF ! j-1
  
  IF ( j+1 >  jpcend ) THEN
    facecentroid(1:3) = pfc(xcoord:zcoord,jcoord,ijknrj)
    distpos = sum( (facecentroid(1:3)-posplag(1:3))**2 )

    IF ( distpos < distposmin ) THEN
      distposmin = distpos
      ijkc = indijk(i  ,j+1,k  ,icoff,ijcoff)
      indexsearch(1:4) = (/ijkc,i,j+1,k/)
      nsearch = nsearch+1
    ENDIF ! distPos 

  ENDIF ! j+1   

  IF ( k-1 < kpcbeg ) THEN
    facecentroid(1:3) = pfc(xcoord:zcoord,kcoord,ijknr)
    distpos = sum( (facecentroid(1:3)-posplag(1:3))**2 )

    IF ( distpos < distposmin ) THEN
      distposmin = distpos
      ijkc = indijk(i  ,j  ,k-1,icoff,ijcoff)
      indexsearch(1:4) = (/ijkc,i,j,k-1/)
      nsearch = nsearch+1
    ENDIF ! distPos 

  ENDIF ! k-1
  
  IF ( k+1 >  kpcend ) THEN
    facecentroid(1:3) = pfc(xcoord:zcoord,kcoord,ijknrk)
    distpos = sum( (facecentroid(1:3)-posplag(1:3))**2 )

    IF ( distpos < distposmin ) THEN
      distposmin = distpos
      ijkc = indijk(i  ,j  ,k+1,icoff,ijcoff)
      indexsearch(1:4) = (/ijkc,i,j,k+1/)
      nsearch = nsearch+1
    ENDIF ! distPos 

  ENDIF ! k+1   

  IF ( nsearch /= 0 ) THEN
    celllocate = .true.
    indexnew(1:4) = indexsearch(1:4)
  ENDIF ! nSearch

! *****************************************************************************
! End
! *****************************************************************************

999  CONTINUE
  CALL deregisterfunction( global )
 
END SUBROUTINE plag_incelltestrobust

!******************************************************************************
!
! RCS Revision history:
!
! $Log: PLAG_InCellTestRobust.F90,v $
! Revision 1.3  2008/12/06 08:44:33  mtcampbe
! Updated license.
!
! Revision 1.2  2008/11/19 22:17:46  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.1  2004/04/09 23:17:19  fnajjar
! Initial Import for robust cell search algorithm
!
!******************************************************************************