v3d4_NeoHookeanInCompress.f90

Go to the documentation of this file.

!*********************************************************************
!* Illinois Open Source License                                      *
!*                                                                   *
!* University of Illinois/NCSA                                       * 
!* Open Source License                                               *
!*                                                                   *
!* Copyright@2008, University of Illinois.  All rights reserved.     *
!*                                                                   *
!*  Developed by:                                                    *
!*                                                                   *
!*     Center for Simulation of Advanced Rockets                     *
!*                                                                   *
!*     University of Illinois                                        *
!*                                                                   *
!*     www.csar.uiuc.edu                                             *
!*                                                                   *
!* Permission is hereby granted, free of charge, to any person       *
!* obtaining a copy of this software and associated documentation    *
!* files (the "Software"), to deal with the Software without         *
!* restriction, including without limitation the rights to use,      *
!* copy, modify, merge, publish, distribute, sublicense, and/or      *
!* sell copies of the Software, and to permit persons to whom the    *
!* Software is furnished to do so, subject to the following          *
!* conditions:                                                       *
!*                                                                   *
!*                                                                   *
!* @ Redistributions of source code must retain the above copyright  * 
!*   notice, this list of conditions and the following disclaimers.  *
!*                                                                   * 
!* @ Redistributions in binary form must reproduce the above         *
!*   copyright notice, this list of conditions and the following     *
!*   disclaimers in the documentation and/or other materials         *
!*   provided with the distribution.                                 *
!*                                                                   *
!* @ Neither the names of the Center for Simulation of Advanced      *
!*   Rockets, the University of Illinois, nor the names of its       *
!*   contributors may be used to endorse or promote products derived * 
!*   from this Software without specific prior written permission.   *
!*                                                                   *
!* THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
!* EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
!* OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
!* NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
!* COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       * 
!* LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
!* ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
!* USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
!*********************************************************************
!* Please acknowledge The University of Illinois Center for          *
!* Simulation of Advanced Rockets in works and publications          *
!* resulting from this software or its derivatives.                  *
!*********************************************************************
SUBROUTINE v3d4_neohookeanincompress(coor,matcstet,lmcstet,R_in,d, &
     s11,s22,s33,s12,s23,s13,&
     numnp,nstart,nend,numcstet,numat_vol, &
     xmu,xkappa)
  
!________________________________________________________________________
!
!  V3D4 - Performs displacement based computations for Volumetric 3D 
!         4-node tetrahedra large deformation (i.e. nonlinear) elastic 
!         elements with linear interpolation functions. (constant strain 
!         tetrahedra). Returns the internal force vector R_in.
!
!  DATE: 04.2000                  AUTHOR: SCOT BREITENFELD
!
! Source:
!    "Nonlinear continuum mechanics for finite element analysis"
!     Javier Bonet and Richard D. Wood
!     ISBN 0-521-57272-X

!________________________________________________________________________

  IMPLICIT NONE
!---- Global variables
  INTEGER :: numnp          ! number of nodal points
  INTEGER :: numcstet       ! number of CSTet elements
  INTEGER :: numat_vol      ! number of volumetric materials
  INTEGER :: istrgss
!--   coordinate array
  REAL*8, DIMENSION(1:3,1:numnp) :: coor
!--   internal force
  REAL*8, DIMENSION(1:3*numnp) :: r_in
!--  displacement vector
  REAL*8, DIMENSION(1:3*numnp) :: d
!--   CSTet stress
  REAL*8, DIMENSION(1:numcstet) :: s11, s22, s33, s12, s23, s13
!--  x, y and z displacements of nodes
  REAL*8 :: u1,u2,u3,u4,v1,v2,v3,v4,w1,w2,w3,w4
!--   coordinate holding variable
  REAL*8 :: x1,x2,x3,x4,y1,y2,y3,y4,z1,z2,z3,z4
!--   coordinate holding variable
  REAL*8 :: x1d,x2d,x3d,x4d,y1d,y2d,y3d,y4d,z1d,z2d,z3d,z4d
