PLAG_CalcFaceCentroids.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: calculate face centroids.
!
! Description: none.
!
! Input: region = current region.
!
! Output: plag%fc = face centroids.
!
! Notes: face centroids are defined for dummy cells.
!
!******************************************************************************
!
! $Id: PLAG_CalcFaceCentroids.F90,v 1.3 2008/12/06 08:44:33 mtcampbe Exp $
!
! Copyright: (c) 2002 by the University of Illinois
!
!******************************************************************************

SUBROUTINE plag_calcfacecentroids( region )

  USE moddatatypes
  USE moddatastruct, ONLY : t_region
  USE modglobal, ONLY     : t_global
  USE modpartlag, ONLY    : t_plag
  USE modinterfaces, ONLY : rflo_getdimensdummynodes, &
                            rflo_getnodeoffset
  USE moderror
  USE modparameters
  IMPLICIT NONE

#define IndIJK(x,y,z,o1,o2) ((x) + ((y) -1)*o1 + ((z)-1)*o2)

! ... parameters
  TYPE(t_region) :: region

! ... loop variables
  INTEGER :: i, ilev, j, k

! ... local variables
  CHARACTER(CHRLEN) :: rcsidentstring

  INTEGER :: icoff, ijcoff, ijkc, idnbeg, idnend, inoff, ijnoff, ijkn, &
             jdnbeg, jdnend, kdnbeg, kdnend
  INTEGER, DIMENSION(4) :: corner
  
  REAL(RFREAL)          :: xyzquad(3,4)
  REAL(RFREAL), POINTER, DIMENSION(:,:)   :: xyz
  REAL(RFREAL), POINTER, DIMENSION(:,:,:) :: fc
  
  TYPE(t_global), POINTER :: global
  TYPE(t_plag),   POINTER :: pplag
  
!******************************************************************************

  rcsidentstring = '$RCSfile: PLAG_CalcFaceCentroids.F90,v $ $Revision: 1.3 $'

  global => region%global
  
  CALL registerfunction( global,'PLAG_CalcFaceCentroids',&
  'PLAG_CalcFaceCentroids.F90' )
    
! Loop over all grid levels ---------------------------------------------------

  DO ilev=1,region%nGridLevels
  
! - Get dimensions ------------------------------------------------------------

    CALL rflo_getdimensdummynodes( region,ilev,idnbeg,idnend, &
                                   jdnbeg,jdnend,kdnbeg,kdnend )
    CALL rflo_getnodeoffset( region,ilev,inoff,ijnoff )
    CALL rflo_getcelloffset( region,ilev,icoff,ijcoff )

! - Set pointers --------------------------------------------------------------

    pplag => region%levels(ilev)%plag
    xyz   => region%levels(ilev)%grid%xyz
    fc    => pplag%fc

! - i-direction ---------------------------------------------------------------

    DO k=kdnbeg,kdnend-1
      DO j=jdnbeg,jdnend-1
        DO i=idnbeg,idnend
          corner(1) = indijk(i,j  ,k  ,inoff,ijnoff)
          corner(2) = indijk(i,j  ,k+1,inoff,ijnoff)
          corner(3) = indijk(i,j+1,k+1,inoff,ijnoff)
          corner(4) = indijk(i,j+1,k  ,inoff,ijnoff)
          xyzquad(1:3,1) = xyz(1:3,corner(1))
          xyzquad(1:3,2) = xyz(1:3,corner(2))
          xyzquad(1:3,3) = xyz(1:3,corner(3))
          xyzquad(1:3,4) = xyz(1:3,corner(4))
          fc(1:3,icoord,corner(1)) = 0.25_rfreal*     &
                                    (xyzquad(1:3,1) + &
                                     xyzquad(1:3,2) + &
                                     xyzquad(1:3,3) + &
                                     xyzquad(1:3,4) )    
        ENDDO
      ENDDO
    ENDDO

! - j-direction ---------------------------------------------------------------

    DO k=kdnbeg,kdnend-1
      DO j=jdnbeg,jdnend
        DO i=idnbeg,idnend-1
          corner(1) = indijk(i  ,j,k  ,inoff,ijnoff)
          corner(2) = indijk(i+1,j,k  ,inoff,ijnoff)
          corner(3) = indijk(i+1,j,k+1,inoff,ijnoff)
          corner(4) = indijk(i  ,j,k+1,inoff,ijnoff)
          xyzquad(1:3,1) = xyz(1:3,corner(1))
          xyzquad(1:3,2) = xyz(1:3,corner(2))
          xyzquad(1:3,3) = xyz(1:3,corner(3))
          xyzquad(1:3,4) = xyz(1:3,corner(4))
          fc(1:3,jcoord,corner(1)) = 0.25_rfreal*     &
                                    (xyzquad(1:3,1) + &
                                     xyzquad(1:3,2) + &
                                     xyzquad(1:3,3) + &
                                     xyzquad(1:3,4) ) 
        ENDDO
      ENDDO
    ENDDO

! - k-direction ---------------------------------------------------------------

    DO k=kdnbeg,kdnend
      DO j=jdnbeg,jdnend-1
        DO i=idnbeg,idnend-1
          corner(1) = indijk(i  ,j  ,k,inoff,ijnoff)
          corner(2) = indijk(i  ,j+1,k,inoff,ijnoff)
          corner(3) = indijk(i+1,j+1,k,inoff,ijnoff)
          corner(4) = indijk(i+1,j  ,k,inoff,ijnoff)
          xyzquad(1:3,1) = xyz(1:3,corner(1))
          xyzquad(1:3,2) = xyz(1:3,corner(2))
          xyzquad(1:3,3) = xyz(1:3,corner(3))
          xyzquad(1:3,4) = xyz(1:3,corner(4))
          fc(1:3,kcoord,corner(1)) = 0.25_rfreal*     &
                                    (xyzquad(1:3,1) + &
                                     xyzquad(1:3,2) + &
                                     xyzquad(1:3,3) + &
                                     xyzquad(1:3,4) ) 
        ENDDO
      ENDDO
    ENDDO

  ENDDO   ! iLev

! finalize

  CALL deregisterfunction( global )

END SUBROUTINE plag_calcfacecentroids

!******************************************************************************
!
! RCS Revision history:
!
! $Log: PLAG_CalcFaceCentroids.F90,v $
! Revision 1.3  2008/12/06 08:44:33  mtcampbe
! Updated license.
!
! Revision 1.2  2008/11/19 22:17:45  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.1  2004/12/01 20:57:02  fnajjar
! Initial revision after changing case
!
! Revision 1.2  2003/05/02 20:10:55  fnajjar
! Redefined IndIJK based on cpp for performance speedup
!
! Revision 1.1  2002/10/25 14:14:44  f-najjar
! Initial Import of Rocpart
!
!
!******************************************************************************