INRT_ReadBoilingRegulation.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: Reads in information related to the interaction Boiling Regulation
!
! Description: none.
!
! Input: regions = data of all regions
!
! Output: fills user data into region%inrtInput%inrts
!
! Notes: none.
!
!******************************************************************************
!
! $Id: INRT_ReadBoilingRegulation.F90,v 1.3 2008/12/06 08:44:31 mtcampbe Exp $
!
! Copyright: (c) 2003 by the University of Illinois
!
!******************************************************************************

SUBROUTINE inrt_readboilingregulation( regions )

  USE moddatatypes
  USE moddatastruct, ONLY : t_region
  USE modglobal,     ONLY : t_global
  USE modmaterials,  ONLY : t_material
  USE modinteract,   ONLY : t_inrt_input,t_inrt_interact
  USE moderror
  USE modparameters
  USE inrt_modparameters

#ifdef RFLO
  USE modinterfaces,        ONLY : readbothregionsection
#endif
#ifdef RFLU
  USE modinterfaces,        ONLY : readbothsection
#endif
  USE modinterfacesinteract,ONLY : inrt_setmaterial
  USE inrt_modinterfaces,   ONLY : inrt_defineboilingregulation
  IMPLICIT NONE

! ... parameters
  TYPE(t_region), POINTER :: regions(:)

! ... loop variables
  INTEGER :: ireg

! ... local variables
  INTEGER, PARAMETER :: nstrkeys_max = 5
  INTEGER, PARAMETER :: nkeys_max    = 20

  CHARACTER(CHRLEN)  :: rcsidentstring
  CHARACTER(CHRLEN)  :: strkeys(nstrkeys_max),keys(nkeys_max)
  CHARACTER(CHRLEN)  :: strvals(nstrkeys_max)

  INTEGER :: brbeg,brend
  INTEGER :: nstrkeys,nimplkeys,nkeys
  INTEGER :: istrkeymaterialliq,istrkeymaterialgas
  INTEGER :: ikey,ikeyused,ikeymodel,ikeyboilpt,ikeyenpms

  LOGICAL :: defined(nkeys_max),strdefined(nstrkeys_max)

  REAL(RFREAL) :: boilpt,enpms
  REAL(RFREAL) :: vals(nkeys_max)

  TYPE(t_material),      POINTER :: matliq,matgas
  TYPE(t_inrt_input),    POINTER :: input
  TYPE(t_inrt_interact), POINTER :: inrt
  TYPE(t_global),        POINTER :: global

!******************************************************************************

  rcsidentstring = '$RCSfile: INRT_ReadBoilingRegulation.F90,v $ $Revision: 1.3 $'

  global => regions(1)%global

  CALL registerfunction( global,'INRT_ReadBoilingRegulation',&
  'INRT_ReadBoilingRegulation.F90' )

! begin -----------------------------------------------------------------------

! define string keys

  istrkeymaterialliq = 1
  istrkeymaterialgas = 2
  nstrkeys = 2

  strkeys(istrkeymaterialliq) = 'MATERIAL_LIQ'
  strkeys(istrkeymaterialgas) = 'MATERIAL_GAS'

  IF (nstrkeys > nstrkeys_max) &
    CALL errorstop( global,err_exceeds_decl_mem,__line__ )

! define implementation-dependent keys

  ikeyused   = 1
  ikeymodel  = 2
  ikeyboilpt = 3
  ikeyenpms  = 4
  nimplkeys  = 4

  keys(ikeyused)   = 'USED'
  keys(ikeymodel)  = 'MODEL'
  keys(ikeyboilpt) = 'BOILING_POINT'
  keys(ikeyenpms)  = 'ENERGY_PER_MASS'

  nkeys = nimplkeys

  IF (nkeys > nkeys_max) CALL errorstop( global,err_exceeds_decl_mem,__line__ )

! Read interaction section from input file

#ifdef RFLO
  CALL readbothregionsection( global,if_input,nkeys,nstrkeys,keys,strkeys, &
                              vals,strvals,brbeg,brend,defined,strdefined )
#endif
#ifdef RFLU
  CALL readbothsection( global,if_input,nkeys,nstrkeys,keys,strkeys, &
                        vals,strvals,defined,strdefined )
  brbeg = lbound(regions,1)
  brend = ubound(regions,1)
#endif

  DO ireg=brbeg,brend

    input => regions(ireg)%inrtInput
    inrt  => input%inrts(inrt_type_boilrgn)

