PEUL_ResidualSmoothing.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: conduct implicit residual smoothing (central form) for smoke.
!
! Description: none.
!
! Input: region = region data (residual, smoothing coeff., temporary array)
!
! Output: region%levels%peul%rhs = smoothed residual.
!
! Notes: none.
!
!******************************************************************************
!
! $Id: PEUL_ResidualSmoothing.F90,v 1.3 2008/12/06 08:44:39 mtcampbe Exp $
!
! Copyright: (c) 2002 by the University of Illinois
!
!******************************************************************************

SUBROUTINE peul_residualsmoothing( region ) ! PUBLIC

  USE moddatatypes
  USE moddatastruct, ONLY : t_region
  USE modglobal,     ONLY : t_global
  USE moderror
  USE modparameters
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  TYPE(t_region), INTENT(INOUT) :: region

! ... loop variables
  INTEGER :: i, j, k, icv

! ... local variables
  CHARACTER(CHRLEN) :: rcsidentstring

  INTEGER :: ipcbeg, ipcend, jpcbeg, jpcend, kpcbeg, kpcend
  INTEGER :: ilev, icoff, ijcoff, off1d, ijkc, ijkc1, ijdum, ijdum1
  INTEGER :: im1, jm1, km1, ip1, jp1, kp1, ncv

  REAL(RFREAL)          :: t
  REAL(RFREAL), POINTER :: rhs(:,:), epsirs(:,:), d(:)

  TYPE(t_global), POINTER :: global

!******************************************************************************

  rcsidentstring = '$RCSfile: PEUL_ResidualSmoothing.F90,v $ $Revision: 1.3 $'

  global => region%global

  CALL registerfunction( global,'PEUL_ResidualSmoothing',&
  'PEUL_ResidualSmoothing.F90' )

! begin -----------------------------------------------------------------------

! get dimensions and pointers

  ilev = region%currLevel

  CALL rflo_getdimensphys( region,ilev,ipcbeg,ipcend,jpcbeg,jpcend, &
                           kpcbeg,kpcend )
  CALL rflo_getcelloffset( region,ilev,icoff,ijcoff )

  epsirs => region%levels(ilev)%peul%epsIrs
  rhs    => region%levels(ilev)%peul%rhs
  d      => region%work1D

  ncv = region%levels(ilev)%peul%nCv

! solution of tridiagonal system in I-direction

  DO k=kpcbeg,kpcend

    i     = ipcbeg - 1
    off1d = ipcend + 1
    DO j=jpcbeg,jpcend
      ijdum    = indij(i,j,off1d) + 1
      d(ijdum) = 0._rfreal
    ENDDO

    DO i=ipcbeg,ipcend
      im1 = i - 1
      DO j=jpcbeg,jpcend
        ijkc     = indijk(i  ,j,k,icoff,ijcoff)
        ijkc1    = indijk(im1,j,k,icoff,ijcoff)
        ijdum    = indij(i  ,j,off1d) + 1
        ijdum1   = indij(im1,j,off1d) + 1
        t        = 1._rfreal/(1._rfreal+2._rfreal*epsirs(icoord,ijkc)- &
                              epsirs(icoord,ijkc)*d(ijdum1))
        d(ijdum) = t*epsirs(icoord,ijkc)

        DO icv=1,ncv
          rhs(icv,ijkc) = t*(rhs(icv,ijkc) + epsirs(icoord,ijkc)*rhs(icv,ijkc1))
        ENDDO

      ENDDO
    ENDDO

    DO i=ipcend-1,ipcbeg,-1
      ip1 = i + 1
      DO j=jpcbeg,jpcend
        ijkc  = indijk(i  ,j,k,icoff,ijcoff)
        ijkc1 = indijk(ip1,j,k,icoff,ijcoff)
        ijdum = indij(i,j,off1d) + 1

        DO icv=1,ncv
          rhs(icv,ijkc) = rhs(icv,ijkc) + d(ijdum)*rhs(icv,ijkc1)
        ENDDO

      ENDDO
    ENDDO

  ENDDO    ! k

