TURB_rFLU_WriteSolutionBinary.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
! ******************************************************************************
!
! Purpose: Write solution file for turbulence in binary ROCFLU format.
!
! Description: None.
!
! Input: region = Pointer to region
!
! Output: None.
!
! Notes: None. 
!
! ******************************************************************************
!
! $Id: TURB_rFLU_WriteSolutionBinary.F90,v 1.5 2008/12/06 08:44:45 mtcampbe Exp $
!
! Copyright: (c) 2004 by the University of Illinois
!
! ******************************************************************************

SUBROUTINE turb_rflu_writesolutionbinary( region ) ! PUBLIC

  USE moddatatypes
  USE modglobal, ONLY    : t_global
  USE moddatastruct, ONLY: t_region 
  USE modgrid, ONLY      : t_grid
  USE moderror
  USE modmpi
  USE modparameters
  
  USE modbuildfilenames, ONLY: buildfilenamesteady, & 
                               buildfilenameunsteady  
  
  USE turb_modparameters

  IMPLICIT NONE
  
! ... arguments
  TYPE(t_region), POINTER :: region  

! ... loop variables
  INTEGER :: i, j
   
! ... local variables
  CHARACTER(CHRLEN) :: ifilename,sectionstring,rcsidentstring
  TYPE(t_grid),   POINTER :: grid
  TYPE(t_global), POINTER :: global

  INTEGER :: errorflag,ifile,nvars
  REAL(RFREAL) :: currenttime
  REAL(RFREAL), DIMENSION(:,:), POINTER :: tv, tcv, vort
  REAL(RFREAL), DIMENSION(:),   POINTER :: lens
  
! ******************************************************************************
! Start, open file
! ******************************************************************************

  rcsidentstring = '$RCSfile: TURB_rFLU_WriteSolutionBinary.F90,v $ $Revision: 1.5 $'

  global => region%global

  CALL registerfunction(global,'TURB_RFLU_WriteSolutionBinary',&
  'TURB_rFLU_WriteSolutionBinary.F90')

  IF ( global%myProcid == masterproc .AND. &
       global%verbLevel > verbose_none ) THEN 
    WRITE(stdout,'(A,1X,A)') solver_name,'Writing binary turbulence file...'
  END IF ! global%verbLevel

  IF ( global%flowType == flow_unsteady ) THEN
    CALL buildfilenameunsteady(global,filedest_outdir,'.turbb', & 
                               region%iRegionGlobal,global%currentTime, & 
                               ifilename)

    IF ( global%myProcid == masterproc .AND. &
         global%verbLevel > verbose_none ) THEN                                             
      WRITE(stdout,'(A,3X,A,1X,I5.5)') solver_name,'Global region:', & 
                                       region%iRegionGlobal
      WRITE(stdout,'(A,3X,A,1X,1PE11.5)') solver_name,'Current time:', & 
                                          global%currentTime  
    END IF ! global%verbLevel
  ELSE
    CALL buildfilenamesteady(global,filedest_outdir,'.turbb', & 
                             region%iRegionGlobal,global%currentIter,ifilename)  

    IF ( global%myProcid == masterproc .AND. &
         global%verbLevel > verbose_none ) THEN                                      
      WRITE(stdout,'(A,3X,A,1X,I5.5)') solver_name,'Global region:', & 
                                       region%iRegionGlobal  
      WRITE(stdout,'(A,3X,A,1X,I6.6)') solver_name,'Current iteration '// &
                                       'number:',global%currentIter             
    END IF ! global%verbLevel
  ENDIF ! global%flowType

  ifile = if_solut
  OPEN(ifile,file=ifilename,form="FORMATTED",status="UNKNOWN", & 
       iostat=errorflag)
  global%error = errorflag          
  IF ( global%error /= err_none ) THEN 
    CALL errorstop(global,err_file_open,__line__,ifilename)
  END IF ! global%error  

! ==============================================================================
! Header and general information
! ==============================================================================

  IF ( global%myProcid == masterproc .AND. &
       global%verbLevel > verbose_low ) THEN  
    WRITE(stdout,'(A,3X,A)') solver_name,'Header information...'
  END IF ! global%verbLevel

  sectionstring = '# ROCTURB solution file'
  WRITE(ifile) sectionstring
  
  sectionstring = '# Precision and range'
  WRITE(ifile) sectionstring
  WRITE(ifile) precision(1.0_rfreal),range(1.0_rfreal)

  sectionstring = '# Initial residual'
  WRITE(ifile) sectionstring
  WRITE(ifile) global%resInit
  
  sectionstring = '# Physical time'
  WRITE(ifile) sectionstring
  WRITE(ifile) global%currentTime 
  
  sectionstring = '# Esg1Sum'
  WRITE(ifile) sectionstring
  WRITE(ifile) global%esg1Sum
  
  sectionstring = '# Esg4Sum'
  WRITE(ifile) sectionstring
  WRITE(ifile) global%esg4Sum

