TURB_rFLU_ReadSolutionASCII.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
! ******************************************************************************
!
! Purpose: Read file for turbulence quantities in ASCII ROCFLU format.
!
! Description: None.
!
! Input: pRegion = Pointer to region
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************
!
! $Id: TURB_rFLU_ReadSolutionASCII.F90,v 1.6 2009/08/26 12:28:53 mtcampbe Exp $
!
! Copyright: (c) 2004 by the University of Illinois
!
! ******************************************************************************

SUBROUTINE turb_rflu_readsolutionascii( region ) ! PUBLIC

  USE moddatatypes
  USE modglobal, ONLY    : t_global
  USE moddatastruct, ONLY: t_region 
  USE modgrid, ONLY      : t_grid
  USE moderror
  USE modmpi
  USE modparameters
  
  USE modbuildfilenames, ONLY: buildfilenamesteady, & 
                               buildfilenameunsteady  
  
  USE turb_modparameters

  IMPLICIT NONE
  
! ... arguments
  TYPE(t_region), POINTER :: region  

! ... loop variables
  INTEGER :: ivars, j
   
! ... local variables
  CHARACTER(CHRLEN) :: errorstring,ifilename,sectionstring,rcsidentstring, & 
                       timestring1,timestring2
  TYPE(t_grid),   POINTER :: grid
  TYPE(t_global), POINTER :: global

  INTEGER :: errorflag,ifile,loopcounter,ncellstot,ncellsexpected,nvars, &
             nvarsexpected,precactual,precexpected,rangeactual,rangeexpected
  REAL(RFREAL) :: currenttime
  REAL(RFREAL), DIMENSION(:,:), POINTER :: tv, tcv, vort
  REAL(RFREAL), DIMENSION(:),   POINTER :: lens
  
! ******************************************************************************
! Start, open file
! ******************************************************************************

  rcsidentstring = '$RCSfile: TURB_rFLU_ReadSolutionASCII.F90,v $ $Revision: 1.6 $'

  global => region%global
  CALL registerfunction(global,'TURB_RFLU_ReadSolutionASCII',&
  'TURB_rFLU_ReadSolutionASCII.F90')

#ifdef GENX
  goto 999    ! Genx doesn't need to read turbulence solution file
#endif

  IF ( global%myProcid == masterproc .AND. &
       global%verbLevel > verbose_none ) THEN 
    WRITE(stdout,'(A,1X,A)') solver_name,'Reading ASCII turbulence file...'
  END IF ! global%verbLevel

  IF ( global%flowType == flow_unsteady ) THEN
    currenttime = global%currentTime

    CALL buildfilenameunsteady(global,filedest_indir,'.turba', & 
                               region%iRegionGlobal,currenttime,ifilename)

    IF ( global%myProcid == masterproc .AND. & 
         global%verbLevel > verbose_none ) THEN                                         
      WRITE(stdout,'(A,3X,A,1X,I5.5)') solver_name,'Global region:', & 
                                       region%iRegionGlobal  
      WRITE(stdout,'(A,3X,A,1X,1PE11.5)') solver_name,'Current time:', & 
                                          currenttime 
    END IF ! global%verbLevel                                       
  ELSE
    CALL buildfilenamesteady(global,filedest_indir,'.turba', & 
                             region%iRegionGlobal,global%currentIter,ifilename)  
  
    IF ( global%myProcid == masterproc .AND. & 
         global%verbLevel > verbose_none ) THEN 
      WRITE(stdout,'(A,3X,A,1X,I5.5)') solver_name,'Global region:', & 
                                       region%iRegionGlobal  
      WRITE(stdout,'(A,3X,A,1X,I6.6)') solver_name,'Current iteration '// & 
                                       'number:',global%currentIter
    END IF ! global%verbLevel                              
  ENDIF ! global%flowType

  ifile = if_solut
  OPEN(ifile,file=ifilename,form="FORMATTED",status="OLD", & 
       iostat=errorflag)   
  global%error = errorflag       
  IF ( global%error /= err_none ) THEN 
    CALL errorstop(global,err_file_open,__line__,ifilename)
  END IF ! global%error  

! ==============================================================================
! Header and general information
! ==============================================================================

  IF ( global%myProcid == masterproc .AND. & 
       global%verbLevel > verbose_low ) THEN  
    WRITE(stdout,'(A,3X,A)') solver_name,'Header information...'
  END IF ! global%verbLevel

  READ(ifile,'(A)') sectionstring
  IF ( trim(sectionstring) /= '# ROCTURB solution file' ) THEN 
    CALL errorstop(global,err_invalid_marker,__line__,sectionstring) 
  END IF ! TRIM  
  
