INRT_ReadHeatTransferNonBurn.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: Reads in information related to the interaction HeatTransferNonBurn
!
! Description: none.
!
! Input: regions = data of all regions
!
! Output: fills user data into region%inrtInput%inrts
!
! Notes: none.
!
!******************************************************************************
!
! $Id: INRT_ReadHeatTransferNonBurn.F90,v 1.3 2008/12/06 08:44:32 mtcampbe Exp $
!
! Copyright: (c) 2003 by the University of Illinois
!
!******************************************************************************

SUBROUTINE inrt_readheattransfernonburn( regions )

  USE moddatatypes
  USE moddatastruct, ONLY : t_region
  USE modglobal,     ONLY : t_global
  USE modinteract,   ONLY : t_inrt_input,t_inrt_interact
  USE moderror
  USE modparameters
  USE inrt_modparameters

#ifdef RFLO
  USE modinterfaces,      ONLY : readregionsection
#endif
#ifdef RFLU
  USE modinterfaces,      ONLY : readsection
#endif
  USE inrt_modinterfaces, ONLY : inrt_setactiveness,inrt_setpermission, &
                                 inrt_determinetokens, &
                                 inrt_defineheattransfernonburn
  IMPLICIT NONE

! ... parameters
  TYPE(t_region), POINTER :: regions(:)

! ... loop variables
  INTEGER :: ireg,iplag

! ... local variables
  INTEGER, PARAMETER :: nkeys_max = 20

  CHARACTER(CHRLEN)  :: rcsidentstring
  CHARACTER(CHRLEN)  :: keys(nkeys_max)

  INTEGER :: brbeg,brend,nedges
  INTEGER :: nplag
  INTEGER :: nimplkeys,nnodekeys,nkeys
  INTEGER :: ind,indmixt,indplag0
  INTEGER :: ikeyused,ikeymodel,ikeynode0
  INTEGER :: ikeymixtactv,ikeyplagactv,ikeymixtperm,ikeyplagperm

  LOGICAL :: defined(nkeys_max)

  REAL(RFREAL) :: vals(nkeys_max)

  TYPE(t_inrt_input),    POINTER :: input
  TYPE(t_inrt_interact), POINTER :: inrt
  TYPE(t_global),        POINTER :: global

!******************************************************************************

  rcsidentstring = &
    '$RCSfile: INRT_ReadHeatTransferNonBurn.F90,v $ $Revision: 1.3 $'

  global => regions(1)%global

  CALL registerfunction( global,'INRT_ReadHeatTransferNonBurn',&
  'INRT_ReadHeatTransferNonBurn.F90' )

! begin -----------------------------------------------------------------------

! define implementation-dependent keys

  ikeyused  = 1
  ikeymodel = 2
  nimplkeys = 2

  keys(ikeyused)  = 'USED'
  keys(ikeymodel) = 'MODEL'

! define Node keys

  ikeynode0 = nimplkeys
  ikeymixtactv = ikeynode0 + 1
  ikeyplagactv = ikeynode0 + 2
  ikeymixtperm = ikeynode0 + 3
  ikeyplagperm = ikeynode0 + 4
  nnodekeys = 4

  keys(ikeymixtactv) = 'MIXT_ACTV'
  keys(ikeyplagactv) = 'PLAG_ACTV'
  keys(ikeymixtperm) = 'MIXT_PERM'
  keys(ikeyplagperm) = 'PLAG_PERM'

  nkeys = ikeynode0 + nnodekeys

  IF (nkeys > nkeys_max) CALL errorstop( global,err_exceeds_decl_mem,__line__ )

! Read interaction section from input file

#ifdef RFLO
  CALL readregionsection( global,if_input,nkeys,keys,vals,brbeg,brend,defined )
#endif
#ifdef RFLU
  CALL readsection( global,if_input,nkeys,keys,vals,defined )
  brbeg = lbound(regions,1)
  brend = ubound(regions,1)
