PEUL_ReadConPartSection.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: read in user input related to Eulerian particle module.
!
! Description: none.
!
! Input: user input file.
!
! Output: regions = PEUL information
!
! Notes:
!
!   Reads in Sc and vis2, even though these do not do anything
!
!******************************************************************************
!
! $Id: PEUL_ReadConPartSection.F90,v 1.3 2008/12/06 08:44:39 mtcampbe Exp $
!
! Copyright: (c) 2002 by the University of Illinois
!
!******************************************************************************

SUBROUTINE peul_readconpartsection( regions,nPtypes,brbeg,brend )

  USE moddatatypes
  USE moddatastruct, ONLY : t_region
  USE modglobal,     ONLY : t_global
  USE modparteul,    ONLY : t_peul_input
  USE moderror
  USE modparameters
  USE peul_modparameters

  USE modinterfaces, ONLY : readbothregionsection
  USE modinterfacesinteract, ONLY : inrt_setmaterial
  IMPLICIT NONE

! ... parameters
  TYPE(t_region), POINTER :: regions(:)
  INTEGER, INTENT(IN)     :: nptypes
  INTEGER, INTENT(OUT)    :: brbeg,brend

! ... loop  variables
  INTEGER :: ireg,iptype

! ... local variables
  INTEGER, PARAMETER :: nstrkeys_max = 5
  INTEGER, PARAMETER :: nkeys_max = 20

  CHARACTER(CHRLEN) :: rcsidentstring
  CHARACTER(20)     :: strkeys(nstrkeys_max),keys(nkeys_max)
  CHARACTER(CHRLEN) :: strvals(nstrkeys_max)

  INTEGER :: nkeys,nstrkeys,nptypesused,errorflag,readstatus
  INTEGER :: istrkeymaterial
  INTEGER :: ikeyused,ikeydiam,ikeypuff,ikeyinitc
  INTEGER :: ikeyschm,ikeyk2,ikeyinvk4,ikeysmoocf,ikeyconstinit
  INTEGER :: ikeynegreport,ikeyclipmodel,ikeymethodv

  LOGICAL :: strdefined(nstrkeys_max),defined(nkeys_max)

  REAL(RFREAL) :: vals(nkeys_max)

  TYPE(t_peul_input), POINTER :: input
  TYPE(t_global),     POINTER :: global

!******************************************************************************

  rcsidentstring = &
    '$RCSfile: PEUL_ReadConPartSection.F90,v $ $Revision: 1.3 $'

  global => regions(1)%global

  CALL registerfunction( global,'PEUL_ReadConPartSection',&
  'PEUL_ReadConPartSection.F90' )

! begin -----------------------------------------------------------------------

! define string keys

  istrkeymaterial = 1
  nstrkeys = 1

  IF (nstrkeys > nstrkeys_max) &
    CALL errorstop( global,err_exceeds_decl_mem,__line__ )

  strkeys(istrkeymaterial) = 'MATERIAL'

! define real keys

  ikeyused      =  1
  ikeydiam      =  2
  ikeypuff      =  3
  ikeyinitc     =  4
  ikeyschm      =  5
  ikeyk2        =  6
  ikeyinvk4     =  7
  ikeysmoocf    =  8
  ikeyconstinit =  9
  ikeynegreport = 10
  ikeyclipmodel = 11
  ikeymethodv   = 12
  nkeys         = 12

  IF (nkeys > nkeys_max) CALL errorstop( global,err_exceeds_decl_mem,__line__ )

  keys(ikeyused)      = 'USED'
  keys(ikeydiam)      = 'DIAM'
  keys(ikeypuff)      = 'PUFF'
  keys(ikeyinitc)     = 'INITC'
  keys(ikeyschm)      = 'SCHM'
  keys(ikeyk2)        = 'K2'
  keys(ikeyinvk4)     = '1/K4'
  keys(ikeysmoocf)    = 'SMOOCF'
  keys(ikeyconstinit) = 'CONSTINIT'
  keys(ikeynegreport) = 'NEGREPORT'
  keys(ikeyclipmodel) = 'CLIPMODEL'
  keys(ikeymethodv)   = 'METH_VEL'

! specify default values for keys

  vals                =  -1.0_rfreal   ! default value for undefined quantity
  vals(ikeyused)      =   1.0_rfreal   ! used by default CONPART section exists
  vals(ikeypuff)      =   1.0_rfreal   ! default for puff factor
  vals(ikeyinitc)     =   1.e-9_rfreal ! default for initial concentration
  vals(ikeyschm)      =   1.0_rfreal   ! default for Schmidt number
  vals(ikeyk2)        =   0.0_rfreal   ! default for k2
  vals(ikeyinvk4)     = 128.0_rfreal   ! default for 1/k4
  vals(ikeysmoocf)    =  -1.0_rfreal   ! default for residual smoothing (none)
  vals(ikeyconstinit) =   0.0_rfreal   ! default for constant init (.FALSE.)
  vals(ikeynegreport) =   0.0_rfreal   ! default for negativity report
  vals(ikeyclipmodel) =   0.0_rfreal   ! default for clipping model
  vals(ikeymethodv)   =   0.0_rfreal   ! default method (0: smoke = fluid vel)
  nptypesused = max(nptypes,1)         ! must be at least one particle type

