v3d4_NeoHookeanInCompressPrin.f90

Go to the documentation of this file.

!*********************************************************************
!* Illinois Open Source License                                      *
!*                                                                   *
!* University of Illinois/NCSA                                       * 
!* Open Source License                                               *
!*                                                                   *
!* Copyright@2008, University of Illinois.  All rights reserved.     *
!*                                                                   *
!*  Developed by:                                                    *
!*                                                                   *
!*     Center for Simulation of Advanced Rockets                     *
!*                                                                   *
!*     University of Illinois                                        *
!*                                                                   *
!*     www.csar.uiuc.edu                                             *
!*                                                                   *
!* Permission is hereby granted, free of charge, to any person       *
!* obtaining a copy of this software and associated documentation    *
!* files (the "Software"), to deal with the Software without         *
!* restriction, including without limitation the rights to use,      *
!* copy, modify, merge, publish, distribute, sublicense, and/or      *
!* sell copies of the Software, and to permit persons to whom the    *
!* Software is furnished to do so, subject to the following          *
!* conditions:                                                       *
!*                                                                   *
!*                                                                   *
!* @ Redistributions of source code must retain the above copyright  * 
!*   notice, this list of conditions and the following disclaimers.  *
!*                                                                   * 
!* @ Redistributions in binary form must reproduce the above         *
!*   copyright notice, this list of conditions and the following     *
!*   disclaimers in the documentation and/or other materials         *
!*   provided with the distribution.                                 *
!*                                                                   *
!* @ Neither the names of the Center for Simulation of Advanced      *
!*   Rockets, the University of Illinois, nor the names of its       *
!*   contributors may be used to endorse or promote products derived * 
!*   from this Software without specific prior written permission.   *
!*                                                                   *
!* THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
!* EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
!* OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
!* NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
!* COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       * 
!* LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
!* ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
!* USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
!*********************************************************************
!* Please acknowledge The University of Illinois Center for          *
!* Simulation of Advanced Rockets in works and publications          *
!* resulting from this software or its derivatives.                  *
!*********************************************************************
SUBROUTINE v3d4_neohookeanincompressprin(coor,matcstet,lmcstet,R_in,d,ci, &
     s11,s22,s33,s12,s23,s13,numnp,nstart,nend,numcstet,numat_vol, &
     xmu,xkappa,xlambda)

!________________________________________________________________________
!
!  V3D4 - Performs displacement based computations for Volumetric 3D 
!         4-node tetrahedra large deformation (i.e. nonlinear) elastic 
!         elements with linear interpolation functions. (constant strain 
!         tetrahedra). Returns the internal force vector R_in.
!
!  DATE: 04.2000                  AUTHOR: SCOT BREITENFELD
!
! Source:
!    "Nonlinear continuum mechanics for finite element analysis"
!     Javier Bonet and Richard D. Wood
!     ISBN 0-521-57272-X

!________________________________________________________________________

  IMPLICIT NONE
!---- Global variables
  INTEGER :: numnp          ! number of nodal points
  INTEGER :: numcstet       ! number of CSTet elements
  INTEGER :: numat_vol      ! number of volumetric materials
!--   coordinate array
  REAL*8, DIMENSION(1:3,1:numnp) :: coor
!--   elastic stiffness consts
  REAL*8, DIMENSION(1:9,1:numat_vol) :: ci
!--   internal force
  REAL*8, DIMENSION(1:3*numnp) :: r_in
!--  displacement vector
  REAL*8, DIMENSION(1:3*numnp) :: d
!--   CSTet stress
  REAL*8, DIMENSION(1:numcstet) :: s11, s22, s33, s12, s23, s13
!--  x, y and z displacements of nodes
  REAL*8 :: u1,u2,u3,u4,v1,v2,v3,v4,w1,w2,w3,w4
!--   coordinate holding variable
  REAL*8 :: x1,x2,x3,x4,y1,y2,y3,y4,z1,z2,z3,z4
!--   coordinate holding variable
  REAL*8 :: x1d,x2d,x3d,x4d,y1d,y2d,y3d,y4d,z1d,z2d,z3d,z4d
!--  Coordinate subtractions
  REAL*8 :: x14, x24, x34, y14, y24, y34, z14, z24, z34
!--  Coordinate subtractions: These are to speed up B calculation
  REAL*8 :: x12, x13, y12, y13, z12, z13
