v3d4.f90

Go to the documentation of this file.

!*********************************************************************
!* Illinois Open Source License                                      *
!*                                                                   *
!* University of Illinois/NCSA                                       * 
!* Open Source License                                               *
!*                                                                   *
!* Copyright@2008, University of Illinois.  All rights reserved.     *
!*                                                                   *
!*  Developed by:                                                    *
!*                                                                   *
!*     Center for Simulation of Advanced Rockets                     *
!*                                                                   *
!*     University of Illinois                                        *
!*                                                                   *
!*     www.csar.uiuc.edu                                             *
!*                                                                   *
!* Permission is hereby granted, free of charge, to any person       *
!* obtaining a copy of this software and associated documentation    *
!* files (the "Software"), to deal with the Software without         *
!* restriction, including without limitation the rights to use,      *
!* copy, modify, merge, publish, distribute, sublicense, and/or      *
!* sell copies of the Software, and to permit persons to whom the    *
!* Software is furnished to do so, subject to the following          *
!* conditions:                                                       *
!*                                                                   *
!*                                                                   *
!* @ Redistributions of source code must retain the above copyright  * 
!*   notice, this list of conditions and the following disclaimers.  *
!*                                                                   * 
!* @ Redistributions in binary form must reproduce the above         *
!*   copyright notice, this list of conditions and the following     *
!*   disclaimers in the documentation and/or other materials         *
!*   provided with the distribution.                                 *
!*                                                                   *
!* @ Neither the names of the Center for Simulation of Advanced      *
!*   Rockets, the University of Illinois, nor the names of its       *
!*   contributors may be used to endorse or promote products derived * 
!*   from this Software without specific prior written permission.   *
!*                                                                   *
!* THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
!* EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
!* OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
!* NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
!* COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       * 
!* LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
!* ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
!* USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
!*********************************************************************
!* Please acknowledge The University of Illinois Center for          *
!* Simulation of Advanced Rockets in works and publications          *
!* resulting from this software or its derivatives.                  *
!*********************************************************************
SUBROUTINE v3d4(coor,matcstet,lmcstet,R_in,d,ci, &
     s11,s22,s33,s12,s23,s13,numnp,nstart,nend,numcstet,numat_vol)
!________________________________________________________________________
!
!  V3D4 - Performs displacement based computations for Volumetric 3D 
!         4-node tetrahedra linear elastic elements with linear 
!         interpolation functions. (constant strain tetrahedra).
!         Returns the internal force vector R_in.
!
!  DATE: 04.2000                  AUTHOR: SCOT BREITENFELD
!________________________________________________________________________

  IMPLICIT NONE
!---- Global variables
  INTEGER :: numnp          ! number of nodal points
  INTEGER :: numcstet       ! number of CSTet elements
  INTEGER :: numat_vol      ! number of volumetric materials
!--   coordinate array
  REAL*8, DIMENSION(1:3,1:numnp) :: coor
!--   elastic stiffness consts
  REAL*8, DIMENSION(1:9,1:numat_vol) :: ci
!--   internal force
  REAL*8, DIMENSION(1:3*numnp) :: r_in
!--   displacement vector
  REAL*8, DIMENSION(1:3*numnp) :: d
!--   CSTet stress
  REAL*8, DIMENSION(1:numcstet) :: s11, s22, s33, s12, s23, s13
!--   connectivity table for CSTet  
  INTEGER, DIMENSION(1:4,1:numcstet) :: lmcstet
!--   mat number for CSTet element
  INTEGER, DIMENSION(1:numcstet) :: matcstet
!---- Local variables
!--   node numbers
  INTEGER :: n1,n2,n3,n4
!--   x, y, and z displacements of nodes
  REAL*8 :: u1,u2,u3,u4,v1,v2,v3,v4,w1,w2,w3,w4
!--   6*volume, inverse(6*volume),  and the volume      
  REAL*8 :: vx6, vx6inv, vol
!--   spacial derivatives
  REAL*8 :: b1,b2,b3,b4,b5,b6,b7,b8,b9,b10,b11,b12
!--   strains
  REAL*8 :: e11,e22,e33,e12,e23,e13
!--   coordinate holding variable
  REAL*8 :: x1,x2,x3,x4,y1,y2,y3,y4,z1,z2,z3,z4
!--  Coordinate subtractions
  REAL*8 :: x14, x24, x34, y14, y24, y34, z14, z24, z34