!--  Coordinate subtractions
  REAL*8 :: x14, x24, x34, y14, y24, y34, z14, z24, z34
!--   6*volume, inverse(6*volume),  and the volume      
!      REAL*8 :: Vx6, vol
!--   spacial derivatives
  REAL*8 :: b1,b2,b3,b4,b5,b6,b7,b8,b9,b10,b11,b12
!--   partial derivatives of the displacement 
  REAL*8 :: dudx,dvdy,dwdz,dudy,dvdx,dvdz,dwdy,dudz,dwdx
!--   strains
  REAL*8 :: e11,e22,e33,e12,e23,e13
! -- connectivity table for CSTet
  INTEGER, DIMENSION(1:4,1:numcstet) :: lmcstet
! -- mat number for CST element
  INTEGER, DIMENSION(1:numcstet) :: matcstet
! -- node numbers
  INTEGER :: n1,n2,n3,n4
! -- dummy and counters
  INTEGER :: i,j,nstart,nend
  INTEGER :: k1n1,k1n2,k1n3,k1n4,k2n1,k2n2,k2n3,k2n4
  INTEGER :: k3n1,k3n2,k3n3,k3n4
! -- 
  REAL*8 :: f11, f12, f13, f21, f22, f23, f31, f32, f33
  REAL*8 :: j1,jsqrd,jsqrdinv
  REAL*8 :: c11, c12, c13, c21, c22, c23, c31, c32, c33
  REAL*8, DIMENSION(1:numat_vol) :: xmu,xkappa
  REAL*8, DIMENSION(1:4,1:4) :: eledb
  REAL*8,DIMENSION(1:3,1:3) :: xj
  REAL*8,DIMENSION(1:3,1:3) :: xjv0
  REAL*8 :: weight = 1.d0/6.d0
  INTEGER :: id, jd, in, ip
  REAL*8 :: xcoor
  REAL*8 :: detjb,detjbv0,evol,theta,press
  REAL*8 :: ic, iiic,vx6old0,vx6old
  REAL*8 :: onethird = 1.d0/3.d0
  REAL*8 :: val11, val21, val31
  
  REAL*8 :: v0x6, v0x6inv
  REAL*8 :: vx6, vx6inv
  REAL*8 :: vol, vol0
  REAL*8 :: term1, term2, cinv
  
  DO i = nstart, nend
     j = matcstet(i)
     
     n1 = lmcstet(1,i)
     n2 = lmcstet(2,i)
     n3 = lmcstet(3,i)
     n4 = lmcstet(4,i)
     
     k3n1 = 3*n1
     k3n2 = 3*n2
     k3n3 = 3*n3
     k3n4 = 3*n4
     
     k2n1 = k3n1 - 1
     k2n2 = k3n2 - 1
     k2n3 = k3n3 - 1
     k2n4 = k3n4 - 1
     
     k1n1 = k3n1 - 2
     k1n2 = k3n2 - 2
     k1n3 = k3n3 - 2
     k1n4 = k3n4 - 2     
     ! k#n# dummy variables replaces:
     u1 = d(k1n1)           ! (3*n1-2)
     u2 = d(k1n2)           ! (3*n2-2)
     u3 = d(k1n3)           ! (3*n3-2)
     u4 = d(k1n4)           ! (3*n4-2)
     v1 = d(k2n1)           ! (3*n1-1)
     v2 = d(k2n2)           ! (3*n2-1)
     v3 = d(k2n3)           ! (3*n3-1)
     v4 = d(k2n4)           ! (3*n4-1)
     w1 = d(k3n1)           ! (3*n1)
     w2 = d(k3n2)           ! (3*n2)
     w3 = d(k3n3)           ! (3*n3)
     w4 = d(k3n4)           ! (3*n4)
     
     x1 = coor(1,n1)
     x2 = coor(1,n2)
     x3 = coor(1,n3)
     x4 = coor(1,n4)
     y1 = coor(2,n1)
     y2 = coor(2,n2)
     y3 = coor(2,n3)
     y4 = coor(2,n4)
     z1 = coor(3,n1)
     z2 = coor(3,n2)
     z3 = coor(3,n3)
     z4 = coor(3,n4)
     
     x1d = x1 + u1
     x2d = x2 + u2
     x3d = x3 + u3
     x4d = x4 + u4
     y1d = y1 + v1
     y2d = y2 + v2
     y3d = y3 + v3
     y4d = y4 + v4
     z1d = z1 + w1
     z2d = z2 + w2
     z3d = z3 + w3
     z4d = z4 + w4
