PEUL_CentralDissipation.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: compute artificial numerical dissipation for smoke.
!
! Description: the dissipation is 4th-order only, with no 2nd-order part
!
! Input: region = data of current region.
!
! Output: region%levels%peul%diss = dissipative fluxes.
!
! Notes: none.
!
!******************************************************************************
!
! $Id: PEUL_CentralDissipation.F90,v 1.3 2008/12/06 08:44:39 mtcampbe Exp $
!
! Copyright: (c) 2002 by the University of Illinois
!
!******************************************************************************

SUBROUTINE peul_centraldissipation( region ) ! PUBLIC

  USE moddatatypes
  USE moddatastruct, ONLY : t_region
  USE modglobal,     ONLY : t_global
  USE modinterfaces, ONLY : rflo_getdimensphys, rflo_getcelloffset
  USE moderror
  USE modparameters
  USE peul_modparameters
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  TYPE(t_region), INTENT(INOUT) :: region

! ... loop variables
  INTEGER :: i, j, k, ii, jj, kk, icv

! ... local variables
  INTEGER, PARAMETER :: npeul_max = 10

  CHARACTER(CHRLEN)  :: rcsidentstring

  INTEGER :: ipcbeg,ipcend,jpcbeg,jpcend,kpcbeg,kpcend
  INTEGER :: ncv,ilev,icoff,ijcoff,ijkc0,ijkcm1,ijkcp1,ijkcp2

  REAL(RFREAL) :: beta,eval,eps2,eps4,pmax,fd,vis4(npeul_max)
  REAL(RFREAL), POINTER :: scv(:,:),sdiss(:,:),srad(:,:)

  TYPE(t_global), POINTER :: global

!******************************************************************************

  rcsidentstring = '$RCSfile: PEUL_CentralDissipation.F90,v $ $Revision: 1.3 $'

  global => region%global

  CALL registerfunction( global,'PEUL_CentralDissipation',&
  'PEUL_CentralDissipation.F90' )

! begin -----------------------------------------------------------------------

! get dimensions and pointers -------------------------------------------------

  ilev = region%currLevel

  CALL rflo_getdimensphys( region,ilev,ipcbeg,ipcend, &
                           jpcbeg,jpcend,kpcbeg,kpcend )
  CALL rflo_getcelloffset( region,ilev,icoff,ijcoff )

  scv  => region%levels(ilev)%peul%cv
  ncv  =  region%levels(ilev)%peul%nCv

  sdiss => region%levels(ilev)%peul%diss
  srad => region%levels(ilev)%peul%srad

  beta =  region%mixtInput%betrk(region%irkStep)

! the implementation assumes that each sCv is a smoke density, so check that
! nCv is indeed the number of smoke particle types

  IF (ncv /= region%peulInput%nPtypes) &
    CALL errorstop( global,err_peul_npmismatch,__line__ )

  IF (ncv > npeul_max) &
    CALL errorstop( global,err_exceeds_decl_mem,__line__ )

  vis4(:)     = 0._rfreal
  vis4(1:ncv) = beta*region%peulInput%ptypes(1:ncv)%vis4

! dissipation in i-direction ------------------------------------------------

  DO k=kpcbeg,kpcend
    DO j=jpcbeg,jpcend

! --- dissipative fluxes at I+1/2

      ii = 0
      DO i=ipcbeg-1,ipcend
        ii     = ii + 1
        ijkc0  = indijk(i  ,j,k,icoff,ijcoff)
        ijkcm1 = indijk(i-1,j,k,icoff,ijcoff)
        ijkcp1 = indijk(i+1,j,k,icoff,ijcoff)
        ijkcp2 = indijk(i+2,j,k,icoff,ijcoff)
        eval   = 0.5_rfreal*(srad(icoord,ijkc0)+srad(icoord,ijkcp1) + &
                         max(srad(jcoord,ijkc0)+srad(jcoord,ijkcp1), &
                             srad(kcoord,ijkc0)+srad(kcoord,ijkcp1)))

        DO icv = 1,ncv
          eps4 = eval*vis4(icv)
          fd   = eps4*( (scv(icv,ijkcm1) - scv(icv,ijkcp2)) + &
              3._rfreal*(scv(icv,ijkcp1) - scv(icv,ijkc0 )) )

          sdiss(icv,ijkc0 ) = sdiss(icv,ijkc0 ) + fd
          sdiss(icv,ijkcp1) = sdiss(icv,ijkcp1) - fd
        ENDDO ! iCv

      ENDDO   ! i
    ENDDO     ! j
  ENDDO       ! k