! ==============================================================================
! Dimensions
! ==============================================================================
  
  nvars = region%turbInput%nOutField
  
  grid => region%grid  
  
  sectionstring = '# Dimensions'
  WRITE(ifile) sectionstring
  WRITE(ifile) grid%nCellsTot,nvars 
  
! ==============================================================================
! Eddy viscosity
! ==============================================================================

  IF ( global%myProcid == masterproc .AND. &
       global%verbLevel > verbose_low ) THEN 
    WRITE(stdout,'(A,3X,A)') solver_name,'Eddy viscosity...'
  END IF ! global%verbLevel

  sectionstring = '# Eddy viscosity'
  WRITE(ifile) sectionstring

  IF (region%turbInput%modelClass == model_les) THEN
    tv => region%mixt%tv
    WRITE(ifile) (tv(tv_mixt_muet,j),j=1,grid%nCellsTot)
  ELSEIF (region%turbInput%modelClass == model_rans) THEN
    tcv => region%turb%cv
    WRITE(ifile) (tcv(cv_sa_nutil,j),j=1,grid%nCellsTot)
  ENDIF

! ==============================================================================
! Total vorticity
! ==============================================================================

  IF ( nvars > 1 ) THEN
    IF ( global%myProcid == masterproc .AND. &
         global%verbLevel > verbose_low ) THEN  
      WRITE(stdout,'(A,3X,A)') solver_name,'Total vorticity...'
    END IF ! global%verbLevel

    sectionstring = '# Total vorticity'
    WRITE(ifile) sectionstring
      
    vort => region%turb%vort
    WRITE(ifile) (sqrt( vort(xcoord,j)**2 + &
                        vort(ycoord,j)**2 + &
                        vort(zcoord,j)**2 ),j=1,grid%nCellsTot)
  ENDIF 
 
! ==============================================================================
! RaNS or DES length scale
! ==============================================================================

  IF ( nvars > 2 ) THEN
    IF (region%turbInput%modelClass == model_rans) THEN

      IF ( global%myProcid == masterproc .AND. &
           global%verbLevel > verbose_low ) THEN  
        WRITE(stdout,'(A,3X,A)') solver_name,'Model length scale...'
      END IF ! global%verbLevel

      sectionstring = '# RANS length scale'
      WRITE(ifile) sectionstring
      
      lens => region%turb%lens
      WRITE(ifile) (lens(j),j=1,grid%nCellsTot)
    ENDIF                                      
  ENDIF 
  
! ==============================================================================
! End marker
! ==============================================================================

  IF ( global%myProcid == masterproc .AND. &
       global%verbLevel > verbose_low ) THEN  
    WRITE(stdout,'(A,3X,A)') solver_name,'End marker...'
  END IF ! global%verbLevel

  sectionstring = '# End'
  WRITE(ifile) sectionstring  

! ==============================================================================
! Close file
! ==============================================================================

  CLOSE(ifile,iostat=errorflag)
  global%error = errorflag      
  IF ( global%error /= err_none ) THEN 
    CALL errorstop(global,err_file_close,__line__,ifilename)
  END IF ! global%error
   
  IF ( global%myProcid == masterproc .AND. &
       global%verbLevel > verbose_none ) THEN   
    WRITE(stdout,'(A,1X,A)') solver_name,'Writing binary flow file done.'
  END IF ! global%verbLevel

  CALL deregisterfunction(global)
    
! ******************************************************************************
! End
! ******************************************************************************
 
END SUBROUTINE turb_rflu_writesolutionbinary


! ******************************************************************************
!
! RCS Revision history:
!
! $Log: TURB_rFLU_WriteSolutionBinary.F90,v $
! Revision 1.5  2008/12/06 08:44:45  mtcampbe
! Updated license.
!
! Revision 1.4  2008/11/19 22:17:57  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.3  2006/01/10 07:18:10  wasistho
! fixed screen print vort to lengthscale
!
! Revision 1.2  2004/06/16 20:01:34  haselbac
! Added use of ModBuildFileNames, cosmetics
!  
! Revision 1.1  2004/03/27 02:19:15  wasistho  
! added routines specific for Rocflu           
!
! ******************************************************************************