INRT_TwoDimAverage.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: Average the cv variables for fluid and smoke in some direction
!
! Description: none.
!
! Input: region = data of current region.
!
! Output: region%levels%mixt%cv
!         region%levels%peul%cv
!         region%levels%plag%cv
!
! Notes: none.
!
!******************************************************************************
!
! $Id: INRT_TwoDimAverage.F90,v 1.4 2008/12/06 08:44:32 mtcampbe Exp $
!
! Copyright: (c) 2004 by the University of Illinois
!
!******************************************************************************

SUBROUTINE inrt_twodimaverage( region )

  USE moddatatypes
  USE moddatastruct, ONLY : t_region
  USE modglobal,     ONLY : t_global
  USE moderror
  USE modparameters
  USE inrt_modparameters
#ifdef PLAG
  USE plag_modparameters
#endif

  USE modinterfaces, ONLY : rflo_getdimensphys, rflo_getcelloffset
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  TYPE(t_region), INTENT(INOUT) :: region

! ... loop variables
  INTEGER :: i,j,k,ipcls

! ... local variables
  CHARACTER(CHRLEN) :: rcsidentstring

  INTEGER :: ipcbeg,ipcend,jpcbeg,jpcend,kpcbeg,kpcend
  INTEGER :: ilev,icoff,ijcoff,ijkc0
  INTEGER :: npcls

  REAL(RFREAL), POINTER, DIMENSION(:,:) :: mixtcv,peulcv,plagcv

  TYPE(t_global), POINTER :: global

!******************************************************************************

  rcsidentstring = '$RCSfile: INRT_TwoDimAverage.F90,v $ $Revision: 1.4 $'

  global => region%global

  CALL registerfunction( global,'INRT_TwoDimAverage',&
  'INRT_TwoDimAverage.F90' )

! begin -----------------------------------------------------------------------

! get dimensions and pointers -------------------------------------------------

  ilev = region%currLevel

  CALL rflo_getdimensphys( region,ilev,ipcbeg,ipcend, &
                           jpcbeg,jpcend,kpcbeg,kpcend )
  CALL rflo_getcelloffset( region,ilev,icoff,ijcoff )

  mixtcv => region%levels(ilev)%mixt%cv
#ifdef PEUL
  peulcv => region%levels(ilev)%peul%cv
#endif
#ifdef PLAG
  plagcv => region%levels(ilev)%plag%cv
#endif

  SELECT CASE (region%inrtInput%twoDAverage)

  CASE (0)
    CONTINUE ! do not average

  CASE (1)

! - zero z-momentum of gas ----------------------------------------------------

    DO k=kpcbeg,kpcend
      DO j=jpcbeg,jpcend
        DO i=ipcbeg,ipcend

          ijkc0 = indijk(i,j,k,icoff,ijcoff)
          mixtcv(cv_mixt_zmom,ijkc0) = 0._rfreal

        END DO   ! i
      END DO     ! j
    END DO       ! k

! - zero z-momentum of Lagrangian particles -----------------------------------

#ifdef PLAG
    npcls = 0
    IF (global%plagUsed) npcls = region%levels(ilev)%plag%nPcls
    IF (npcls > 0) THEN

      DO ipcls = 1,npcls
        plagcv(cv_plag_zmom,ipcls) = 0._rfreal
      END DO ! iPcls

    END IF ! nPcls
#endif

    CALL k_average(mixtcv,cv_mixt_neqs)

#ifdef PEUL
    IF (global%peulUsed) THEN
      CALL k_average(peulcv,region%levels(ilev)%peul%nCv)
    END IF ! peulUsed
#endif

  CASE default
    CALL errorstop(global,err_reached_default,__line__)

  END SELECT ! twoDAverage

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( global )

CONTAINS

! average in k-direction ------------------------------------------------------

  SUBROUTINE k_average(cv,nCv)

    REAL(RFREAL), POINTER    :: cv(:,:)
    INTEGER,      INTENT(IN) :: ncv

    INTEGER      :: icv
    REAL(RFREAL) :: csum,vsum
    REAL(RFREAL), POINTER :: vol(:)

    vol => region%levels(ilev)%grid%vol

    DO j=jpcbeg,jpcend
      DO i=ipcbeg,ipcend
        DO icv = 1,ncv

          csum = 0._rfreal
          vsum = 0._rfreal
          DO k=kpcbeg,kpcend
            ijkc0 = indijk(i,j,k,icoff,ijcoff)
            csum = csum + vol(ijkc0) * cv(icv,ijkc0)
            vsum = vsum + vol(ijkc0)
          END DO ! k
          csum = csum / vsum

          DO k=kpcbeg,kpcend
            ijkc0 = indijk(i,j,k,icoff,ijcoff)
            cv(icv,ijkc0) = csum
          END DO ! k

        END DO   ! iCv
      END DO     ! i
    END DO       ! j

  END SUBROUTINE k_average

END SUBROUTINE inrt_twodimaverage

!******************************************************************************
!
! RCS Revision history:
!
! $Log: INRT_TwoDimAverage.F90,v $
! Revision 1.4  2008/12/06 08:44:32  mtcampbe
! Updated license.
!
! Revision 1.3  2008/11/19 22:17:44  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.2  2006/02/15 20:17:03  wasistho
! put peul and plag within ifdef
!
! Revision 1.1  2004/12/01 21:56:47  fnajjar
! Initial revision after changing case
!
! Revision 1.2  2004/03/05 22:09:03  jferry
! created global variables for peul, plag, and inrt use
!
! Revision 1.1  2004/03/02 21:47:29  jferry
! Added After Update interactions
!
!******************************************************************************