!--   6*volume, inverse(6*volume),  and the volume      
!      REAL*8 :: Vx6, vol
!--   spacial derivatives
  REAL*8 :: b1,b2,b3,b4,b5,b6,b7,b8,b9,b10,b11,b12
!--   partial derivatives of the displacement 
  REAL*8 :: dudx,dvdy,dwdz,dudy,dvdx,dvdz,dwdy,dudz,dwdx
!--   strains
  REAL*8 :: e11,e22,e33,e12,e23,e13
! -- connectivity table for CSTet
  INTEGER, DIMENSION(1:4,1:numcstet) :: lmcstet
! -- mat number for CST element
  INTEGER, DIMENSION(1:numcstet) :: matcstet
! -- node numbers
  INTEGER :: n1,n2,n3,n4
! -- dummy and counters
  INTEGER :: i,j,nstart,nend
  INTEGER :: k1n1,k1n2,k1n3,k1n4,k2n1,k2n2,k2n3,k2n4
  INTEGER :: k3n1,k3n2,k3n3,k3n4
! -- 
  REAL*8 :: f11, f12, f13, f21, f22, f23, f31, f32, f33
  REAL*8 :: j1,jsqrd,jsqrdinv
  REAL*8 :: c11, c12, c13, c21, c22, c23, c31, c32, c33
  REAL*8 :: xmu, xlambda
  REAL*8, DIMENSION(1:4,1:4) :: eledb
  REAL*8,DIMENSION(1:3,1:3) :: xj
  REAL*8,DIMENSION(1:3,1:3) :: xjv0
  REAL*8 :: weight = 1.d0/6.d0
  INTEGER :: id, jd, in, ip
  REAL*8 :: xcoor
  REAL*8 :: detjb,detjbv0,evol,theta,xkappa,press
  REAL*8 :: ic, iiic,vx6old0,vx6old
  REAL*8 :: onethird = 1.d0/3.d0
  REAL*8 :: val11, val21, val31
  
  REAL*8 :: v0x6, v0x6inv
  REAL*8 :: vx6, vx6inv
  REAL*8 :: vol, vol0
  REAL*8 :: term1, term2, cinv
  REAL*8, DIMENSION(1:3,1:3) :: btens,princ,sigma
  REAL*8, DIMENSION(1:3) :: stret,sprin
  REAL*8 :: detf
  REAL*8 :: sh1, sh2, sh3, sh4, sh5, sh6, sh7, sh8, sh9, sh10, sh11, sh12
  REAL*8 :: voldef,vx6invdef,vx6def

  DO i = nstart, nend
     j = matcstet(i)
     
     n1 = lmcstet(1,i)
     n2 = lmcstet(2,i)
     n3 = lmcstet(3,i)
     n4 = lmcstet(4,i)
     
     k3n1 = 3*n1
     k3n2 = 3*n2
     k3n3 = 3*n3
     k3n4 = 3*n4
     
     k2n1 = k3n1 - 1
     k2n2 = k3n2 - 1
     k2n3 = k3n3 - 1
     k2n4 = k3n4 - 1
     
     k1n1 = k3n1 - 2
     k1n2 = k3n2 - 2
     k1n3 = k3n3 - 2
     k1n4 = k3n4 - 2     
     ! k#n# dummy variables replaces:
     u1 = d(k1n1)           ! (3*n1-2)
     u2 = d(k1n2)           ! (3*n2-2)
     u3 = d(k1n3)           ! (3*n3-2)
     u4 = d(k1n4)           ! (3*n4-2)
     v1 = d(k2n1)           ! (3*n1-1)
     v2 = d(k2n2)           ! (3*n2-1)
     v3 = d(k2n3)           ! (3*n3-1)
     v4 = d(k2n4)           ! (3*n4-1)
     w1 = d(k3n1)           ! (3*n1)
     w2 = d(k3n2)           ! (3*n2)
     w3 = d(k3n3)           ! (3*n3)
     w4 = d(k3n4)           ! (3*n4)

     x1 = coor(1,n1)
     x2 = coor(1,n2)
     x3 = coor(1,n3)
     x4 = coor(1,n4)
     y1 = coor(2,n1)
     y2 = coor(2,n2)
     y3 = coor(2,n3)
     y4 = coor(2,n4)
     z1 = coor(3,n1)
     z2 = coor(3,n2)
     z3 = coor(3,n3)
     z4 = coor(3,n4)
     
     x12 = x1 - x2          ! not used in vol. calc
     x13 = x1 - x3          ! not used in vol. calc
     x14 = x1 - x4
     x24 = x2 - x4
     x34 = x3 - x4
     y12 = y1 - y2          ! not used in vol. calc
     y13 = y1 - y3          ! not used in vol. calc
     y14 = y1 - y4
     y24 = y2 - y4
     y34 = y3 - y4
     z12 = z1 - z2          ! not used in vol. calc
     z13 = z1 - z3          ! not used in vol. calc
     z14 = z1 - z4
     z24 = z2 - z4
     z34 = z3 - z4
     
     val11 =    y24*z34 - z24*y34
     val21 = -( x24*z34 - z24*x34 )
     val31 =    x24*y34 - y24*x34
     
     v0x6 = -( x14*val11 + y14*val21 + z14*val31 )
         
     vx6inv = 1.d0/v0x6