! dissipation in j-direction ------------------------------------------------

  DO k=kpcbeg,kpcend
    DO i=ipcbeg,ipcend

! --- dissipative fluxes at J+1/2

      jj = 0
      DO j=jpcbeg-1,jpcend
        jj     = jj + 1
        ijkc0  = indijk(i,j  ,k,icoff,ijcoff)
        ijkcm1 = indijk(i,j-1,k,icoff,ijcoff)
        ijkcp1 = indijk(i,j+1,k,icoff,ijcoff)
        ijkcp2 = indijk(i,j+2,k,icoff,ijcoff)
        eval   = 0.5_rfreal*(srad(jcoord,ijkc0)+srad(jcoord,ijkcp1) + &
                         max(srad(icoord,ijkc0)+srad(icoord,ijkcp1), &
                             srad(kcoord,ijkc0)+srad(kcoord,ijkcp1)))

        DO icv = 1,ncv
          eps4 = eval*vis4(icv)
          fd   = eps4*( (scv(icv,ijkcm1) - scv(icv,ijkcp2)) + &
              3._rfreal*(scv(icv,ijkcp1) - scv(icv,ijkc0 )) )

          sdiss(icv,ijkc0 ) = sdiss(icv,ijkc0 ) + fd
          sdiss(icv,ijkcp1) = sdiss(icv,ijkcp1) - fd
        ENDDO ! iCv

      ENDDO   ! j
    ENDDO     ! i
  ENDDO       ! k

! dissipation in k-direction --------------------------------------------------

  DO j=jpcbeg,jpcend
    DO i=ipcbeg,ipcend

! --- dissipative fluxes at K+1/2

      kk = 0
      DO k=kpcbeg-1,kpcend
        kk     = kk + 1
        ijkc0  = indijk(i,j,k  ,icoff,ijcoff)
        ijkcm1 = indijk(i,j,k-1,icoff,ijcoff)
        ijkcp1 = indijk(i,j,k+1,icoff,ijcoff)
        ijkcp2 = indijk(i,j,k+2,icoff,ijcoff)
        eval   = 0.5_rfreal*(srad(kcoord,ijkc0)+srad(kcoord,ijkcp1) + &
                         max(srad(icoord,ijkc0)+srad(icoord,ijkcp1), &
                             srad(jcoord,ijkc0)+srad(jcoord,ijkcp1)))

        DO icv = 1,ncv
          eps4 = eval*vis4(icv)
          fd   = eps4*( (scv(icv,ijkcm1) - scv(icv,ijkcp2)) + &
              3._rfreal*(scv(icv,ijkcp1) - scv(icv,ijkc0 )) )

          sdiss(icv,ijkc0 ) = sdiss(icv,ijkc0 ) + fd
          sdiss(icv,ijkcp1) = sdiss(icv,ijkcp1) - fd
        ENDDO ! iCv

      ENDDO   ! k
    ENDDO     ! i
  ENDDO       ! j

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( global )

END SUBROUTINE peul_centraldissipation

!******************************************************************************
!
! RCS Revision history:
!
! $Log: PEUL_CentralDissipation.F90,v $
! Revision 1.3  2008/12/06 08:44:39  mtcampbe
! Updated license.
!
! Revision 1.2  2008/11/19 22:17:51  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.1  2004/12/01 21:09:25  haselbac
! Initial revision after changing case
!
! Revision 1.8  2004/07/28 15:42:13  jferry
! deleted defunct constructs: useDetangle, useSmokeDrag, useSmokeHeatTransfer
!
! Revision 1.7  2004/03/05 22:09:04  jferry
! created global variables for peul, plag, and inrt use
!
! Revision 1.6  2004/03/02 21:48:09  jferry
! First phase of replacing Detangle interaction
!
! Revision 1.5  2003/09/25 15:42:57  jferry
! Added mixture source terms due to active smoke (for Detangle interaction)
!
! Revision 1.4  2003/05/15 02:57:05  jblazek
! Inlined index function.
!
! Revision 1.3  2003/05/01 22:57:24  jferry
! substituted macro for IndIJK
!
! Revision 1.2  2003/04/09 15:12:04  jferry
! miscellaneous stylistic changes
!
! Revision 1.1  2003/02/11 22:52:50  jferry
! Initial import of Rocsmoke
!
!******************************************************************************