!
!     creates the Jacobian matrix using equation ???
!     Using undeformed coordinates
     
     x14 = x1 - x4
     x24 = x2 - x4
     x34 = x3 - x4
     y14 = y1 - y4
     y24 = y2 - y4
     y34 = y3 - y4
     z14 = z1 - z4
     z24 = z2 - z4
     z34 = z3 - z4
     
     val11 =    y24*z34 - z24*y34
     val21 = -( x24*z34 - z24*x34 )
     val31 =    x24*y34 - y24*x34
     
     v0x6 = -( x14*val11 + y14*val21 + z14*val31 )
!
!     creates the Jacobian matrix using equation ???
!     Determines the determinant of xj and checks for zero values
!
!     Using deformed coordinates

     x14 = x1d - x4d
     x24 = x2d - x4d
     x34 = x3d - x4d
     y14 = y1d - y4d
     y24 = y2d - y4d
     y34 = y3d - y4d
     z14 = z1d - z4d
     z24 = z2d - z4d
     z34 = z3d - z4d
     
     val11 =    y24*z34 - z24*y34
     val21 = -( x24*z34 - z24*x34 )
     val31 =    x24*y34 - y24*x34
     
     vx6 = -( x14*val11 + y14*val21 + z14*val31 )
     
     IF(vx6.LE.0.d0) THEN
        WRITE(*,100) i
        stop
     ENDIF
     

! calculate the volume
      
     vol0 = v0x6/6.d0
     vol  = vx6/6.d0
     
     v0x6inv = 1.d0/v0x6
     
! See the maple worksheet 'V3D4.mws' for the derivation of Vx6

! See the maple worksheet 'V3D4.mws' for the derivation of [B]
! NOTE: Factored for a more equivalent/compact form then maple's

     b1  = ( (y3-y4)*(z2-z4) - (y2-y4)*(z3-z4) ) * v0x6inv
     b2  = ( (z3-z4)*(x2-x4) - (z2-z4)*(x3-x4) ) * v0x6inv
     b3  = ( (x3-x4)*(y2-y4) - (x2-x4)*(y3-y4) ) * v0x6inv
     b4  = ( (y1-y3)*(z1-z4) - (y1-y4)*(z1-z3) ) * v0x6inv
     b5  = ( (z1-z3)*(x1-x4) - (z1-z4)*(x1-x3) ) * v0x6inv
     b6  = ( (x1-x3)*(y1-y4) - (x1-x4)*(y1-y3) ) * v0x6inv
     b7  = ( (y1-y4)*(z1-z2) - (y1-y2)*(z1-z4) ) * v0x6inv
     b8  = ( (z1-z4)*(x1-x2) - (z1-z2)*(x1-x4) ) * v0x6inv
     b9  = ( (x1-x4)*(y1-y2) - (x1-x2)*(y1-y4) ) * v0x6inv
     b10 = ( (y1-y2)*(z1-z3) - (y1-y3)*(z1-z2) ) * v0x6inv
     b11 = ( (z1-z2)*(x1-x3) - (z1-z3)*(x1-x2) ) * v0x6inv
     b12 = ( (x1-x2)*(y1-y3) - (x1-x3)*(y1-y2) ) * v0x6inv
