WriteTecplotAscii.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: write grid (and solution) data to plot file in ASCII format.
!
! Description: none.
!
! Input: iReg     = region number
!        iLev     = grid level
!        plotType = 1 - grid + smoke only, = 2 - grid + all fields
!        region   = region data (dimensions, flow variables)
!
! Output: to plot file.
!
! Notes: none.
!
!******************************************************************************
!
! $Id: WriteTecplotAscii.F90,v 1.3 2008/12/06 08:45:08 mtcampbe Exp $
!
! Copyright: (c) 2003 by the University of Illinois
!
!******************************************************************************

SUBROUTINE writetecplotascii( iReg,iLev,plotType,region )

  USE moddatatypes
  USE moderror
  USE moddatastruct, ONLY : t_region
  USE modglobal, ONLY     : t_global
  USE rflo_modinterfacespost, ONLY : rflo_getdimensphysnodes, &
                                     rflo_getnodeoffset, &
                                     rflo_getcelloffset, aver, averdiv
  USE modmpi
  USE modparameters
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  INTEGER :: ireg, ilev, plottype

  TYPE(t_region) :: region

! ... loop variables
  INTEGER :: i, j, k, ipeul

! ... local variables
  CHARACTER(CHRLEN+4) :: fname
  CHARACTER(256)      :: varstr
  CHARACTER(16)       :: concstr

  INTEGER :: ipnbeg, ipnend, jpnbeg, jpnend, kpnbeg, kpnend
  INTEGER :: icoff, ijcoff, inoff, ijnoff, ijkn, cell(8), errorflag, npeul

  REAL(RFREAL)          :: rho, u, v, w, press, temp, mach, c, qq
  REAL(RFREAL), POINTER :: xyz(:,:), cv(:,:), dv(:,:), tv(:,:), gv(:,:)
  REAL(RFREAL), POINTER :: peulcv(:,:), conc(:)

  TYPE(t_global), POINTER :: global

!******************************************************************************

  global => region%global

  CALL registerfunction( global,'WriteTecplotAscii',&
  'WriteTecplotAscii.F90' )

! set parameters --------------------------------------------------------------

  CALL rflo_getdimensphysnodes( region,ilev,ipnbeg,ipnend, &
                                jpnbeg,jpnend,kpnbeg,kpnend )
  CALL rflo_getcelloffset( region,ilev,icoff,ijcoff )
  CALL rflo_getnodeoffset( region,ilev,inoff,ijnoff )

  npeul = region%levels(ilev)%peul%nCv

  IF (npeul > 0) ALLOCATE( conc(npeul),stat=errorflag )

  global%error = errorflag
  IF (global%error /= 0) CALL errorstop( global,err_allocate,__line__ )

! open file and write the header ----------------------------------------------

  IF (ireg == 1) THEN
    WRITE(fname,'(A,ES11.5,A)') &
       trim(global%casename)//'.peul_',global%currentTime,'.dat'
    OPEN(if_plot,file=fname,status='unknown',form='formatted',iostat=errorflag)
    global%error = errorflag
    IF (global%error /= 0) CALL errorstop( global,err_file_open,__line__,fname )

    IF (global%flowType == flow_steady) THEN
      WRITE(if_plot,1000,err=10) trim(global%casename),global%currentIter
    ELSE
      IF (global%currentTime <= 0._rfreal) THEN
        WRITE(if_plot,1005,err=10) trim(global%casename),global%timeStamp
      ELSE
        WRITE(if_plot,1005,err=10) trim(global%casename),global%currentTime
      ENDIF
    ENDIF

    varstr = 'x y z'
    IF (plottype == plot_grid_flow) varstr = 'x y z rho u v w p T M'

    DO ipeul=1,npeul
      SELECT CASE (ipeul)
      CASE ( 0: 9)
        WRITE(concstr,'(A,I1)') 'c_', ipeul
      CASE (10:99)
        WRITE(concstr,'(A,I2)') 'c_', ipeul
      CASE default
        WRITE(concstr,'(A)') 'c_?'
      END SELECT ! iPeul
      varstr = trim(varstr)//' '//trim(concstr)
    ENDDO ! iPeul

    WRITE(if_plot,1010,err=10) trim(varstr)

  ENDIF   ! iReg=1

! write zone header

  WRITE(if_plot,1015) ireg,ipnend-ipnbeg+1,jpnend-jpnbeg+1,kpnend-kpnbeg+1