!--  Coordinate subtractions: These are to speed up B calculation
  REAL*8 :: x12, x13, y12, y13, z12, z13
!-- Dummy
  REAL*8 :: c11, c21, c31
!--   dummy and counters
  INTEGER :: i,j,nstart,nend
  INTEGER :: k1n1,k1n2,k1n3,k1n4,k2n1,k2n2,k2n3,k2n4
  INTEGER :: k3n1,k3n2,k3n3,k3n4

  DO i = nstart, nend
     j = matcstet(i)
     
     n1 = lmcstet(1,i)
     n2 = lmcstet(2,i)
     n3 = lmcstet(3,i)
     n4 = lmcstet(4,i)
     
     k3n1 = 3*n1
     k3n2 = 3*n2
     k3n3 = 3*n3
     k3n4 = 3*n4
     
     k2n1 = k3n1 - 1
     k2n2 = k3n2 - 1
     k2n3 = k3n3 - 1
     k2n4 = k3n4 - 1
     
     k1n1 = k3n1 - 2
     k1n2 = k3n2 - 2
     k1n3 = k3n3 - 2
     k1n4 = k3n4 - 2         
     ! k#n# dummy variables replaces:
     u1 = d(k1n1)           ! (3*n1-2)
     u2 = d(k1n2)           ! (3*n2-2)
     u3 = d(k1n3)           ! (3*n3-2)
     u4 = d(k1n4)           ! (3*n4-2)
     v1 = d(k2n1)           ! (3*n1-1)
     v2 = d(k2n2)           ! (3*n2-1)
     v3 = d(k2n3)           ! (3*n3-1)
     v4 = d(k2n4)           ! (3*n4-1)
     w1 = d(k3n1)           ! (3*n1)
     w2 = d(k3n2)           ! (3*n2)
     w3 = d(k3n3)           ! (3*n3)
     w4 = d(k3n4)           ! (3*n4)
     
     x1 = coor(1,n1) ! Node 1, x-coor
     x2 = coor(1,n2) ! Node 2, x-coor
     x3 = coor(1,n3) ! Node 3, x-coor
     x4 = coor(1,n4) ! Node 4, x-coor
     y1 = coor(2,n1) ! Node 1, y-coor
     y2 = coor(2,n2) ! Node 2, y-coor
     y3 = coor(2,n3) ! Node 3, y-coor
     y4 = coor(2,n4) ! Node 4, y-coor
     z1 = coor(3,n1) ! Node 1, z-coor
     z2 = coor(3,n2) ! Node 2, z-coor
     z3 = coor(3,n3) ! Node 3, z-coor
     z4 = coor(3,n4) ! Node 4, z-coor

     x12 = x1 - x2          ! not used in vol. calc
     x13 = x1 - x3          ! not used in vol. calc
     x14 = x1 - x4
     x24 = x2 - x4
     x34 = x3 - x4
     y12 = y1 - y2          ! not used in vol. calc
     y13 = y1 - y3          ! not used in vol. calc
     y14 = y1 - y4
     y24 = y2 - y4
     y34 = y3 - y4
     z12 = z1 - z2          ! not used in vol. calc
     z13 = z1 - z3          ! not used in vol. calc
     z14 = z1 - z4
     z24 = z2 - z4
     z34 = z3 - z4
     
     c11 =    y24*z34 - z24*y34
     c21 = -( x24*z34 - z24*x34 )
     c31 =    x24*y34 - y24*x34
     
     vx6 = -( x14*c11 + y14*c21 + z14*c31 )

     vx6inv = 1.d0 / vx6

! See the maple worksheet 'V3D4.mws' for the derivation of [B]
! NOTE: Factored for a more equivalent/compact form then maple's

     b1  = (y34*z24 - y24*z34) * vx6inv
     b2  = (z34*x24 - z24*x34) * vx6inv
     b3  = (x34*y24 - x24*y34) * vx6inv
     b4  = (y13*z14 - y14*z13) * vx6inv
     b5  = (z13*x14 - z14*x13) * vx6inv
     b6  = (x13*y14 - x14*y13) * vx6inv
     b7  = (y14*z12 - y12*z14) * vx6inv
     b8  = (z14*x12 - z12*x14) * vx6inv
     b9  = (x14*y12 - x12*y14) * vx6inv
     b10 = (y12*z13 - y13*z12) * vx6inv
     b11 = (z12*x13 - z13*x12) * vx6inv
     b12 = (x12*y13 - x13*y12) * vx6inv

