PEUL_SourceEqEul.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: compute source terms associated with Equilibrium Eulerian method
!
! Description: none.
!
! Input: region = data of current region.
!
! Output: region%levels%peul%rhs = source terms.
!
! Notes: none.
!
!******************************************************************************
!
! $Id: PEUL_SourceEqEul.F90,v 1.3 2008/12/06 08:44:39 mtcampbe Exp $
!
! Copyright: (c) 2004 by the University of Illinois
!
!******************************************************************************

SUBROUTINE peul_sourceeqeul( region,ipt )

  USE moddatatypes
  USE moddatastruct, ONLY : t_region
  USE modglobal,     ONLY : t_global
  USE modparteul,    ONLY : t_peul_ptype
  USE moderror
  USE modparameters
  USE peul_modparameters

  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  TYPE(t_region), INTENT(INOUT) :: region
  INTEGER,        INTENT(IN)    :: ipt

! ... loop variables
  INTEGER :: ijkn,i,j,k

! ... local variables
  CHARACTER(CHRLEN) :: rcsidentstring

  INTEGER :: ilev,ibn,ien,errorflag,ic,ijknpi,ijknpj,ijknpk
  INTEGER :: ipcbeg,ipcend,jpcbeg,jpcend,kpcbeg,kpcend,icoff,ijcoff
  INTEGER :: idnbeg,idnend,jdnbeg,jdnend,kdnbeg,kdnend,inoff,ijnoff

  REAL(RFREAL) :: ux,uy,uz,vx,vy,vz,wx,wy,wz,taufac,mass,tau,trg2av

  REAL(RFREAL), POINTER,     DIMENSION(:,:) :: gtv,gradi,gradj,gradk,scv,srhs
  REAL(RFREAL), POINTER,     DIMENSION(:)   :: vol
  REAL(RFREAL), ALLOCATABLE, DIMENSION(:)   :: trg2i,trg2j,trg2k

  TYPE(t_peul_ptype), POINTER :: ptype
  TYPE(t_global),     POINTER :: global

!******************************************************************************

  rcsidentstring = '$RCSfile: PEUL_SourceEqEul.F90,v $ $Revision: 1.3 $'

  global => region%global

  CALL registerfunction( global,'PEUL_SourceEqEul',&
  'PEUL_SourceEqEul.F90' )

! begin -----------------------------------------------------------------------

  ilev = region%currLevel

  CALL rflo_getdimensphys( region,ilev,ipcbeg,ipcend, &
                           jpcbeg,jpcend,kpcbeg,kpcend )
  CALL rflo_getcelloffset( region,ilev,icoff,ijcoff )

  CALL rflo_getdimensdummynodes( region,ilev,idnbeg,idnend, &
                                 jdnbeg,jdnend,kdnbeg,kdnend )
  CALL rflo_getnodeoffset( region,ilev,inoff,ijnoff )
  ibn = indijk(idnbeg,jdnbeg,kdnbeg,inoff,ijnoff)
  ien = indijk(idnend,jdnend,kdnend,inoff,ijnoff)

  vol   => region%levels(ilev)%grid%vol

  gtv   => region%levels(ilev)%mixt%tv

  gradi => region%levels(ilev)%mixt%gradi
  gradj => region%levels(ilev)%mixt%gradj
  gradk => region%levels(ilev)%mixt%gradk

  scv   => region%levels(ilev)%peul%cv
  srhs  => region%levels(ilev)%peul%rhs

  ptype => region%peulInput%ptypes(ipt)