! -----------------------------------------------------------------------------
! Precision and range
! -----------------------------------------------------------------------------
    
  READ(ifile,'(A)') sectionstring
  IF ( trim(sectionstring) /= '# Precision and range' ) THEN 
    CALL errorstop(global,err_invalid_marker,__line__,sectionstring) 
  END IF ! TRIM  
  
  precexpected  = precision(1.0_rfreal)
  rangeexpected = range(1.0_rfreal)
  
  READ(ifile,'(2(I8))') precactual,rangeactual
  IF ( precactual < precexpected .OR. rangeactual < rangeexpected ) THEN 
    CALL errorstop(global,err_prec_range,__line__)
  END IF ! precActual
  
! -----------------------------------------------------------------------------
! Initial residual (for RaNS), physical time, and energy subgrid quantities
! -----------------------------------------------------------------------------
  
  READ(ifile,'(A)') sectionstring
  IF ( trim(sectionstring) /= '# Initial residual' ) THEN 
    CALL errorstop(global,err_invalid_marker,__line__,ifilename)
  END IF ! TRIM  
  
  READ(ifile,'(E23.16)') global%resInit
  
  READ(ifile,'(A)') sectionstring
  IF ( trim(sectionstring) /= '# Physical time' ) THEN 
    CALL errorstop(global,err_invalid_marker,__line__,ifilename)
  END IF ! TRIM    
   
  READ(ifile,'(E23.16)') currenttime 

  IF ( global%flowType == flow_unsteady ) THEN
    IF ( global%currentTime < 0.0_rfreal ) THEN
      global%currentTime = currenttime
    ELSE
      WRITE(timestring1,'(1PE11.5)') global%currentTime
      WRITE(timestring2,'(1PE11.5)') currenttime          
      IF ( trim(timestring1) /= trim(timestring2) ) THEN
        CALL errorstop(global,err_time_solution,__line__,trim(ifilename))
      END IF ! global%currentTime 
    END IF ! global%currentTime
  END IF ! global%flowType  
  
  READ(ifile,'(A)') sectionstring
  IF ( trim(sectionstring) /= '# Esg1Sum' ) THEN 
    CALL errorstop(global,err_invalid_marker,__line__,ifilename)
  END IF ! TRIM    
   
  READ(ifile,'(E23.16)') global%esg1Sum
  
  READ(ifile,'(A)') sectionstring
  IF ( trim(sectionstring) /= '# Esg4Sum' ) THEN 
    CALL errorstop(global,err_invalid_marker,__line__,ifilename)
  END IF ! TRIM    
   
  READ(ifile,'(E23.16)') global%esg4Sum
  
! ==============================================================================
! Dimensions
! ==============================================================================
  
  grid => region%grid  
  
  nvarsexpected  = region%turbInput%nOutField
  ncellsexpected = grid%nCellsTot    
  
  READ(ifile,'(A)') sectionstring
  IF ( trim(sectionstring) /= '# Dimensions' ) THEN 
    CALL errorstop(global,err_invalid_marker,__line__,sectionstring) 
  END IF ! TRIM
  
  READ(ifile,'(2(I8))') ncellstot,nvars
  IF ( ncellstot /= ncellsexpected ) THEN 
    WRITE(errorstring,'(A,1X,I6,1X,A,1X,I6))') 'Specified:',ncellstot, & 
                                               'but expected:',ncellsexpected
    CALL errorstop(global,err_invalid_ncells,__line__,errorstring)
  END IF ! nCellsExpected     
  
  IF ( nvars /= nvarsexpected ) THEN 
    WRITE(errorstring,'(A,1X,I6,1X,A,1X,I6))') 'Specified:',nvars, & 
                                               'but expected:',nvarsexpected  
    CALL errorstop(global,err_invalid_nvars,__line__)
  END IF ! nVarsExpected   
  
! ==============================================================================
! Rest of file
! ==============================================================================

  ivars       = 0
  loopcounter = 0

  DO ! set up infinite loop
    loopcounter = loopcounter + 1
  
    READ(ifile,'(A)') sectionstring

    SELECT CASE ( trim(sectionstring) ) 

! ------------------------------------------------------------------------------
!   Eddy viscosity
! ------------------------------------------------------------------------------

      CASE ( '# Eddy viscosity' )
        IF ( global%myProcid == masterproc .AND. &
             global%verbLevel > verbose_low ) THEN  
          WRITE(stdout,'(A,3X,A)') solver_name,'Eddy viscosity...'
        END IF ! global%verbLevel    

        IF (region%turbInput%modelClass == model_les) THEN
          tv => region%mixt%tv
      
          ivars = ivars + 1
          READ(ifile,'(5(E23.16))') (tv(tv_mixt_muet,j),j=1,grid%nCellsTot)

          IF (ASSOCIATED( region%turb%postv ) .eqv. .true.) THEN
            region%turb%postv(1,:) = tv(tv_mixt_muet,:)
          ENDIF
        ELSEIF (region%turbInput%modelClass == model_rans) THEN
          tcv => region%turb%cv
      
          ivars = ivars + 1
          READ(ifile,'(5(E23.16))') (tcv(cv_sa_nutil,j),j=1,grid%nCellsTot)

          IF (ASSOCIATED( region%turb%postv ).eqv. .true.) THEN
            region%turb%postv(1,:) = tcv(cv_sa_nutil,:)
          ENDIF
        ENDIF

