INRT_VaporEnergyConversion.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: convert vapor energy of particles to gas energy
!
! Description: none.
!
! Input: region  = current region.
!
! Output: region%levels(iLev)%plag%cv
!         region%levels(iLev)%mixt%cv
!
! Notes:
!
!   Need to investigate release of energy into dummy cells
!
!******************************************************************************
!
! $Id: INRT_VaporEnergyConversion.F90,v 1.4 2008/12/06 08:44:32 mtcampbe Exp $
!
! Copyright: (c) 2004 by the University of Illinois
!
!******************************************************************************

SUBROUTINE inrt_vaporenergyconversion( region )

  USE moddatatypes
  USE moddatastruct, ONLY : t_region
  USE modglobal,     ONLY : t_global
  USE modmixture,    ONLY : t_mixt
  USE modpartlag,    ONLY : t_plag
  USE modinteract,   ONLY : t_inrt_interact
  USE moderror
  USE modparameters
  USE inrt_modparameters

#ifdef PLAG
  USE plag_modparameters
#endif

#ifdef RFLO
  USE modinterfaces, ONLY: rflo_getdimensdummy,rflo_getcelloffset

#include "Indexing.h"
#endif

  USE modinterfaces, ONLY: mixtperf_g_cpr, mixtperf_r_m, mixtureproperties
  IMPLICIT NONE

! ... parameters
  TYPE(t_region), INTENT(INOUT), TARGET :: region

! ... loop variables
  INTEGER :: ipcls, ic

! ... local variables
  CHARACTER(CHRLEN) :: rcsidentstring

#ifdef RFLO
  INTEGER :: idcbeg, idcend, jdcbeg, jdcend, kdcbeg, kdcend
  INTEGER :: ilev, icoff, ijcoff
#endif
  INTEGER :: indplagvapor, errorflag, ibc, iec, indcp, indmol, npcls, icell

  INTEGER, POINTER, DIMENSION(:,:) :: pplagaiv

  REAL(RFREAL) :: releasetemp, gastemp, keepfrac, rgas, gamma, hcap, deltaener

  REAL(RFREAL), POINTER, DIMENSION(:)   :: vol
  REAL(RFREAL), POINTER, DIMENSION(:,:) :: pmixtcv, pmixtdv, pmixtgv
  REAL(RFREAL), POINTER, DIMENSION(:,:) :: pplagcv, pplagarv

  REAL(RFREAL), ALLOCATABLE :: vaportot(:)

  TYPE(t_inrt_interact), POINTER :: pinrtburn
  TYPE(t_mixt),          POINTER :: pmixt
  TYPE(t_plag),          POINTER :: pplag
  TYPE(t_global),        POINTER :: global

!******************************************************************************

  rcsidentstring = &
    '$RCSfile: INRT_VaporEnergyConversion.F90,v $ $Revision: 1.4 $'

  global => region%global

  CALL registerfunction( global,'INRT_VaporEnergyConversion',&
  'INRT_VaporEnergyConversion.F90' )

#ifdef PLAG
! begin -----------------------------------------------------------------------

#ifdef RFLO
  ilev = region%currLevel
  CALL rflo_getdimensdummy( region,ilev,idcbeg,idcend, &
                            jdcbeg,jdcend,kdcbeg,kdcend )
  CALL rflo_getcelloffset( region,ilev,icoff,ijcoff )

  ibc = indijk(idcbeg,jdcbeg,kdcbeg,icoff,ijcoff)
  iec = indijk(idcend,jdcend,kdcend,icoff,ijcoff)
  pmixt => region%levels(ilev)%mixt
  pplag => region%levels(ilev)%plag
  vol   => region%levels(ilev)%grid%vol
  indcp  = pmixt%indCp
  indmol = pmixt%indMol
#endif

#ifdef RFLU
  ibc = 1
  iec = region%grid%nCellsTot
  pmixt => region%mixt
  pplag => region%plag
  vol   => region%grid%vol
  indcp  = region%mixtInput%indCp
  indmol = region%mixtInput%indMol
#endif

! Check if there are any particles --------------------------------------------

  npcls = 0
  IF (global%plagUsed) npcls = pplag%nPcls

  IF (npcls < 1) go to 9

! Check if particle vapor energy is active ------------------------------------

  indplagvapor = region%inrtInput%indPlagVapor
  IF (region%inrtInput%globActiveness(indplagvapor) /= inrt_act_active) go to 9

! Set pointers and values -----------------------------------------------------

  pmixtcv  => pmixt%cv
  pmixtdv  => pmixt%dv
  pmixtgv  => pmixt%gv

  pplagcv  => pplag%cv
  pplagaiv => pplag%aiv
  pplagarv => pplag%arv

  pinrtburn => region%inrtInput%inrts(inrt_type_burning)

