PEUL_BcondInjection.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: update values in dummy cells for smoke at injection boundary patch.
!
! Description: none.
!
! Input: region = region dimensions, user input
!        patch  = current patch.
!
! Output: region%levels%peul = smoke variables in dummy cells.
!
! Notes: if the mass flow rate is zero or negative, the corresponding
!        cell face is treated like solid wall.
!
!******************************************************************************
!
! $Id: PEUL_BcondInjection.F90,v 1.4 2008/12/06 08:44:38 mtcampbe Exp $
!
! Copyright: (c) 2002 by the University of Illinois
!
!******************************************************************************

SUBROUTINE peul_bcondinjection( region,patch )

  USE moddatatypes
  USE modbndpatch,   ONLY : t_patch
  USE moddatastruct, ONLY : t_region
  USE modglobal,     ONLY : t_global
  USE moderror
  USE modparameters
  USE peul_modparameters

  USE modinterfaces, ONLY : rflo_getpatchindices, rflo_getpatchdirection, &
                            rflo_getcelloffset
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  TYPE(t_region), INTENT(INOUT) :: region
  TYPE(t_patch),  INTENT(IN)    :: patch

! ... loop variables
  INTEGER :: idum, i, j, k, n1, n2

! ... local variables
  CHARACTER(CHRLEN) :: rcsidentstring

  INTEGER :: ibeg, iend, jbeg, jend, kbeg, kend, idir, jdir, kdir, ilev
  INTEGER :: icoff, ijcoff, noff, ijkc, ijkc1, ijkd, mixti2d, peuli2d
  INTEGER :: mixtdistrib, peuldistrib, dumextrapol, nptypes, lobound

  REAL(RFREAL) :: rhogas, mrate

  REAL(RFREAL), POINTER :: mixtcv(:,:), peulcv(:,:), vals(:,:)

  TYPE(t_global), POINTER :: global

!******************************************************************************

  rcsidentstring = '$RCSfile: PEUL_BcondInjection.F90,v $ $Revision: 1.4 $'

  global => region%global

  CALL registerfunction( global,'PEUL_BcondInjection',&
  'PEUL_BcondInjection.F90' )

! begin -----------------------------------------------------------------------

! get dimensions and pointers

  ilev   = region%currLevel
  lobound = patch%lbound

  CALL rflo_getpatchindices( region,patch,ilev, &
                             ibeg,iend,jbeg,jend,kbeg,kend )
  CALL rflo_getpatchdirection( patch,idir,jdir,kdir )
  CALL rflo_getcelloffset( region,ilev,icoff,ijcoff )

  noff        = abs(patch%l1end-patch%l1beg) + 1
  dumextrapol = patch%mixt%switches(bcswi_inject_extrap)
  mixtdistrib = patch%mixt%distrib
  peuldistrib = patch%peul%distrib

  mixtcv => region%levels(ilev)%mixt%cv
  peulcv => region%levels(ilev)%peul%cv
  vals   => patch%peul%vals

  nptypes = region%peulInput%nPtypes
  IF (region%levels(ilev)%peul%nCv /= nptypes) &
    CALL errorstop( global,err_peul_npmismatch,__line__ )
  IF (lbound(vals,1) /= 1 .OR. ubound(vals,1) /= nptypes) &
    CALL errorstop( global,err_peul_npmismatch,__line__ )

! loop over all cells of a patch

  DO idum=1,region%nDumCells
    DO k=kbeg,kend
      DO j=jbeg,jend
        DO i=ibeg,iend

          ijkc  = indijk(i-(idum-1)*idir,j-(idum-1)*jdir,k-(idum-1)*kdir,icoff,ijcoff)
          ijkc1 = indijk(i-(idum-2)*idir,j-(idum-2)*jdir,k-(idum-2)*kdir,icoff,ijcoff)
          ijkd  = indijk(i-idum*idir,j-idum*jdir,k-idum*kdir,icoff,ijcoff)

          SELECT CASE(lobound)
          CASE (1:2)
            n1 = j - jbeg
            n2 = k - kbeg
          CASE (3:4)
            n1 = k - kbeg
            n2 = i - ibeg
          CASE(5:6)
            n1 = i - ibeg
            n2 = j - jbeg
          END SELECT ! lobound

          mixti2d = mixtdistrib * indij(n1,n2,noff)
          peuli2d = peuldistrib * indij(n1,n2,noff)

          mrate   = vals(bcdat_inject_mfrate,mixti2d)

! ------- surface burning and 1st dummy cell

          IF (mrate>0._rfreal .AND. idum==1) THEN

            IF (dumextrapol == extrapol_const) THEN
              rhogas = mixtcv(cv_mixt_dens,ijkd)
              peulcv(:,ijkd) = rhogas*vals(:,peuli2d)

            ELSE
              rhogas = 0.5_rfreal*(mixtcv(cv_mixt_dens,ijkc) + &
                                   mixtcv(cv_mixt_dens,ijkd))
              peulcv(:,ijkd) = 2._rfreal*rhogas*vals(:,peuli2d) - peulcv(:,ijkc)
            END IF ! dumExtrapol

! ------- not burning or dummy cell>1

          ELSE ! treat like slip wall

            IF (dumextrapol == extrapol_const) THEN
              peulcv(:,ijkd) = peulcv(:,ijkc)
            ELSE
              peulcv(:,ijkd) = 2._rfreal*peulcv(:,ijkc) - peulcv(:,ijkc1)
            END IF ! dumExtrapol

          END IF ! mRate .AND. idum

        ENDDO  ! i
      ENDDO    ! j
    ENDDO      ! k
  ENDDO        ! idum

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( global )

END SUBROUTINE peul_bcondinjection

!******************************************************************************
!
! RCS Revision history:
!
! $Log: PEUL_BcondInjection.F90,v $
! Revision 1.4  2008/12/06 08:44:38  mtcampbe
! Updated license.
!
! Revision 1.3  2008/11/19 22:17:51  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.2  2006/08/19 15:40:18  mparmar
! Renamed patch variables
!
! Revision 1.1  2004/12/01 21:09:15  haselbac
! Initial revision after changing case
!
! Revision 1.3  2003/05/15 02:57:05  jblazek
! Inlined index function.
!
! Revision 1.2  2003/04/09 15:11:31  jferry
! removed dependence on temporary storage structures
!
! Revision 1.1  2003/02/11 22:52:50  jferry
! Initial import of Rocsmoke
!
!******************************************************************************