#endif

  DO ireg=brbeg,brend

    input => regions(ireg)%inrtInput
    inrt  => input%inrts(inrt_type_htransnb)

! - Check that INRT_DEFAULT section has been read, and that interaction has not

    IF (.NOT. input%defaultRead) &
      CALL errorstop( global,err_inrt_defunread,__line__ )

    IF (inrt%used) CALL errorstop( global,err_inrt_read,__line__ )

! - Use local variables for some useful quantities

    nplag = input%nPlag

    indmixt  = input%indMixt
    indplag0 = input%indPlag0

! - Check if interaction is used

    inrt%used = .true. ! used by default when its section appears

    IF (defined(ikeyused)) THEN
      IF (nint(vals(ikeyused)) == 0) inrt%used = .false.
    END IF ! defined(iKeyUsed)

    IF (nplag < 1) inrt%used = .false. ! cannot occur without particles

    IF (.NOT. inrt%used) cycle ! do not bother with unused interactions

! - Define interaction (using any relevant information from input deck)

    CALL inrt_defineheattransfernonburn(regions(ireg))

! - Check for switches

    inrt%switches(inrt_swi_htransnb_model) = inrt_htransnb_model_default

    IF (defined(ikeymodel)) THEN

      SELECT CASE (nint(vals(ikeymodel)))

      CASE (1)
        inrt%switches(inrt_swi_htransnb_model) = inrt_htransnb_model_stokes

      CASE (2)
        inrt%switches(inrt_swi_htransnb_model) = inrt_htransnb_model_rm

      CASE default
        CALL errorstop( global,err_inrt_badswitch,__line__ )

      END SELECT ! vals(iKeyModel)

    END IF ! defined(iKeyModel)

! - Check for Mixture controls

    IF (defined(ikeymixtactv)) &
      CALL inrt_setactiveness(global,vals(ikeymixtactv), &
                              inrt%activeness(indmixt))

    IF (defined(ikeymixtperm)) &
      CALL inrt_setpermission(global,vals(ikeymixtperm), &
                              inrt%permission(indmixt))

! - Check for Lagrangian particle controls

    DO iplag=1,nplag+1

      ind = indplag0 + iplag

      IF (defined(ikeyplagactv)) &
        CALL inrt_setactiveness(global,vals(ikeyplagactv), &
                                inrt%activeness(ind))

      IF (defined(ikeyplagperm)) &
        CALL inrt_setpermission(global,vals(ikeyplagperm), &
                                inrt%permission(ind))

    END DO ! iPlag

! - Determine permission Tokens

    CALL inrt_determinetokens(regions(ireg),inrt)

  END DO ! iReg

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( global )

END SUBROUTINE inrt_readheattransfernonburn

!******************************************************************************
!
! RCS Revision history:
!
! $Log: INRT_ReadHeatTransferNonBurn.F90,v $
! Revision 1.3  2008/12/06 08:44:32  mtcampbe
! Updated license.
!
! Revision 1.2  2008/11/19 22:17:44  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.1  2004/12/01 21:56:36  fnajjar
! Initial revision after changing case
!
! Revision 1.7  2004/07/23 22:43:16  jferry
! Integrated rocspecies into rocinteract
!
! Revision 1.6  2004/03/05 22:09:03  jferry
! created global variables for peul, plag, and inrt use
!
! Revision 1.5  2004/03/02 21:49:22  jferry
! Added inrtUsed flag to mixture data structure
!
! Revision 1.4  2003/04/02 22:32:04  jferry
! codified Activeness and Permission structures for rocinteract
!
! Revision 1.3  2003/03/24 23:30:52  jferry
! overhauled rocinteract to allow interaction design to use user input
!
! Revision 1.2  2003/03/11 16:09:39  jferry
! Added comments
!
! Revision 1.1  2003/03/04 22:12:35  jferry
! Initial import of Rocinteract
!
!******************************************************************************