! write data ------------------------------------------------------------------
! pointer to variables

  xyz => region%levels(ilev)%grid%xyz
  cv  => region%levels(ilev)%mixt%cv
  dv  => region%levels(ilev)%mixt%dv
  tv  => region%levels(ilev)%mixt%tv
  gv  => region%levels(ilev)%mixt%gv
  IF (npeul > 0) peulcv => region%levels(ilev)%peul%cv

  DO k=kpnbeg,kpnend
    DO j=jpnbeg,jpnend
      DO i=ipnbeg,ipnend
        ijkn = indijk(i,j,k,inoff,ijnoff)
        cell(1) = indijk(i  ,j  ,k  ,icoff,ijcoff)
        cell(2) = indijk(i-1,j  ,k  ,icoff,ijcoff)
        cell(3) = indijk(i  ,j-1,k  ,icoff,ijcoff)
        cell(4) = indijk(i-1,j-1,k  ,icoff,ijcoff)
        cell(5) = indijk(i  ,j  ,k-1,icoff,ijcoff)
        cell(6) = indijk(i-1,j  ,k-1,icoff,ijcoff)
        cell(7) = indijk(i  ,j-1,k-1,icoff,ijcoff)
        cell(8) = indijk(i-1,j-1,k-1,icoff,ijcoff)

        DO ipeul=1,npeul
          conc(ipeul) = aver(cell,ipeul,peulcv)
        ENDDO

        IF (plottype == plot_grid_only) THEN

! ------- write grid coordinates and smoke fields only

          WRITE(if_plot,1020,err=10) xyz(xcoord,ijkn), &
                                     xyz(ycoord,ijkn), &
                                     xyz(zcoord,ijkn), &
                                     (conc(ipeul),ipeul=1,npeul)

        ELSE

! ------- write grid and all fields

          rho   = aver(cell,cv_mixt_dens,cv)
          u     = averdiv(cell,cv_mixt_xmom,cv,cv_mixt_dens,cv)
          v     = averdiv(cell,cv_mixt_ymom,cv,cv_mixt_dens,cv)
          w     = averdiv(cell,cv_mixt_zmom,cv,cv_mixt_dens,cv)
          press = aver(cell,dv_mixt_pres,dv)
          temp  = aver(cell,dv_mixt_temp,dv)
          c     = aver(cell,dv_mixt_soun,dv)
          qq    = u*u + v*v + w*w
          mach  = sqrt(qq)/c

          WRITE(if_plot,1020,err=10) xyz(xcoord,ijkn), &
                                     xyz(ycoord,ijkn), &
                                     xyz(zcoord,ijkn), &
                                     rho,u,v,w,press,temp,mach, &
                                     (conc(ipeul),ipeul=1,npeul)

        ENDIF ! plotType

      ENDDO
    ENDDO
  ENDDO

! close file, handle errors ---------------------------------------------------

  IF (ireg == global%nRegions) THEN
    CLOSE(if_plot,iostat=errorflag)
    global%error = errorflag
    IF (global%error /= 0) &
      CALL errorstop( global,err_file_close,__line__,fname )
  ENDIF

  IF (npeul > 0) DEALLOCATE( conc,stat=errorflag )

  global%error = errorflag
  IF (global%error /= 0) CALL errorstop( global,err_deallocate,__line__ )

  CALL deregisterfunction( global )
  goto 999

10   CONTINUE
  CALL errorstop( global,err_file_write,__line__,fname )

! formats ---------------------------------------------------------------------

1000 FORMAT('TITLE="',a,'. Iteration: ',i8,'."')
1005 FORMAT('TITLE="',a,'. Time: ',es11.5,'."')
1010 FORMAT('VARIABLES= ',a)
1015 FORMAT('ZONE T="',i5.5,'", I=',i6,', J=',i6,', K=',i6,', F=POINT')
1020 FORMAT(999(1x,es13.6))

999  CONTINUE
END SUBROUTINE writetecplotascii

!******************************************************************************
!
! RCS Revision history:
!
! $Log: WriteTecplotAscii.F90,v $
! Revision 1.3  2008/12/06 08:45:08  mtcampbe
! Updated license.
!
! Revision 1.2  2008/11/19 22:18:18  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.1  2004/12/01 22:29:09  fnajjar
! Initial revision after changing case
!
! Revision 1.2  2004/03/02 21:50:57  jferry
! Added timestamp to name of peulpost output file
!
! Revision 1.1  2003/09/25 15:40:22  jferry
! Implented Rocsmoke post-processing
!
!******************************************************************************