! See the maple worksheet 'V3D4.mws' for the derivation of Vx6

! See the maple worksheet 'V3D4.mws' for the derivation of [B]
! NOTE: Factored for a more equivalent/compact form then maple's
     
     b1  = (y34*z24 - y24*z34) * vx6inv
     b2  = (z34*x24 - z24*x34) * vx6inv
     b3  = (x34*y24 - x24*y34) * vx6inv
     b4  = (y13*z14 - y14*z13) * vx6inv
     b5  = (z13*x14 - z14*x13) * vx6inv
     b6  = (x13*y14 - x14*y13) * vx6inv
     b7  = (y14*z12 - y12*z14) * vx6inv
     b8  = (z14*x12 - z12*x14) * vx6inv
     b9  = (x14*y12 - x12*y14) * vx6inv
     b10 = (y12*z13 - y13*z12) * vx6inv
     b11 = (z12*x13 - z13*x12) * vx6inv
     b12 = (x12*y13 - x13*y12) * vx6inv
! 
! deformation gradients F
!
     f11 = 1.d0 + ( b1*u1 + b4*u2 + b7*u3 + b10*u4 ) ! 1 + ( dudx )
     f22 = 1.d0 + ( b2*v1 + b5*v2 + b8*v3 + b11*v4 ) ! 1 + ( dvdy )
     f33 = 1.d0 + ( b3*w1 + b6*w2 + b9*w3 + b12*w4 ) ! 1 + ( dwdz )
     f12 = b2*u1 + b5*u2 + b8*u3 + b11*u4 ! dudy
     f21 = b1*v1 + b4*v2 + b7*v3 + b10*v4 ! dvdx
     f23 = b3*v1 + b6*v2 + b9*v3 + b12*v4 ! dvdz
     f32 = b2*w1 + b5*w2 + b8*w3 + b11*w4 ! dwdy
     f13 = b3*u1 + b6*u2 + b9*u3 + b12*u4 ! dudz
     f31 = b1*w1 + b4*w2 + b7*w3 + b10*w4 ! dwdx

     detf = f11*(f22*f33-f23*f32)+f12*(f31*f23-f21*f33)+f13*(-f31*f22+f21*f32)
     IF(detf.LE.0.d0) THEN
        WRITE(*,*)'Jacobian has become zero for element',i
        stop
     ENDIF

!                                     
!     obtains the tensor b, left cauchy-green tensor using equation ???
!
     btens(1,1) = f11**2+f12**2+f13**2
     btens(1,2) = f21*f11+f12*f22+f13*f23
     btens(1,3) = f31*f11+f12*f32+f13*f33
     btens(2,1) = btens(1,2)
     btens(2,2) = f21**2+f22**2+f23**2
     btens(2,3) = f21*f31+f32*f22+f23*f33
     btens(3,1) = btens(1,3)
     btens(3,2) = btens(2,3)
     btens(3,3) = f31**2+f32**2+f33**2

     CALL jacobi(btens,stret,princ)
     
     CALL cauchystressprinc(3,xmu,xlambda,detf,stret,princ,sigma,sprin)

     s11(i) = sigma(1,1)
     s12(i) = sigma(1,2)
     s13(i) = sigma(1,3)
     s22(i) = sigma(2,2)
     s23(i) = sigma(2,3)
     s33(i) = sigma(3,3)

     x1 = x1 + u1
     x2 = x2 + u2
     x3 = x3 + u3
     x4 = x4 + u4
     y1 = y1 + v1
     y2 = y2 + v2
     y3 = y3 + v3
     y4 = y4 + v4
     z1 = z1 + w1
     z2 = z2 + w2
     z3 = z3 + w3
     z4 = z4 + w4
     
     x12 = x1 - x2          ! not used in vol. calc
     x13 = x1 - x3          ! not used in vol. calc
     x14 = x1 - x4
     x24 = x2 - x4
     x34 = x3 - x4
     y12 = y1 - y2          ! not used in vol. calc
     y13 = y1 - y3          ! not used in vol. calc
     y14 = y1 - y4
     y24 = y2 - y4
     y34 = y3 - y4
     z12 = z1 - z2          ! not used in vol. calc
     z13 = z1 - z3          ! not used in vol. calc
     z14 = z1 - z4
     z24 = z2 - z4
     z34 = z3 - z4
     
     val11 =    y24*z34 - z24*y34
     val21 = -( x24*z34 - z24*x34 )
     val31 =    x24*y34 - y24*x34
     
     vx6def = -( x14*val11 + y14*val21 + z14*val31 )
     
     vx6invdef = 1.d0 / vx6def 

