INRT_ReadMaterialInput.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
! *****************************************************************************
!
! Purpose: Read in user input related to physical materials.
!
! Description: None.
!
! Input: 
!   global      Pointer to global data
!
! Output: None.
!
! Notes: None.
!
! *****************************************************************************
!
! $Id: INRT_ReadMaterialInput.F90,v 1.5 2008/12/06 08:44:32 mtcampbe Exp $
!
! Copyright: (c) 2003-2005 by the University of Illinois
!
! *****************************************************************************

SUBROUTINE inrt_readmaterialinput(global)

  USE moddatatypes
  USE modglobal, ONLY: t_global
  USE modmaterials
  USE moderror
  USE modparameters

  USE modbuildfilenames, ONLY: buildfilenameplain
    
  USE modinterfaces, ONLY: readbothsection

  IMPLICIT NONE

! ******************************************************************************
! Declarations and definitions
! ******************************************************************************

! ==============================================================================
! Arguments
! ==============================================================================

  TYPE(t_global), POINTER :: global

! ==============================================================================
! Locals
! ==============================================================================

  INTEGER, PARAMETER :: nstrkeys_max = 5
  INTEGER, PARAMETER :: nkeys_max = 20
  LOGICAL :: strdefined(nstrkeys_max),defined(nkeys_max)
  CHARACTER(20) :: strkeys(nstrkeys_max),keys(nkeys_max)
  CHARACTER(256) :: line  
  CHARACTER(CHRLEN) :: rcsidentstring,strvals(nstrkeys_max)
  CHARACTER(CHRLEN) :: fname
  INTEGER :: errorflag,nmat,ikeymolw,ikeydens,ikeyspht,ikeysurftens, &
             ikeytboil,ikeytmelt,imat,ipass,istrkeyname,istrkeyphase, &
             nstrkeys,nkeys
  REAL(RFREAL) :: vals(nkeys_max)
  TYPE(t_material), POINTER :: material

! ******************************************************************************
! Start
! ******************************************************************************

  rcsidentstring = '$RCSfile: INRT_ReadMaterialInput.F90,v $ $Revision: 1.5 $'

  CALL registerfunction( global,'INRT_ReadMaterialInput',&
  'INRT_ReadMaterialInput.F90' )

! ******************************************************************************
! Define keys for string-valued quantities
! ******************************************************************************

  istrkeyname  = 1
  istrkeyphase = 2
  nstrkeys     = 2

  IF ( nstrkeys > nstrkeys_max ) THEN
    CALL errorstop(global,err_exceeds_decl_mem,__line__)
  END IF ! nStrKeys

  strkeys(istrkeyname)  = 'NAME'
  strkeys(istrkeyphase) = 'PHASE'

! ******************************************************************************
! Define keys for real-valued quantities
! ******************************************************************************

  ikeymolw     = 1
  ikeydens     = 2
  ikeyspht     = 3
  ikeysurftens = 4
  ikeytboil    = 5
  ikeytmelt    = 6
  nkeys        = 6

  IF ( nkeys > nkeys_max ) THEN 
    CALL errorstop(global,err_exceeds_decl_mem,__line__)
  END IF ! nKeys

  keys(ikeymolw)     = 'MOLW'
  keys(ikeydens)     = 'DENS'
  keys(ikeyspht)     = 'SPHT'
  keys(ikeysurftens) = 'SURFTENS'
  keys(ikeytboil)    = 'TBOIL'
  keys(ikeytmelt)    = 'TMELT'

! ******************************************************************************
! Search for MATERIAL sections
! ******************************************************************************

  CALL buildfilenameplain(global,filedest_indir,'.inp',fname)

  DO ipass = 1,2

