INRT_ReadDefaultSection.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: Reads in default information for all interactions
!
! Description: none.
!
! Input: regions = data of all regions
!
! Output: fills user data into region%inrtInput
!
! Notes: none.
!
!******************************************************************************
!
! $Id: INRT_ReadDefaultSection.F90,v 1.3 2008/12/06 08:44:31 mtcampbe Exp $
!
! Copyright: (c) 2003 by the University of Illinois
!
!******************************************************************************

SUBROUTINE inrt_readdefaultsection( regions )

  USE moddatatypes
  USE moddatastruct, ONLY : t_region
  USE modglobal,     ONLY : t_global
  USE modinteract,   ONLY : t_inrt_input
  USE moderror
  USE modparameters
  USE inrt_modparameters

#ifdef RFLO
  USE modinterfaces,      ONLY : readregionsection
#endif
#ifdef RFLU
  USE modinterfaces,      ONLY : readsection
#endif
  USE modinterfaces,      ONLY : makenumberedkeys
  USE inrt_modinterfaces, ONLY : inrt_setactiveness,inrt_setpermission
  IMPLICIT NONE

! ... parameters
  TYPE(t_region), POINTER :: regions(:)

! ... loop variables
  INTEGER :: ireg,iplag,ipeul,iinrt

! ... local variables
  INTEGER, PARAMETER :: nkeys_max = 30
  INTEGER, PARAMETER :: npeul_max = 10

  CHARACTER(CHRLEN)  :: rcsidentstring
  CHARACTER(CHRLEN)  :: keys(nkeys_max)

  INTEGER :: brbeg,brend
  INTEGER :: nplag,npeul
  INTEGER :: nfixedkeys,nkeys
  INTEGER :: ind,indmixt,indplag0,indpeul0
  INTEGER :: ikey,ikeymixtactv,ikeyplagactv,ikeymixtperm,ikeyplagperm
  INTEGER :: ikeycomputeaux,ikeytwodaverage
  INTEGER :: ikeyactv,ikeyperm,ikeypeulactv0,ikeypeulperm0

  LOGICAL :: defined(nkeys_max)

  REAL(RFREAL) :: vals(nkeys_max)

  TYPE(t_inrt_input), POINTER :: input
  TYPE(t_global),     POINTER :: global

!******************************************************************************

  rcsidentstring = &
    '$RCSfile: INRT_ReadDefaultSection.F90,v $ $Revision: 1.3 $'

  global => regions(1)%global

  CALL registerfunction( global,'INRT_ReadDefaultSection',&
  'INRT_ReadDefaultSection.F90' )

! begin -----------------------------------------------------------------------

! define Node keys and other fixed keys

  ikeycomputeaux  = 1
  ikeytwodaverage = 2
  ikeymixtactv    = 3
  ikeyplagactv    = 4
  ikeymixtperm    = 5
  ikeyplagperm    = 6
  nfixedkeys = 6

  keys(ikeycomputeaux)  = 'COMPUTE_AUX'
  keys(ikeytwodaverage) = '2D_AVERAGE'
  keys(ikeymixtactv) = 'MIXT_ACTV'
  keys(ikeyplagactv) = 'PLAG_ACTV'
  keys(ikeymixtperm) = 'MIXT_PERM'
  keys(ikeyplagperm) = 'PLAG_PERM'

  ikeypeulactv0 = nfixedkeys
  ikeypeulperm0 = ikeypeulactv0 + npeul_max

#ifdef RFLO
  CALL makenumberedkeys(keys,ikeypeulactv0+1,'PEUL',1,npeul_max,1)
  CALL makenumberedkeys(keys,ikeypeulperm0+1,'PEUL',1,npeul_max,1)
#endif
#ifdef RFLU
  CALL makenumberedkeys(keys,ikeypeulactv0+1,'SPEC',1,npeul_max,1)
  CALL makenumberedkeys(keys,ikeypeulperm0+1,'SPEC',1,npeul_max,1)
#endif

  DO ipeul=1,npeul_max
    keys(ikeypeulactv0+ipeul) = trim(keys(ikeypeulactv0+ipeul))//'_ACTV'
    keys(ikeypeulperm0+ipeul) = trim(keys(ikeypeulperm0+ipeul))//'_PERM'
  END DO ! iPeul

  nkeys = ikeypeulperm0 + npeul_max

  IF (nkeys > nkeys_max) CALL errorstop( global,err_exceeds_decl_mem,__line__ )

! Read default section from input file

#ifdef RFLO
  CALL readregionsection( global,if_input,nkeys,keys,vals,brbeg,brend,defined )