! 
! deformation gradients F
!
     f11 = 1.d0 + ( b1*u1 + b4*u2 + b7*u3 + b10*u4 ) ! 1 + ( dudx )
     f22 = 1.d0 + ( b2*v1 + b5*v2 + b8*v3 + b11*v4 ) ! 1 + ( dvdy )
     f33 = 1.d0 + ( b3*w1 + b6*w2 + b9*w3 + b12*w4 ) ! 1 + ( dwdz )
     f12 = b2*u1 + b5*u2 + b8*u3 + b11*u4 ! dudy
     f21 = b1*v1 + b4*v2 + b7*v3 + b10*v4 ! dvdx
     f23 = b3*v1 + b6*v2 + b9*v3 + b12*v4 ! dvdz
     f32 = b2*w1 + b5*w2 + b8*w3 + b11*w4 ! dwdy
     f13 = b3*u1 + b6*u2 + b9*u3 + b12*u4 ! dudz
     f31 = b1*w1 + b4*w2 + b7*w3 + b10*w4 ! dwdx
     
     theta = vol/vol0
     
     press = xkappa(j)*(theta-1.d0)
     
     j1 = f11*(f22*f33-f23*f32)+f12*(f31*f23-f21*f33)+f13*(-f31*f22+f21*f32)
     IF(j1.LE.0.d0) THEN
        WRITE(*,*)'Volume has become zero for element',i
        stop
     ENDIF
     jsqrd = j1*j1
     
! first invariant of C
     
     ic = f11**2+f21**2+f31**2+f12**2+f22**2+f32**2+f13**2+f23**2+f33**2
     
! Third invariant of C
     
     iiic = jsqrd        
     
!          T
!     C = F  F = right Cauchy-Green deformation tensor
!
     c11 = (f11*f11+f21*f21+f31*f31)
     c12 = (f11*f12+f21*f22+f31*f32)
     c13 = (f11*f13+f21*f23+f31*f33)
     c21 = c12 
     c22 = (f12*f12+f22*f22+f32*f32)
     c23 = (f12*f13+f22*f23+f32*f33) 
     c31 = c13
     c32 = c23
     c33 = (f13*f13+f23*f23+f33*f33)
!
! Second Piola-Kirchoff tensor
! Eq. (5.28), pg. 124 

     jsqrdinv = 1.d0/jsqrd
     
     term1 = xmu(j)*iiic**(-onethird)
     term2 = press*j1
     
     cinv = (c22*c33-c23*c32)*jsqrdinv
     s11(i) = term1*(1.d0-onethird*ic*cinv) + term2*cinv
     cinv = (c11*c33-c31*c13)*jsqrdinv
     s22(i) = term1*(1.d0-onethird*ic*cinv) + term2*cinv
     cinv = (c11*c22-c12*c21)*jsqrdinv
     s33(i) = term1*(1.d0-onethird*ic*cinv) + term2*cinv
     cinv = (-c12*c33+c13*c32)*jsqrdinv
     s12(i) = cinv*(-term1*onethird*ic + term2)
     cinv = (-c11*c23+c13*c21)*jsqrdinv
     s23(i) = cinv*(-term1*onethird*ic + term2)
     cinv = ( c12*c23-c13*c22)*jsqrdinv
     s13(i) = cinv*(-term1*onethird*ic + term2)

! ASSEMBLE THE INTERNAL FORCE VECTOR
!
! local node 1

     r_in(k1n1) = r_in(k1n1) - vol0* &
          ( s11(i)*b1*f11 + s22(i)*b2*f12 + s33(i)*b3*f13 &
          + s12(i)*( b2*f11 + b1*f12 ) &
          + s23(i)*( b3*f12 + b2*f13 ) &
          + s13(i)*( b3*f11 + b1*f13 ) )
     r_in(k2n1) = r_in(k2n1) - vol0* &
          ( s11(i)*b1*f21 + s22(i)*b2*f22 + s33(i)*b3*f23 &
          + s12(i)*( b1*f22 + b2*f21 ) &
          + s23(i)*( b3*f22 + b2*f23 ) &
          + s13(i)*( b3*f21 + b1*f23 ) )
     r_in(k3n1) = r_in(k3n1) - vol0* &
          ( s11(i)*b1*f31 + s22(i)*b2*f32 + s33(i)*b3*f33 &
          + s12(i)*( b2*f31 + b1*f32 ) &
          + s23(i)*( b3*f32 + b2*f33 ) &
          + s13(i)*( b3*f31 + b1*f33 ) )