! read smoke section from input file

  CALL readbothregionsection( global,if_input,nkeys,nstrkeys,keys,strkeys, &
                              vals,strvals,brbeg,brend,defined,strdefined )

  IF (nint(vals(ikeyused)) == 1) THEN
    readstatus = 1 ! read and used
  ELSE
    readstatus = 0 ! read and not used
  END IF ! iKeyUsed

  DO ireg = brbeg,brend

    input => regions(ireg)%peulInput

    IF (input%readStatus == -1) THEN
      input%readStatus = readstatus
    ELSE
      CALL errorstop( global,err_sec_read_twice,__line__ )
    ENDIF

    IF (input%readStatus == 0) cycle

! - allocate ptypes

    ALLOCATE( input%ptypes(nptypesused),stat=errorflag )
    global%error = errorflag
    IF (global%error /= 0) CALL errorstop( global,err_allocate,__line__ )

! - fill in input data

    input%nPtypes = nptypesused

    DO iptype=1,nptypesused
      nullify(input%ptypes(iptype)%material)
      IF (strdefined(istrkeymaterial)) THEN
        CALL inrt_setmaterial(global,input%ptypes(iptype)%material, &
                              strvals(istrkeymaterial))
      END IF ! strDefined
    END DO ! iPtype

    input%ptypes(:)%diam    = vals(ikeydiam)
    input%ptypes(:)%puff    = vals(ikeypuff)
    input%ptypes(:)%initc   = vals(ikeyinitc)
    input%ptypes(:)%Sc      = vals(ikeyschm)
    input%ptypes(:)%vis2    = vals(ikeyk2)
    input%ptypes(:)%vis4    = vals(ikeyinvk4) ! reciprocal taken in
                                              ! PEUL_DerivedInputValues
    input%smoocf            = vals(ikeysmoocf)
    input%constInit         = (nint(vals(ikeyconstinit)) == 1)
    input%ptypes(:)%negReport = nint(vals(ikeynegreport))
    input%ptypes(:)%clipModel = nint(vals(ikeyclipmodel))

    SELECT CASE (nint(vals(ikeynegreport)))
    CASE (0)
      input%ptypes(:)%negReport = peul_neg_report_none
    CASE (1)
      input%ptypes(:)%negReport = peul_neg_report_used
    CASE default
      CALL errorstop( global,err_peul_badval,__line__ )
    END SELECT ! vals(iKeyNegReport)

    SELECT CASE (nint(vals(ikeyclipmodel)))
    CASE (0)
      input%ptypes(:)%clipModel = peul_clip_model_none
    CASE (1)
      input%ptypes(:)%clipModel = peul_clip_model_used
    CASE default
      CALL errorstop( global,err_peul_badval,__line__ )
    END SELECT ! vals(iKeyClipModel)

    SELECT CASE (nint(vals(ikeymethodv)))
    CASE (0)
      input%ptypes(:)%methodV = peul_methv_fluidvel
    CASE (1)
      input%ptypes(:)%methodV = peul_methv_eqeul
    CASE default
      CALL errorstop( global,err_peul_badval,__line__ )
    END SELECT ! vals(iKeyMethodV)

  END DO ! iReg

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( global )

END SUBROUTINE peul_readconpartsection

!******************************************************************************
!
! RCS Revision history:
!
! $Log: PEUL_ReadConPartSection.F90,v $
! Revision 1.3  2008/12/06 08:44:39  mtcampbe
! Updated license.
!
! Revision 1.2  2008/11/19 22:17:51  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.1  2004/12/01 21:09:45  haselbac
! Initial revision after changing case
!
! Revision 1.11  2004/05/03 15:09:42  jferry
! added equilibrium Eulerian capability for smoke
!
! Revision 1.10  2004/03/05 22:09:04  jferry
! created global variables for peul, plag, and inrt use
!
! Revision 1.9  2004/03/02 21:44:52  jferry
! Added clipping options
!
! Revision 1.8  2003/09/26 21:49:06  fnajjar
! Changed interface call for INRT_SetMaterial to ModInterfacesInteract
!
! Revision 1.7  2003/04/14 16:33:52  jferry
! added option to initialize to constant for t > 0
!
! Revision 1.6  2003/04/07 18:29:01  jferry
! added inflow boundary condition and initialization to a constant
!
! Revision 1.5  2003/03/24 23:30:53  jferry
! overhauled rocinteract to allow interaction design to use user input
!
! Revision 1.4  2003/03/11 16:04:57  jferry
! Created data type for material properties
!
! Revision 1.3  2003/03/04 19:26:47  jferry
! Cleaned up routines that read sections of input files
!
! Revision 1.2  2003/02/12 23:34:48  jferry
! Replaced [io]stat=global%error with local errorFlag
!
! Revision 1.1  2003/02/11 22:52:51  jferry
! Initial import of Rocsmoke
!
!******************************************************************************