! allocate temporary arrays ---------------------------------------------------

  ALLOCATE( trg2i(ibn:ien),stat=errorflag )
  errorflag = global%error
  IF (global%error /= 0) CALL errorstop( global,err_allocate,__line__ )

  ALLOCATE( trg2j(ibn:ien),stat=errorflag )
  errorflag = global%error
  IF (global%error /= 0) CALL errorstop( global,err_allocate,__line__ )

  ALLOCATE( trg2k(ibn:ien),stat=errorflag )
  errorflag = global%error
  IF (global%error /= 0) CALL errorstop( global,err_allocate,__line__ )

  DO ijkn = ibn,ien

    ux  = gradi(gr_mixt_ux,ijkn)
    uy  = gradi(gr_mixt_uy,ijkn)
    uz  = gradi(gr_mixt_uz,ijkn)
    vx  = gradi(gr_mixt_vx,ijkn)
    vy  = gradi(gr_mixt_vy,ijkn)
    vz  = gradi(gr_mixt_vz,ijkn)
    wx  = gradi(gr_mixt_wx,ijkn)
    wy  = gradi(gr_mixt_wy,ijkn)
    wz  = gradi(gr_mixt_wz,ijkn)

    trg2i(ijkn) = ux**2 + vy**2 + wz**2 + 2._rfreal*(uy*vx + vz*wy + wx*uz)

    ux  = gradj(gr_mixt_ux,ijkn)
    uy  = gradj(gr_mixt_uy,ijkn)
    uz  = gradj(gr_mixt_uz,ijkn)
    vx  = gradj(gr_mixt_vx,ijkn)
    vy  = gradj(gr_mixt_vy,ijkn)
    vz  = gradj(gr_mixt_vz,ijkn)
    wx  = gradj(gr_mixt_wx,ijkn)
    wy  = gradj(gr_mixt_wy,ijkn)
    wz  = gradj(gr_mixt_wz,ijkn)

    trg2j(ijkn) = ux**2 + vy**2 + wz**2 + 2._rfreal*(uy*vx + vz*wy + wx*uz)

    ux  = gradk(gr_mixt_ux,ijkn)
    uy  = gradk(gr_mixt_uy,ijkn)
    uz  = gradk(gr_mixt_uz,ijkn)
    vx  = gradk(gr_mixt_vx,ijkn)
    vy  = gradk(gr_mixt_vy,ijkn)
    vz  = gradk(gr_mixt_vz,ijkn)
    wx  = gradk(gr_mixt_wx,ijkn)
    wy  = gradk(gr_mixt_wy,ijkn)
    wz  = gradk(gr_mixt_wz,ijkn)

    trg2k(ijkn) = ux**2 + vy**2 + wz**2 + 2._rfreal*(uy*vx + vz*wy + wx*uz)

  END DO ! ijkN

  taufac = ptype%tauVcoef

  DO k=kpcbeg,kpcend
    DO j=jpcbeg,jpcend
      DO i=ipcbeg,ipcend

        ic = indijk(i,j,k,icoff,ijcoff)
        mass = scv(ipt,ic)*vol(ic)

        IF (mass > 0._rfreal) THEN ! only effects positive masses

          tau = taufac / gtv(tv_mixt_muel,ic)

          ijkn   = indijk(i  ,j  ,k  ,inoff,ijnoff)
          ijknpi = indijk(i+1,j  ,k  ,inoff,ijnoff)
          ijknpj = indijk(i  ,j+1,k  ,inoff,ijnoff)
          ijknpk = indijk(i  ,j  ,k+1,inoff,ijnoff)

          trg2av = (trg2i(ijkn) + trg2i(ijknpi) + &
                    trg2j(ijkn) + trg2j(ijknpj) + &
                    trg2k(ijkn) + trg2k(ijknpk)) / 6._rfreal

          srhs(ipt,ic) = srhs(ipt,ic) - mass * tau * trg2av

        END IF ! mass

      END DO ! i
    END DO   ! j
  END DO     ! k

! Deallocate temporary array --------------------------------------------------

  DEALLOCATE( trg2i,stat=errorflag )
  global%error = errorflag
  IF (global%error /= 0) CALL errorstop( global,err_deallocate,__line__ )

  DEALLOCATE( trg2j,stat=errorflag )
  global%error = errorflag
  IF (global%error /= 0) CALL errorstop( global,err_deallocate,__line__ )

  DEALLOCATE( trg2k,stat=errorflag )
  global%error = errorflag
  IF (global%error /= 0) CALL errorstop( global,err_deallocate,__line__ )

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( global )

END SUBROUTINE peul_sourceeqeul

!******************************************************************************
!
! RCS Revision history:
!
! $Log: PEUL_SourceEqEul.F90,v $
! Revision 1.3  2008/12/06 08:44:39  mtcampbe
! Updated license.
!
! Revision 1.2  2008/11/19 22:17:52  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.1  2004/12/01 21:09:59  haselbac
! Initial revision after changing case
!
! Revision 1.1  2004/05/04 20:27:37  jferry
! Implemented equilibrium Eulerian method
!
!******************************************************************************