! calculate the strain            
!                        [E] = [B]{d}
!  
     e11 = b1*u1 + b4*u2 + b7*u3 + b10*u4
     e22 = b2*v1 + b5*v2 + b8*v3 + b11*v4
     e33 = b3*w1 + b6*w2 + b9*w3 + b12*w4
     e12 = b2*u1 + b1*v1 + b5*u2 + b4*v2 + b8*u3 + b7*v3 + b11*u4 + b10*v4
     e23 = b3*v1 + b2*w1 + b6*v2 + b5*w2 + b9*v3 + b8*w3 + b12*v4 + b11*w4 
     e13 = b3*u1 + b1*w1 + b6*u2 + b4*w2 + b9*u3 + b7*w3 + b12*u4 + b10*w4 

! calculate the stress            -1
!                        [S] = [C]  {E}
!       
     s11(i) = e11*ci(1,j) + e22*ci(2,j) + e33*ci(4,j)
     s22(i) = e11*ci(2,j) + e22*ci(3,j) + e33*ci(5,j)
     s33(i) = e11*ci(4,j) + e22*ci(5,j) + e33*ci(6,j)
     s12(i) = e12*ci(7,j)
     s23(i) = e23*ci(8,j)
     s13(i) = e13*ci(9,j)

! calculate the volume

     vol = vx6 / 6.d0

! ASSEMBLE THE INTERNAL FORCE VECTOR

! local node 1
     r_in(k1n1) = r_in(k1n1) - (s11(i)*b1 + s12(i)*b2 + s13(i)*b3)*vol
     r_in(k2n1) = r_in(k2n1) - (s22(i)*b2 + s12(i)*b1 + s23(i)*b3)*vol
     r_in(k3n1) = r_in(k3n1) - (s33(i)*b3 + s23(i)*b2 + s13(i)*b1)*vol
! local node 2 
     r_in(k1n2) = r_in(k1n2) - (s11(i)*b4 + s12(i)*b5 + s13(i)*b6)*vol
     r_in(k2n2) = r_in(k2n2) - (s22(i)*b5 + s12(i)*b4 + s23(i)*b6)*vol
     r_in(k3n2) = r_in(k3n2) - (s33(i)*b6 + s23(i)*b5 + s13(i)*b4)*vol
! local node 3 
     r_in(k1n3) = r_in(k1n3) - (s11(i)*b7 + s12(i)*b8 + s13(i)*b9 )*vol
     r_in(k2n3) = r_in(k2n3) - (s22(i)*b8 + s12(i)*b7 + s23(i)*b9 )*vol
     r_in(k3n3) = r_in(k3n3) - (s33(i)*b9 + s23(i)*b8 + s13(i)*b7 )*vol
! local node 4
     r_in(k1n4) = r_in(k1n4) - (s11(i)*b10 + s12(i)*b11 + s13(i)*b12 )*vol
     r_in(k2n4) = r_in(k2n4) - (s22(i)*b11 + s12(i)*b10 + s23(i)*b12 )*vol
     r_in(k3n4) = r_in(k3n4) - (s33(i)*b12 + s23(i)*b11 + s13(i)*b10 )*vol

     x1 = coor(1,n1) + u1
     x2 = coor(1,n2) + u2
     x3 = coor(1,n3) + u3
     x4 = coor(1,n4) + u4
     y1 = coor(2,n1) + v1
     y2 = coor(2,n2) + v2
     y3 = coor(2,n3) + v3
     y4 = coor(2,n4) + v4
     z1 = coor(3,n1) + w1
     z2 = coor(3,n2) + w2
     z3 = coor(3,n3) + w3
     z4 = coor(3,n4) + w4
     
     x14 = x1 - x4
     x24 = x2 - x4
     x34 = x3 - x4
     y14 = y1 - y4
     y24 = y2 - y4
     y34 = y3 - y4
     z14 = z1 - z4
     z24 = z2 - z4
     z34 = z3 - z4
     
     c11 =    y24*z34 - z24*y34
     c21 = -( x24*z34 - z24*x34 )
     c31 =    x24*y34 - y24*x34
     
     vx6 = -( x14*c11 + y14*c21 + z14*c31 )

     IF(vx6.LT.0.d0) THEN
        print*,'DEFORMED VOLUME TURNED NEGATIVE'
        stop
     ENDIF

  ENDDO
  RETURN
END SUBROUTINE v3d4