! local node 2 
     r_in(k1n2) = r_in(k1n2) - vol0* &
          ( s11(i)*b4*f11 + s22(i)*b5*f12 + s33(i)*b6*f13 &
          + s12(i)*( b5*f11 + b4*f12 ) &
          + s23(i)*( b6*f12 + b5*f13 ) &
          + s13(i)*( b6*f11 + b4*f13 ) )
     r_in(k2n2) = r_in(k2n2) - vol0* &
          ( s11(i)*b4*f21 + s22(i)*b5*f22 + s33(i)*b6*f23 &
          + s12(i)*( b4*f22 + b5*f21 ) &
          + s23(i)*( b6*f22 + b5*f23 ) &
          + s13(i)*( b6*f21 + b4*f23 ) )
     r_in(k3n2) = r_in(k3n2) - vol0* &
          ( s11(i)*b4*f31 + s22(i)*b5*f32 + s33(i)*b6*f33 &
          + s12(i)*( b5*f31 + b4*f32 ) &
          + s23(i)*( b6*f32 + b5*f33 ) &
          + s13(i)*( b6*f31 + b4*f33 ) )
! local node 3 
     r_in(k1n3) = r_in(k1n3) - vol0* &
          ( s11(i)*b7*f11 + s22(i)*b8*f12 + s33(i)*b9*f13 &
          + s12(i)*( b8*f11 + b7*f12 ) &
          + s23(i)*( b9*f12 + b8*f13 ) &
          + s13(i)*( b9*f11 + b7*f13 ) )
     r_in(k2n3) = r_in(k2n3) - vol0* &
          ( s11(i)*b7*f21 + s22(i)*b8*f22 + s33(i)*b9*f23 &
          + s12(i)*( b7*f22 + b8*f21 ) &
          + s23(i)*( b9*f22 + b8*f23 ) &
          + s13(i)*( b9*f21 + b7*f23 ) )
     r_in(k3n3) = r_in(k3n3) - vol0* &
          ( s11(i)*b7*f31 + s22(i)*b8*f32 + s33(i)*b9*f33 &
          + s12(i)*( b8*f31 + b7*f32 ) &
          + s23(i)*( b9*f32 + b8*f33 ) &
          + s13(i)*( b9*f31 + b7*f33 ) )
! local node 4         
     r_in(k1n4) = r_in(k1n4) - vol0* &
          ( s11(i)*b10*f11 + s22(i)*b11*f12+s33(i)*b12*f13 &
          + s12(i)*( b11*f11 + b10*f12 ) &
          + s23(i)*( b12*f12 + b11*f13 ) &
          + s13(i)*( b12*f11 + b10*f13 ) )
     r_in(k2n4) = r_in(k2n4) - vol0* &
          ( s11(i)*b10*f21 + s22(i)*b11*f22 + s33(i)*b12*f23 &
          + s12(i)*( b10*f22 + b11*f21 ) &
          + s23(i)*( b12*f22 + b11*f23 ) &
          + s13(i)*( b12*f21 + b10*f23 ) )
     r_in(k3n4) = r_in(k3n4) - vol0* &
          ( s11(i)*b10*f31 + s22(i)*b11*f32 + s33(i)*b12*f33 &
          + s12(i)*( b11*f31 + b10*f32 ) &
          + s23(i)*( b12*f32 + b11*f33 ) &
          + s13(i)*( b12*f31 + b10*f33 ) )
  ENDDO

  RETURN
      
100 FORMAT(' Negative Jacobian for element: ',i10)
END SUBROUTINE v3d4_neohookeanincompress