PERI_CnlForceTerm.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: add mean pressure gradient term to rhs
!
! Description: mean pressure gradient is added as source term of axial
!              momentum to force the flow and periodicity
!
! Input: region = data of current region.
!
! Output: region%levels%mixt%rhs = channel pressure gradient added to residual
!
! Notes: none.
!
!******************************************************************************
!
! $Id: PERI_CnlForceTerm.F90,v 1.5 2008/12/06 08:44:36 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************

SUBROUTINE peri_cnlforceterm( region )

  USE moddatatypes
  USE moddatastruct, ONLY : t_region
#ifdef RFLO
  USE modinterfaces, ONLY : rflo_getdimensphys, rflo_getcelloffset

#include "Indexing.h"
#endif
  USE moderror
  USE modparameters
  USE peri_modparameters
  IMPLICIT NONE

! ... parameters
  TYPE(t_region) :: region

! ... loop variables
  INTEGER :: i, j, k, ijkc0

! ... local variables
  CHARACTER(CHRLEN) :: rcsidentstring

#ifdef RFLO
  INTEGER :: ipcbeg, ipcend, jpcbeg, jpcend, kpcbeg, kpcend
  INTEGER :: ilev, icoff, ijcoff
  REAL(RFREAL), POINTER :: dv(:,:)
#endif
#ifdef RFLU
  REAL(RFREAL), POINTER :: cv(:,:)
#endif

  REAL(RFREAL), POINTER :: rhs(:,:), vol(:)
  REAL(RFREAL) :: refmeanpgrad

!******************************************************************************

  rcsidentstring = '$RCSfile: PERI_CnlForceTerm.F90,v $'

  CALL registerfunction( region%global,'PERI_CnlForceTerm',&
  'PERI_CnlForceTerm.F90' )

! get dimensions, pointers and parameters -------------------------------------

#ifdef RFLO
  ilev = region%currLevel

  CALL rflo_getdimensphys( region,ilev,ipcbeg,ipcend, &
                           jpcbeg,jpcend,kpcbeg,kpcend )
  CALL rflo_getcelloffset( region,ilev,icoff,ijcoff )

  dv   => region%levels(ilev)%mixt%dv
  rhs  => region%levels(ilev)%mixt%rhs
  vol  => region%levels(ilev)%grid%vol
#endif
#ifdef RFLU
  cv   => region%mixt%cv
  rhs  => region%mixt%rhs
  vol  => region%grid%vol
#endif

  refmeanpgrad = region%periInput%meanPgrad

#ifdef RFLO
  DO k = kpcbeg, kpcend
    DO j = jpcbeg, jpcend
      DO i = ipcbeg, ipcend
        ijkc0 = indijk(i ,j ,k ,icoff,ijcoff)
#endif
#ifdef RFLU
  DO ijkc0 = 1, region%grid%nCells
#endif
        rhs(cv_mixt_xmom,ijkc0) = rhs(cv_mixt_xmom,ijkc0) + vol(ijkc0)*refmeanpgrad
#ifdef RFLO
        rhs(cv_mixt_ener,ijkc0) = rhs(cv_mixt_ener,ijkc0) + &
                                  vol(ijkc0)*refmeanpgrad*dv(dv_mixt_uvel,ijkc0)
      ENDDO ! i
    ENDDO   ! j
  ENDDO     ! k
#endif
#ifdef RFLU
        rhs(cv_mixt_ener,ijkc0) = rhs(cv_mixt_ener,ijkc0) + vol(ijkc0)* &
                                  refmeanpgrad*cv(cv_mixt_xmom,ijkc0)/ &
                                  cv(cv_mixt_dens,ijkc0)
  ENDDO     ! ijkC0
#endif

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( region%global )

END SUBROUTINE peri_cnlforceterm

!******************************************************************************
!
! RCS Revision history:
!
! $Log: PERI_CnlForceTerm.F90,v $
! Revision 1.5  2008/12/06 08:44:36  mtcampbe
! Updated license.
!
! Revision 1.4  2008/11/19 22:17:49  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.3  2004/06/17 20:03:05  wasistho
! compiled with RFLU
!
! Revision 1.2  2004/06/11 21:49:40  wasistho
! prepared for RFLU
!
! Revision 1.1  2004/06/08 23:56:56  wasistho
! changed nomenclature
!
! Revision 1.3  2004/01/22 03:59:22  wasistho
! add dpdx*u1 to rhs(energy-eq.)
!
! Revision 1.2  2003/05/15 02:57:05  jblazek
! Inlined index function.
!
! Revision 1.1.1.1  2003/03/29 03:36:30  wasistho
! install ROCPERI
!
!******************************************************************************