! solution of tridiagonal system in J-direction

  DO k=kpcbeg,kpcend

    j     = jpcbeg - 1
    off1d = jpcend + 1
    DO i=ipcbeg,ipcend
      ijdum    = indij(j,i,off1d) + 1
      d(ijdum) = 0._rfreal
    ENDDO

    DO j=jpcbeg,jpcend
      jm1 = j - 1
      DO i=ipcbeg,ipcend
        ijkc     = indijk(i,j  ,k,icoff,ijcoff)
        ijkc1    = indijk(i,jm1,k,icoff,ijcoff)
        ijdum    = indij(j  ,i,off1d) + 1
        ijdum1   = indij(jm1,i,off1d) + 1
        t        = 1._rfreal/(1._rfreal+2._rfreal*epsirs(jcoord,ijkc)- &
                              epsirs(jcoord,ijkc)*d(ijdum1))
        d(ijdum) = t*epsirs(jcoord,ijkc)

        DO icv=1,ncv
          rhs(icv,ijkc) = t*(rhs(icv,ijkc) + epsirs(icoord,ijkc)*rhs(icv,ijkc1))
        ENDDO

      ENDDO
    ENDDO

    DO j=jpcend-1,jpcbeg,-1
      jp1 = j + 1
      DO i=ipcbeg,ipcend
        ijkc  = indijk(i,j  ,k,icoff,ijcoff)
        ijkc1 = indijk(i,jp1,k,icoff,ijcoff)
        ijdum = indij(j,i,off1d) + 1

        DO icv=1,ncv
          rhs(icv,ijkc) = rhs(icv,ijkc) + d(ijdum)*rhs(icv,ijkc1)
        ENDDO

      ENDDO
    ENDDO

  ENDDO    ! k

! solution of tridiagonal system in K-direction

  DO j=jpcbeg,jpcend

    k     = kpcbeg - 1
    off1d = kpcend + 1
    DO i=ipcbeg,ipcend
      ijdum    = indij(k,i,off1d) + 1
      d(ijdum) = 0._rfreal
    ENDDO

    DO k=kpcbeg,kpcend
      km1 = k - 1
      DO i=ipcbeg,ipcend
        ijkc     = indijk(i,j,k  ,icoff,ijcoff)
        ijkc1    = indijk(i,j,km1,icoff,ijcoff)
        ijdum    = indij(k  ,i,off1d) + 1
        ijdum1   = indij(km1,i,off1d) + 1
        t        = 1._rfreal/(1._rfreal+2._rfreal*epsirs(kcoord,ijkc)- &
                              epsirs(kcoord,ijkc)*d(ijdum1))
        d(ijdum) = t*epsirs(kcoord,ijkc)

        DO icv=1,ncv
          rhs(icv,ijkc) = t*(rhs(icv,ijkc) + epsirs(icoord,ijkc)*rhs(icv,ijkc1))
        ENDDO

      ENDDO
    ENDDO

    DO k=kpcend-1,kpcbeg,-1
      kp1 = k + 1
      DO i=ipcbeg,ipcend
        ijkc  = indijk(i,j,k  ,icoff,ijcoff)
        ijkc1 = indijk(i,j,kp1,icoff,ijcoff)
        ijdum = indij(k,i,off1d) + 1

        DO icv=1,ncv
          rhs(icv,ijkc) = rhs(icv,ijkc) + d(ijdum)*rhs(icv,ijkc1)
        ENDDO

      ENDDO
    ENDDO

  ENDDO    ! j

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( global )

END SUBROUTINE peul_residualsmoothing

!******************************************************************************
!
! RCS Revision history:
!
! $Log: PEUL_ResidualSmoothing.F90,v $
! Revision 1.3  2008/12/06 08:44:39  mtcampbe
! Updated license.
!
! Revision 1.2  2008/11/19 22:17:52  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.1  2004/12/01 21:09:54  haselbac
! Initial revision after changing case
!
! Revision 1.3  2003/05/15 02:57:05  jblazek
! Inlined index function.
!
! Revision 1.2  2003/04/09 15:12:04  jferry
! miscellaneous stylistic changes
!
! Revision 1.1  2003/02/11 22:52:51  jferry
! Initial import of Rocsmoke
!
!******************************************************************************