ZN_gen_grid.f90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!
! ---------------------------------------------------------------------------
!
!   SUBROUTINE  : ZN_gen_grid
!
!   purpose     : grid generation  
!
!   Authors          :  P. Loner
!
!   Creation Date    :  Sep. 3, 2002
!
!   Modifications    :
!
!    No.     Date         Authors       Description
!     1    09/03/02       K. Tang       Global variables G_ZN
!
! ---------------------------------------------------------------------------
!
!
!   arguments   :
!
!      G_ZN     : Global variables for Rocburn_1D_ZN
!      gridtype : = 1  expoential grid 
!                 = 2  boundary layer grid
!      numx     : maximum number of grid points
!      beta     : stretch parameter 
!      xmax     : the maximum dimension in x-coordinate
!      x        : the x-coordinate array
!      z        : the z-coordinate arary
!      zx       : the first derivative of z
!      zxx      : the second derivative of z 
!      delz     : the z spacing
!                                 
! ---------------------------------------------------------------------------
!
  SUBROUTINE zn_gen_grid(G_ZN, gridtype, numx, x, z, zx, zxx)

    USE m_rocburn_zn_global_data

    IMPLICIT NONE
    include 'mpif.h'

    TYPE (g_burn_1d), POINTER :: g_zn
    INTEGER, INTENT(IN) :: gridtype, numx
    REAL(DBL), INTENT (OUT) :: x(:), z(:), zx(:), zxx(:)
!
!
! ---------------------------------------------------------------------------
!   local variables

    REAL(DBL) :: bpm,bp1,bm1,czx,czxx,term,term2
    INTEGER :: i

! ---------------------------------------------------------------------------
    IF(g_zn%xmax >= 0.0) then
         print *,' ROCBURN_ZN: rank=',g_zn%rank,' xmax >= 0'
         print *,' ROCBURN_ZN: job aborted!'
         stop
    END IF

    IF(numx.gt.(g_zn%nxmax)) then
      print *,' ROCBURN_ZN: rankk=',g_zn%rank,' numx=',numx, &
              ' nxmax=',g_zn%nxmax
      print *,' ROCBURN_ZN: nx > maximum number of', &
              ' allowed spatial nodes'
      print *,' ROCBURN_ZN: job aborted!'
      stop
    END IF

    g_zn%delz = 1.0/dble(numx-1)

    IF(g_zn%rank ==0) THEN
      print *,' ROCBURN_ZN: delz=',g_zn%delz
      print *,' ROCBURN_ZN: nxmax=',g_zn%nxmax
    END IF

    IF (gridtype == 1) THEN
!
!     exponential grid
!

      DO i=1,numx
        z(i) = dble(i-1)*g_zn%delz
        x(i) = log(1.-z(i))/g_zn%beta
        IF (i.eq.numx) THEN
            x(i) = -10.
        END IF
        zx(i)  = -g_zn%beta*exp(g_zn%beta*x(i))
        zxx(i) = -g_zn%beta**2*exp(g_zn%beta*x(i))
      END DO ! i

    ELSE
!
!     Anderson, Tanehill and Pletcher boundary layer grid control
!

      bp1=g_zn%beta+1.0
      bm1=g_zn%beta-1.0
      bpm=bp1/bm1
      czx=2.0*g_zn%beta/log(bpm)/g_zn%xmax
      czxx=-2.0/g_zn%xmax*czx

      DO i=1,numx
        z(i)=dble(i-1)*g_zn%delz
        term=bpm**(1.0-z(i))
        x(i)=g_zn%xmax*(bp1-bm1*term)/(term+1.0)
        term2=g_zn%beta**2-(1.0-x(i)/g_zn%xmax)**2
        zx(i)=czx/term2
        zxx(i)= czxx*(1.0-x(i)/g_zn%xmax)/term2**2
      END DO ! i

    END IF

    IF(g_zn%rank == 0) THEN
       WRITE (*,*)
       WRITE (*,*)' ROCBURN_ZN: Smallest delta x = ',x(1)-x(2)
       WRITE (*,*)' ROCBURN_ZN: Largest delta x  = ',x(numx-1)-x(numx)
       WRITE (*,*)
    END IF

    RETURN

  END SUBROUTINE zn_gen_grid