! calculate the volume
     voldef = vx6def/6.d0

     IF(vx6def.LE.0.d0) THEN
        WRITE(*,100) i
        stop
     ENDIF
     
     sh1  = (y34*z24 - y24*z34) * vx6invdef
     sh2  = (z34*x24 - z24*x34) * vx6invdef
     sh3  = (x34*y24 - x24*y34) * vx6invdef
     sh4  = (y13*z14 - y14*z13) * vx6invdef
     sh5  = (z13*x14 - z14*x13) * vx6invdef
     sh6  = (x13*y14 - x14*y13) * vx6invdef
     sh7  = (y14*z12 - y12*z14) * vx6invdef
     sh8  = (z14*x12 - z12*x14) * vx6invdef
     sh9  = (x14*y12 - x12*y14) * vx6invdef
     sh10 = (y12*z13 - y13*z12) * vx6invdef
     sh11 = (z12*x13 - z13*x12) * vx6invdef
     sh12 = (x12*y13 - x13*y12) * vx6invdef

! ASSEMBLE THE INTERNAL FORCE VECTOR (uses Cauchy Stress)
!
! local node 1
     r_in(k1n1) = r_in(k1n1) - voldef* &
          ( s11(i)*sh1 + s12(i)*sh2 + s13(i)*sh3 )
     r_in(k2n1) = r_in(k2n1) - voldef* &
          ( s12(i)*sh1 + s22(i)*sh2 + s23(i)*sh3 )
     r_in(k3n1) = r_in(k3n1) - voldef* &
          ( s13(i)*sh1 + s23(i)*sh2 + s33(i)*sh3 )
! local node 2 
     r_in(k1n2) = r_in(k1n2) - voldef* &
          ( s11(i)*sh4 + s12(i)*sh5 + s13(i)*sh6 )
     r_in(k2n2) = r_in(k2n2) - voldef* &
          ( s12(i)*sh4 + s22(i)*sh5 + s23(i)*sh6 )
     r_in(k3n2) = r_in(k3n2) - voldef* &
          ( s13(i)*sh4 + s23(i)*sh5 + s33(i)*sh6 )
! local node 3 
     r_in(k1n3) = r_in(k1n3) - voldef* &
          ( s11(i)*sh7 + s12(i)*sh8 + s13(i)*sh9 )
     r_in(k2n3) = r_in(k2n3) - voldef* &
          ( s12(i)*sh7 + s22(i)*sh8 + s23(i)*sh9 )
     r_in(k3n3) = r_in(k3n3) - voldef* &
          ( s13(i)*sh7 + s23(i)*sh8 + s33(i)*sh9 )
! local node 4  
     r_in(k1n4) = r_in(k1n4) - voldef* &
          ( s11(i)*sh10 + s12(i)*sh11 + s13(i)*sh12 )
     r_in(k2n4) = r_in(k2n4) - voldef* &
          ( s12(i)*sh10 + s22(i)*sh11 + s23(i)*sh12 )
     r_in(k3n4) = r_in(k3n4) - voldef* &
          ( s13(i)*sh10 + s23(i)*sh11 + s33(i)*sh12 )

  ENDDO

  RETURN
      
100 FORMAT(' Negative Jacobian for element: ',i10)

END SUBROUTINE v3d4_neohookeanincompressprin