! ------------------------------------------------------------------------------
!   Total vorticity
! ------------------------------------------------------------------------------

      CASE ( '# Total vorticity' ) 
        IF ( global%myProcid == masterproc .AND. & 
             global%verbLevel > verbose_low ) THEN  
          WRITE(stdout,'(A,3X,A)') solver_name,'Total vorticity...'
        END IF ! global%verbLevel         
      
        vort => region%turb%vort
      
        ivars = ivars + 1      
        READ(ifile,'(5(E23.16))') (vort(xcoord,j),j=1,grid%nCellsTot)

! ------------------------------------------------------------------------------
!   RaNS or DES length scale
! ------------------------------------------------------------------------------

      CASE ( '# RANS length scale' ) 
        IF ( global%myProcid == masterproc .AND. & 
             global%verbLevel > verbose_low ) THEN  
          WRITE(stdout,'(A,3X,A)') solver_name,'RaNS length scale...'
        END IF ! global%verbLevel          
      
        lens => region%turb%lens
      
        ivars = ivars + 1      
        READ(ifile,'(5(E23.16))') (lens(j),j=1,grid%nCellsTot)

        IF (ASSOCIATED( region%turb%postv ) .eqv. .true.) THEN
          region%turb%postv(2,:) = lens(:)
        ENDIF

! ------------------------------------------------------------------------------
!     End marker
! ------------------------------------------------------------------------------ 
      
      CASE ( '# End' ) 
        IF ( global%myProcid == masterproc .AND. & 
             global%verbLevel > verbose_low ) THEN  
          WRITE(stdout,'(A,3X,A)') solver_name,'End marker...'
        END IF ! global%verbLevel           
      
        EXIT
      
! ------------------------------------------------------------------------------
!     Invalid section string
! ------------------------------------------------------------------------------ 
      
      CASE default
        IF ( global%verbLevel > verbose_low ) THEN  
          WRITE(stdout,'(A,3X,A)') solver_name,sectionstring
        END IF ! verbosityLevel           
      
        CALL errorstop(global,err_invalid_marker,__line__,sectionstring)        
             
    END SELECT ! TRIM
  
! ------------------------------------------------------------------------------
!   Guard against infinite loop - might be unnecessary because of read errors?
! ------------------------------------------------------------------------------  
  
    IF ( loopcounter >= limit_infinite_loop ) THEN 
      CALL errorstop(global,err_infinite_loop,__line__)
    END IF ! loopCounter
  
  END DO ! <empty>

! ==============================================================================
! Check and information about number of variables read
! ==============================================================================

  IF ( ivars /= nvars ) THEN 
    CALL errorstop(global,err_invalid_nvars,__line__)
  END IF ! iVar

! ==============================================================================
! Close file
! ==============================================================================

  CLOSE(ifile,iostat=errorflag)   
  global%error = errorflag   
  IF ( global%error /= err_none ) THEN 
    CALL errorstop(global,err_file_close,__line__,ifilename)
  END IF ! global%error
   
  IF ( global%myProcid == masterproc .AND. & 
       global%verbLevel > verbose_none ) THEN   
    WRITE(stdout,'(A,1X,A)') solver_name,'Reading ASCII turbulence file done.'
  END IF ! global%verbLevel

! finalize --------------------------------------------------------------------

999  CONTINUE

  CALL deregisterfunction(global)
    
! ******************************************************************************
! End
! ******************************************************************************
 
END SUBROUTINE turb_rflu_readsolutionascii


! ******************************************************************************
!
! RCS Revision history:
!
! $Log: TURB_rFLU_ReadSolutionASCII.F90,v $
! Revision 1.6  2009/08/26 12:28:53  mtcampbe
! Ported to Hera.   Fixed logical expression syntax errors.  Replaced all
! IF (logical_variable)  with IF (logical_variable .eqv. .true.) as
! consistent with the specification.  Also changed: IF( ASSOCIATED(expr) )
! to IF ( ASSOCIATED(expr) .eqv. .true. ).   Intel compilers produce code
! which silently fails for some mal-formed expressions, so these changes
! are a net which should ensure that they are evaluated as intended.
!
! Revision 1.5  2008/12/06 08:44:45  mtcampbe
! Updated license.
!
! Revision 1.4  2008/11/19 22:17:56  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.3  2006/01/12 09:44:09  wasistho
! copy to postv
!
! Revision 1.2  2004/06/16 20:01:30  haselbac
! Added use of ModBuildFileNames, cosmetics
!    
! Revision 1.1  2004/03/27 02:19:15  wasistho  
! added routines specific for Rocflu           
!
! ******************************************************************************