PEUL_ExchangeDummyConf.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: exchange values between interior and dummy cells of the
!          corresponding patches of the adjacent regions (both regions
!          are on the same processor) specific to PEUL Module.
!
! Description: none.
!
! Input: region    = current region
!        regionSrc = source region
!        patch     = current patch of region
!        patchSrc  = source patch of regionSrc.
!
! Output: regions%levels%peul%cv = eulerian particle variables in dummy cells.
!
! Notes: intended for conforming grid boundaries only.
!
!******************************************************************************
!
! $Id: PEUL_ExchangeDummyConf.F90,v 1.3 2008/12/06 08:44:39 mtcampbe Exp $
!
! Copyright: (c) 2003 by the University of Illinois
!
!******************************************************************************

SUBROUTINE peul_exchangedummyconf( region,regionSrc,patch,patchSrc )

  USE moddatatypes
  USE modbndpatch, ONLY   : t_patch
  USE moddatastruct, ONLY : t_region
  USE modglobal, ONLY     : t_global
  USE modindexing, ONLY   : indijkmap
  USE modinterfaces, ONLY : rflo_getpatchindices, rflo_getpatchdirection, &
        rflo_getcelloffset, rflo_getpatchmapping
  USE modparteul, ONLY    : t_peul
  USE moderror
  USE modparameters
  USE peul_modparameters
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  TYPE(t_region), INTENT(INOUT) :: region
  TYPE(t_region), INTENT(IN)    :: regionsrc
  TYPE(t_patch),  INTENT(INOUT) :: patch
  TYPE(t_patch),  INTENT(IN )   :: patchsrc

! ... loop variables
  INTEGER :: icv, idum, i, j, k, ii, jj, kk

! ... local variables
  CHARACTER(CHRLEN) :: rcsidentstring

  INTEGER :: ibeg, iend, jbeg, jend, kbeg, kend, idir, jdir, kdir, &
             icoff, ijcoff, ijkd, ilev
  INTEGER :: ibegsrc, iendsrc, jbegsrc, jendsrc, kbegsrc, kendsrc, &
             idirsrc, jdirsrc, kdirsrc, icoffsrc, ijcoffsrc, ijkcsrc
  INTEGER :: lb, lbs, l1srcdir, l2srcdir, mapmat(3,4)
  INTEGER :: ncv

  LOGICAL :: align

  REAL(RFREAL), POINTER, DIMENSION(:,:) :: pcv, pcvsrc

  TYPE(t_global), POINTER :: global

!******************************************************************************

  rcsidentstring = '$RCSfile: PEUL_ExchangeDummyConf.F90,v $ $Revision: 1.3 $'

  global => region%global

  CALL registerfunction( global,'PEUL_ExchangeDummyConf',&
  'PEUL_ExchangeDummyConf.F90' )

! check if the source region is active ----------------------------------------

  IF (regionsrc%active == off) THEN
    CALL errorstop( region%global,err_srcregion_off,__line__ )
  ENDIF

! get dimensions and pointers -------------------------------------------------

  ilev = region%currLevel

  CALL rflo_getpatchindices( region,patch,ilev,ibeg,iend, &
                             jbeg,jend,kbeg,kend )
  CALL rflo_getpatchindices( regionsrc,patchsrc,ilev,ibegsrc,iendsrc, &
                             jbegsrc,jendsrc,kbegsrc,kendsrc )
  CALL rflo_getpatchdirection( patch   ,idir   ,jdir,   kdir    )
  CALL rflo_getpatchdirection( patchsrc,idirsrc,jdirsrc,kdirsrc )
  CALL rflo_getcelloffset( region   ,ilev,icoff   ,ijcoff    )
  CALL rflo_getcelloffset( regionsrc,ilev,icoffsrc,ijcoffsrc )

  ncv  =  region%levels(ilev)%peul%nCv

  pcv    => region%levels(ilev)%peul%cv
  pcvsrc => regionsrc%levels(ilev)%peul%cv

! the implementation assumes that each cv is a smoke density, so check that
! nCv is indeed the number of smoke particle types

  IF (ncv /= region%peulInput%nPtypes) &
    CALL errorstop( region%global,err_peul_npmismatch,__line__ )

! mapping between patches -----------------------------------------------------

                                       l1srcdir =  1
  IF (patch%srcL1beg > patch%srcL1end) l1srcdir = -1
                                       l2srcdir =  1
  IF (patch%srcL2beg > patch%srcL2end) l2srcdir = -1

  lb    = patch%lbound
  lbs   = patch%srcLbound
  align = patch%align

  CALL rflo_getpatchmapping( lb,lbs,l1srcdir,l2srcdir,align, &
                             idir,jdir,kdir,idirsrc,jdirsrc,kdirsrc, &
                             ibeg,iend,jbeg,jend,kbeg,kend, &
                             ibegsrc,iendsrc,jbegsrc,jendsrc,kbegsrc,kendsrc, &
                             mapmat )

! loop over dummy nodes of current patch --------------------------------------

  DO icv=1,ncv
    DO idum=1,region%nDumCells
      DO k=kbeg,kend
        DO j=jbeg,jend
          DO i=ibeg,iend
            ii      = i - idum*idir
            jj      = j - idum*jdir
            kk      = k - idum*kdir
            ijkd    = indijk(ii,jj,kk,icoff,ijcoff)
            ijkcsrc = indijkmap(ii,jj,kk,mapmat,icoffsrc,ijcoffsrc)

            pcv(icv,ijkd) = pcvsrc(icv,ijkcsrc)
          ENDDO  ! i
        ENDDO    ! j
      ENDDO      ! k
    ENDDO        ! idum
  ENDDO          ! iCv

! finalize

  CALL deregisterfunction( global )

END SUBROUTINE peul_exchangedummyconf

!******************************************************************************
!
! RCS Revision history:
!
! $Log: PEUL_ExchangeDummyConf.F90,v $
! Revision 1.3  2008/12/06 08:44:39  mtcampbe
! Updated license.
!
! Revision 1.2  2008/11/19 22:17:51  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.1  2004/12/01 21:09:35  haselbac
! Initial revision after changing case
!
! Revision 1.3  2004/03/05 22:09:04  jferry
! created global variables for peul, plag, and inrt use
!
! Revision 1.2  2003/05/15 02:57:05  jblazek
! Inlined index function.
!
! Revision 1.1  2003/04/09 14:33:58  fnajjar
! Initial Import of Multi-region rocsmoke
!
!******************************************************************************