#endif
#ifdef RFLU
  CALL readsection( global,if_input,nkeys,keys,vals,defined )
  brbeg = lbound(regions,1)
  brend = ubound(regions,1)
#endif

  DO ireg=brbeg,brend

    input => regions(ireg)%inrtInput

    IF (input%defaultRead) &
      CALL errorstop( global,err_inrt_defread,__line__ )

    input%defaultRead = .true.

    nplag = input%nPlag
    npeul = input%nPeul
    IF (npeul > npeul_max) &
      CALL errorstop( global,err_exceeds_decl_mem,__line__ )

    input%computeAux = .true.

    IF (defined(ikeycomputeaux)) THEN

      SELECT CASE ( nint(vals(ikeycomputeaux)) )

      CASE (0)
        input%computeAux = .false.

      CASE (1)
        input%computeAux = .true.

      CASE default
        CALL errorstop( global,err_inrt_badswitch,__line__ )

      END SELECT ! iKeyComputeAux

    END IF ! iKeyComputeAux

    input%twoDAverage = 0

    IF (defined(ikeytwodaverage)) THEN

      SELECT CASE ( nint(vals(ikeytwodaverage)) )

      CASE (0:1)
        input%twoDAverage = nint(vals(ikeytwodaverage))

      CASE default
        CALL errorstop( global,err_inrt_badswitch,__line__ )

      END SELECT ! iKeyTwoDAverage

    END IF ! iKeyTwoDAverage

! - Indices for Nodes

    indmixt  = input%indMixt
    indplag0 = input%indPlag0
    indpeul0 = input%indPeul0

! - Check for Mixture controls

    IF (defined(ikeymixtactv)) &
      CALL inrt_setactiveness(global,vals(ikeymixtactv), &
                              input%globActiveness(indmixt))

    IF (defined(ikeymixtperm)) &
      CALL inrt_setpermission(global,vals(ikeymixtperm), &
                              input%globPermission(indmixt))

! - Check for Lagrangian particle controls

    DO iplag = 1,nplag+1

      ind = indplag0 + iplag

      IF (defined(ikeyplagactv)) &
        CALL inrt_setactiveness(global,vals(ikeyplagactv), &
                                input%globActiveness(ind))

      IF (defined(ikeyplagperm)) &
        CALL inrt_setpermission(global,vals(ikeyplagperm), &
                                input%globPermission(ind))

    END DO ! iPlag

! - Check for Smoke controls

    DO ipeul = 1,npeul

      ikeyactv = ikeypeulactv0 + ipeul
      ikeyperm = ikeypeulperm0 + ipeul
      ind      = indpeul0      + ipeul

      IF (defined(ikeyactv)) &
        CALL inrt_setactiveness(global,vals(ikeyactv), &
                                input%globActiveness(ind))

      IF (defined(ikeyperm)) &
        CALL inrt_setpermission(global,vals(ikeyperm), &
                                input%globPermission(ind))

    END DO ! iPeul

! - Initialize local Activeness and Permission to global values

    DO iinrt = 1,inrt_type_total

      input%inrts(iinrt)%activeness = input%globActiveness
      input%inrts(iinrt)%permission = input%globPermission

    END DO ! iInrt

  END DO ! iReg

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( global )

END SUBROUTINE inrt_readdefaultsection

!******************************************************************************
!
! RCS Revision history:
!
! $Log: INRT_ReadDefaultSection.F90,v $
! Revision 1.3  2008/12/06 08:44:31  mtcampbe
! Updated license.
!
! Revision 1.2  2008/11/19 22:17:44  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.1  2004/12/01 21:56:34  fnajjar
! Initial revision after changing case
!
! Revision 1.9  2004/07/28 15:42:12  jferry
! deleted defunct constructs: useDetangle, useSmokeDrag, useSmokeHeatTransfer
!
! Revision 1.8  2004/07/23 22:43:16  jferry
! Integrated rocspecies into rocinteract
!
! Revision 1.7  2004/03/05 22:09:03  jferry
! created global variables for peul, plag, and inrt use
!
! Revision 1.6  2004/03/02 21:47:29  jferry
! Added After Update interactions
!
! Revision 1.5  2003/09/25 15:48:43  jferry
! implemented Boiling Regulation interaction
!
! Revision 1.4  2003/04/02 22:32:04  jferry
! codified Activeness and Permission structures for rocinteract
!
! Revision 1.3  2003/03/24 23:30:52  jferry
! overhauled rocinteract to allow interaction design to use user input
!
! Revision 1.2  2003/03/11 16:09:39  jferry
! Added comments
!
! Revision 1.1  2003/03/04 22:12:35  jferry
! Initial import of Rocinteract
!
!******************************************************************************