! - Check that INRT_DEFAULT section has been read, and that interaction has not

    IF (.NOT. input%defaultRead) &
      CALL errorstop( global,err_inrt_defunread,__line__ )

    IF (inrt%used) CALL errorstop( global,err_inrt_read,__line__ )

! - Check if interaction is used

    inrt%used = .true. ! used by default when its section appears

    IF (defined(ikeyused)) THEN
      IF (nint(vals(ikeyused)) == 0) inrt%used = .false.
    END IF ! defined(iKeyUsed)

    IF (.NOT. inrt%used) cycle ! do not bother with unused interactions

! - Define interaction (using any relevant information from input deck)

    CALL inrt_defineboilingregulation(regions(ireg))

! - Set pointers to liq and gas materials

    IF (strdefined(istrkeymaterialliq)) THEN
      CALL inrt_setmaterial(global,matliq,strvals(istrkeymaterialliq))
    ELSE
      CALL errorstop( global,err_inrt_missingmat,__line__ )
    END IF ! strDefined(iStrKeyMaterialLiq)

    IF (strdefined(istrkeymaterialgas)) THEN
      CALL inrt_setmaterial(global,matgas,strvals(istrkeymaterialgas))
    ELSE
      CALL errorstop( global,err_inrt_missingmat,__line__ )
    END IF ! strDefined(iStrKeyMaterialGas)

! - Check that input and output materials have the same properties

    IF (matliq%molw /= matgas%molw .OR. matliq%dens /= matgas%dens .OR. &
        matliq%spht /= matgas%spht) &
      CALL errorstop( global,err_inrt_boil_same,__line__ )

! - Check for switches

! - Material indices

    inrt%switches(inrt_swi_boilrgn_liqind) = matliq%index
    inrt%switches(inrt_swi_boilrgn_gasind) = matgas%index

! - Which model is used

    inrt%switches(inrt_swi_boilrgn_model) = inrt_boilrgn_model_default

    IF (defined(ikeymodel)) THEN

      SELECT CASE (nint(vals(ikeymodel)))

      CASE (1)
        inrt%switches(inrt_swi_boilrgn_model) = inrt_boilrgn_model_sharp

      CASE default
        CALL errorstop( global,err_inrt_badswitch,__line__ )

      END SELECT ! vals(iKeyModel)

    END IF ! defined(iKeyModel)

! - Check for data

! - Boiling point of substance

    IF (defined(ikeyboilpt)) THEN

      boilpt = vals(ikeyboilpt)

      IF (boilpt <= 0._rfreal) CALL errorstop( global,err_inrt_badval,__line__ )

      inrt%data(inrt_dat_boilrgn_boilpt) = boilpt

    ELSE

      CALL errorstop( global,err_inrt_missingval,__line__ )

    END IF ! defined(iKeyBoilPt)

! - Energy released during condensation per unit mass of substance

    IF (defined(ikeyenpms)) THEN

      enpms = vals(ikeyenpms)

      IF (enpms <= 0._rfreal) CALL errorstop( global,err_inrt_badval,__line__ )

      inrt%data(inrt_dat_boilrgn_enpms) = enpms

    ELSE

      CALL errorstop( global,err_inrt_missingval,__line__ )

    END IF ! defined(iKeyEnPMs)

  END DO ! iReg

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( global )

END SUBROUTINE inrt_readboilingregulation

!******************************************************************************
!
! RCS Revision history:
!
! $Log: INRT_ReadBoilingRegulation.F90,v $
! Revision 1.3  2008/12/06 08:44:31  mtcampbe
! Updated license.
!
! Revision 1.2  2008/11/19 22:17:44  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.1  2004/12/01 21:56:32  fnajjar
! Initial revision after changing case
!
! Revision 1.5  2004/07/23 22:43:16  jferry
! Integrated rocspecies into rocinteract
!
! Revision 1.4  2004/03/05 22:09:03  jferry
! created global variables for peul, plag, and inrt use
!
! Revision 1.3  2004/03/02 21:48:09  jferry
! First phase of replacing Detangle interaction
!
! Revision 1.2  2003/09/26 21:46:54  fnajjar
! Modified ModInterfaces call to ModInterfacesInteract
!
! Revision 1.1  2003/09/25 15:48:43  jferry
! implemented Boiling Regulation interaction
!
!******************************************************************************