! temperature below which to release vapor energy, which is set to be the same
! as the temperature above which burning shunts energy to vapor

  releasetemp = pinrtburn%data(inrt_dat_burning_vapor_temp)

  IF (releasetemp < 500._rfreal .OR. releasetemp > 10000._rfreal) THEN
    CALL errorstop( global,err_inrt_badval,__line__ )
  END IF ! releaseTemp

! need mixture temperature and spht, so compute all dv and gv for mixture

  IF ( region%mixtInput%gasModel == gas_model_tcperf ) THEN ! cp, Mol=const.
    CALL mixtureproperties(region,ibc,iec,.false.)
  ELSE
    CALL mixtureproperties(region,ibc,iec,.true.)
  END IF ! region%mixtInput%gasModel

! allocate and zero temporary array -------------------------------------------

  ALLOCATE( vaportot(ibc:iec),stat=errorflag )
  errorflag = global%error
  IF (global%error /= 0) CALL errorstop( global,err_allocate,__line__ )

  vaportot(:) = 0._rfreal

! sum up vapor energy in cells ------------------------------------------------

  DO ipcls = 1,npcls

    icell = pplagaiv(aiv_plag_icells,ipcls)

    vaportot(icell) = vaportot(icell) + pplagcv( cv_plag_enervapor,ipcls) * &
                                        pplagarv(arv_plag_spload,  ipcls)
  END DO ! iPcls

  DO ic = ibc,iec

    keepfrac = -1._rfreal
    gastemp  = pmixtdv(dv_mixt_temp,ic)

    IF (vaportot(ic) > 0._rfreal .AND. gastemp < releasetemp) THEN

! --- normalize vaporTot by cell volume

! --- Note: normalization is necessary because cv values are not per volume
! --- for particles, but are per volume for continuua, in contrast to rhs
! --- values, which are not per unit volume either for particles or continuua.

      vaportot(ic) = vaportot(ic) / vol(ic)

! --- Compute heat capacity of gas (this is based on how revision 1.12 of
! --- perfgasDependentVars.F90 computes these quantities)

      rgas  = mixtperf_r_m(  pmixtgv(gv_mixt_mol,ic*indmol))
      gamma = mixtperf_g_cpr(pmixtgv(gv_mixt_cp, ic*indcp ),rgas)

      hcap  = (rgas/(gamma - 1._rfreal)) * pmixtcv(cv_mixt_dens,ic)

! --- Compute difference between current energy and that which would
! --- result from raising the gas temperature to releaseTemp

      deltaener = hcap*(releasetemp - gastemp)

! --- Augment gas energy

      IF (vaportot(ic) > deltaener) THEN

        pmixtcv(cv_mixt_ener,ic) = pmixtcv(cv_mixt_ener,ic) + deltaener

        keepfrac = 1._rfreal - deltaener / vaportot(ic)

      ELSE

        pmixtcv(cv_mixt_ener,ic) = pmixtcv(cv_mixt_ener,ic) + vaportot(ic)

        keepfrac = 0._rfreal

      END IF ! vaporTot(ic) > deltaEner

    ELSE

      keepfrac = 1._rfreal

    END IF ! vaporTot(ic) > 0._RFREAL .AND. gasTemp < releaseTemp

    IF (keepfrac < 0._rfreal .OR. keepfrac > 1._rfreal) THEN
      CALL errorstop( global,err_invalid_value,__line__ )
    END IF ! keepFrac

! - save value of keepFrac in the vaporTot array

    vaportot(ic) = keepfrac

  END DO ! ic

! Loop over all the particles -------------------------------------------------

  DO ipcls = 1,npcls

    icell = pplagaiv(aiv_plag_icells,ipcls)

    pplagcv(cv_plag_enervapor,ipcls) = pplagcv(cv_plag_enervapor,ipcls) * &
                                       vaportot(icell)
  END DO ! iPcls

! Deallocate temporary array --------------------------------------------------

  DEALLOCATE( vaportot,stat=errorflag )
  global%error = errorflag
  IF (global%error /= 0) CALL errorstop( global,err_deallocate,__line__ )

! finalize --------------------------------------------------------------------

9 CONTINUE
#endif
  CALL deregisterfunction( global )

END SUBROUTINE inrt_vaporenergyconversion

!******************************************************************************
!
! RCS Revision history:
!
! $Log: INRT_VaporEnergyConversion.F90,v $
! Revision 1.4  2008/12/06 08:44:32  mtcampbe
! Updated license.
!
! Revision 1.3  2008/11/19 22:17:44  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.2  2005/10/31 21:09:37  haselbac
! Changed specModel and SPEC_MODEL_NONE
!
! Revision 1.1  2004/12/01 21:56:49  fnajjar
! Initial revision after changing case
!
! Revision 1.3  2004/03/25 21:15:33  jferry
! added MixtureProperties to ModInterfaces list
!
! Revision 1.2  2004/03/05 22:09:03  jferry
! created global variables for peul, plag, and inrt use
!
! Revision 1.1  2004/03/02 21:47:29  jferry
! Added After Update interactions
!
!******************************************************************************