! ==============================================================================
!   Open file
! ==============================================================================

    OPEN(if_input,file=trim(fname),form='FORMATTED',status='OLD', &
         iostat=errorflag)
    global%error = errorflag
    IF ( global%error /= err_none ) THEN
      CALL errorstop(global,err_file_open,__line__,'File: '//trim(fname))
    END IF ! global%error

! ==============================================================================
!   Read file looking for keywords
! ==============================================================================

    SELECT CASE ( ipass )

! -----------------------------------------------------------------------------
!     First pass: Count number of material sections and allocate materials
! -----------------------------------------------------------------------------

      CASE ( 1 ) 
        nmat = 0 ! initialize count of materials

        DO
          READ(if_input,'(A256)',err=10,end=86) line
          IF ( trim(line) == '# MATERIAL' ) THEN 
            nmat = nmat + 1
          END IF ! TRIM
        END DO ! <empty>

86      CONTINUE

        IF ( nmat > 0 ) THEN
          ALLOCATE(global%materials(nmat),stat=errorflag)
          global%error = errorflag
          IF ( global%error /= err_none ) THEN
            CALL errorstop(global,err_allocate,__line__)
          END IF ! global%error
        ELSE 
          nullify(global%materials)
        END IF ! nMat

        global%nMaterials = nmat

! -----------------------------------------------------------------------------
!     Second pass: Search for real- and string-valued keys
! -----------------------------------------------------------------------------

      CASE ( 2 ) 
        imat = 0 ! initialize index of materials

        DO
          READ(if_input,'(A256)',err=10,end=87) line
          
          IF ( trim(line) == '# MATERIAL' ) THEN
            imat = imat + 1
            material => global%materials(imat)

! --------- Set values to indicate the status of undefined --------------------

            material%molw     = -1.0_rfreal
            material%dens     = -1.0_rfreal
            material%spht     = -1.0_rfreal
            material%surftens = -1.0_rfreal
            material%Tboil    = -1.0_rfreal
            material%Tmelt    = -1.0_rfreal
            material%Phase    = -1

! --------- Read real- and string-valued keys ---------------------------------

            CALL readbothsection(global,if_input,nkeys,nstrkeys,keys, &
                                 strkeys,vals,strvals,defined,strdefined)

! --------- ensure that material is named -------------------------------------

            IF ( strdefined(istrkeyname) .EQV. .true. ) THEN
              material%name = trim(strvals(istrkeyname))
            ELSE
              CALL errorstop(global,err_val_undefined,__line__)
            END IF ! strDefined(iStrKeyName)

! --------- Set material phase ------------------------------------------------

            IF ( strdefined(istrkeyphase) .EQV. .true. ) THEN                                              
              SELECT CASE ( strvals(istrkeyphase)(1:1) )
                CASE ( 'G','g' )
                  material%phase = 1
                CASE ( 'L','l' )
                  material%phase = 2
                CASE ( 'S','s' )
                  material%phase = 3
                CASE default
                  CALL errorstop(global,err_reached_default,__line__)
                END SELECT ! strVals
            END IF ! strDefined

! --------- Set material index to iMat (its index in global%materials(:)) -----

            material%index = imat

! --------- Set real-valued quantities ----------------------------------------

            IF ( defined(ikeymolw) .EQV. .true. ) THEN 
              material%molw = vals(ikeymolw)
            ELSE 
              CALL errorstop(global,err_val_undefined,__line__,'MOLW')
            END IF ! defined(iKeyMolw)

            IF ( defined(ikeydens) .EQV. .true. ) THEN 
              material%dens = vals(ikeydens)
            ELSE 
              IF ( material%phase /= 1 ) THEN 
                CALL errorstop(global,err_val_undefined,__line__,'DENS')
              END IF ! material%phase
            END IF ! defined(iKeyDens)

            IF ( defined(ikeyspht) .EQV. .true. ) THEN
              material%spht = vals(ikeyspht)
            ELSE
              CALL errorstop(global,err_val_undefined,__line__,'SPHT')
            END IF ! defined(iKeySpht)

            IF ( defined(ikeysurftens) .EQV. .true. ) THEN 
              material%surftens = vals(ikeysurftens)
            END IF ! defined(iKeySurfTens)

            IF ( defined(ikeytboil) .EQV. .true. ) THEN
              material%Tboil = vals(ikeytboil)
            END IF ! defined(iKeyTboil)

            IF ( defined(ikeytmelt) .EQV. .true. ) THEN
              material%Tmelt = vals(ikeytmelt)
            END IF ! defined(iKeyTmelt)
          END IF ! line
        END DO ! <empty>

87      CONTINUE

! -----------------------------------------------------------------------------
!     Default
! -----------------------------------------------------------------------------

      CASE default
        CALL errorstop(global,err_reached_default,__line__)
    END SELECT ! iPass

! ==============================================================================
!   Close file
! ==============================================================================

    CLOSE(if_input,iostat=errorflag)
    global%error = errorflag
    IF ( global%error /=  err_none ) THEN
      CALL errorstop(global,err_file_close,__line__,'File: '//trim(fname))
    END IF ! global%error
  END DO ! iPass

! ******************************************************************************
! End
! ******************************************************************************

  CALL deregisterfunction(global)
  
  goto 999

10   CONTINUE
  CALL errorstop(global,err_file_read,__line__,'File: '//trim(fname))

999  CONTINUE

END SUBROUTINE inrt_readmaterialinput

! *****************************************************************************
!
! RCS Revision history:
!
! $Log: INRT_ReadMaterialInput.F90,v $
! Revision 1.5  2008/12/06 08:44:32  mtcampbe
! Updated license.
!
! Revision 1.4  2008/11/19 22:17:44  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.3  2005/11/14 17:01:44  haselbac
! Added check for DENS, clean-up
!
! Revision 1.2  2005/11/10 02:32:35  haselbac
! Clean-up
!
! Revision 1.1  2004/12/01 21:56:39  fnajjar
! Initial revision after changing case
!
! Revision 1.6  2004/07/27 21:28:32  jferry
! minor bug fix
!
! Revision 1.5  2004/07/23 22:43:17  jferry
! Integrated rocspecies into rocinteract
!
! Revision 1.4  2004/04/15 16:04:21  jferry
! minor formatting (removed trailing spaces)
!
! Revision 1.3  2004/03/02 21:49:46  jferry
! Added melting and boiling point to material definitions
!
! Revision 1.2  2003/09/13 20:17:31  fnajjar
! Added surface tension to Materials datastructure
!
! Revision 1.1  2003/03/24 23:23:25  jferry
! converted from libfloflu routine to rocinteract routine
!
! *****************************************************************************