TURB_rFLO_RansAllocDataBuffers.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: allocate RaNS data buffers (send & receive) for inter-region
!          communication (mixture only).
!
! Description: none.
!
! Input: regions = data of all regions
!        iReg    = region number
!
! Output: regions%levels%patches%turb%... = send & receive buffers
!
! Notes: none.
!
!******************************************************************************
!
! $Id: TURB_rFLO_RansAllocDataBuffers.F90,v 1.4 2008/12/06 08:44:44 mtcampbe Exp $
!
! Copyright: (c) 2003 by the University of Illinois
!
!******************************************************************************

SUBROUTINE turb_rflo_ransallocdatabuffers( regions,iReg ) ! PUBLIC

  USE moddatatypes
  USE modbndpatch, ONLY   : t_patch
  USE moddatastruct, ONLY : t_region, t_level, t_dcelltransf
  USE modglobal, ONLY     : t_global
  USE moderror
  USE modparameters
  USE turb_modparameters
  IMPLICIT NONE

! ... parameters
  TYPE(t_region), POINTER :: regions(:)

  INTEGER :: ireg

! ... loop variables
  INTEGER :: ipatch, ilev, ir

! ... local variables
  INTEGER :: bctype, iregsrc, n1, n2, n1src, n2src, neqs, neqssrc, &
             ndc, ndcsrc, ndim, ndimsrc, ncv, errorflag

  TYPE(t_patch), POINTER       :: patch
  TYPE(t_global), POINTER      :: global
  TYPE(t_level), POINTER       :: level
  TYPE(t_dcelltransf), POINTER :: sendeccell, recveccell
  TYPE(t_dcelltransf), POINTER :: sndturbeccell, rcvturbeccell

!******************************************************************************

  global => regions(ireg)%global

  CALL registerfunction( global,'TURB_RFLO_RansAllocDataBuffers',&
  'TURB_rFLO_RansAllocDataBuffers.F90' )

  IF (regions(ireg)%turbInput%modelClass /= model_rans) goto 999

! data buffers for patches ----------------------------------------------------

  ncv = regions(ireg)%turbInput%nCv

  DO ilev=1,regions(ireg)%nGridLevels
    DO ipatch=1,regions(ireg)%nPatches
  
      patch => regions(ireg)%levels(ilev)%patches(ipatch)
      bctype = patch%bcType

      IF ((bctype>=bc_regionconf .AND. bctype<=bc_regionconf+bc_range) .OR. &
          (bctype>=bc_tra_peri   .AND. bctype<=bc_tra_peri  +bc_range) .OR. &
          (bctype>=bc_rot_peri   .AND. bctype<=bc_rot_peri  +bc_range)) THEN
        iregsrc = patch%srcRegion
        IF (regions(iregsrc)%procid /= global%myProcid) THEN  ! other processor
          n1      = abs(patch%l1end   -patch%l1beg   ) + 2    ! large enough
          n2      = abs(patch%l2end   -patch%l2beg   ) + 2    ! for NODES!
          n1src   = abs(patch%srcL1end-patch%srcL1beg) + 2
          n2src   = abs(patch%srcL2end-patch%srcL2beg) + 2
          neqs    = ncv
          neqssrc = ncv
          ndc     = regions(ireg   )%nDumCells
          ndcsrc  = regions(iregsrc)%nDumCells
          ndim    = n1*n2*neqs*ndc
          ndimsrc = n1src*n2src*neqssrc*ndcsrc
          ALLOCATE( patch%turb%sendBuff(ndimsrc),stat=errorflag )
          ALLOCATE( patch%turb%recvBuff(ndim   ),stat=errorflag )
          global%error = errorflag
          IF (global%error /= 0) CALL errorstop( global,err_allocate,__line__ )
          patch%turb%nSendBuff = ndimsrc
          patch%turb%nRecvBuff = ndim
          global%nRequests        = global%nRequests + 1
          patch%turb%iRequest  = global%nRequests
        ENDIF
      ELSE IF ((bctype>=bc_regionint  .AND. bctype<=bc_regionint +bc_range) .OR. &
               (bctype>=bc_regnonconf .AND. bctype<=bc_regnonconf+bc_range)) THEN
        CALL errorstop( global,err_unknown_bc,__line__ )  ! #### TEMPORARY ####
      ENDIF  ! bcType

    ENDDO    ! iPatch
  ENDDO      ! iLev

! data buffers for edge & corner cells

  IF (global%nProcAlloc > 1) THEN    ! only if multiple processors

    DO ilev=1,regions(ireg)%nGridLevels

! --- allocate send and receive region data

      level => regions(ireg)%levels(ilev)

      ALLOCATE( level%sndTurbEcCells(global%nRegions),stat=errorflag )
      ALLOCATE( level%rcvTurbEcCells(global%nRegions),stat=errorflag )
      global%error = errorflag
      IF (global%error /= 0) CALL errorstop( global,err_allocate,__line__ )

      DO ir=1,global%nRegions
        sendeccell    => regions(ireg)%levels(ilev)%sendEcCells(ir)
        recveccell    => regions(ireg)%levels(ilev)%recvEcCells(ir)
        sndturbeccell => regions(ireg)%levels(ilev)%sndTurbEcCells(ir)
        rcvturbeccell => regions(ireg)%levels(ilev)%rcvTurbEcCells(ir)
        sndturbeccell%nCells = sendeccell%nCells
        rcvturbeccell%nCells = recveccell%nCells

        IF (sndturbeccell%nCells > 0) THEN
          global%nRequests       = global%nRequests + 1
          sndturbeccell%iRequest = global%nRequests
          ALLOCATE( sndturbeccell%buff(sndturbeccell%nCells*ncv), &
                    stat=errorflag )
          global%error = errorflag
          IF (global%error /= 0) CALL errorstop( global,err_allocate,__line__ )
        ENDIF
        IF (rcvturbeccell%nCells > 0) THEN
          rcvturbeccell%iRequest = -999999
          ALLOCATE( rcvturbeccell%buff(rcvturbeccell%nCells*ncv), &
                    stat=errorflag )
          global%error = errorflag
          IF (global%error /= 0) CALL errorstop( global,err_allocate,__line__ )
        ENDIF
      ENDDO    ! ir
    ENDDO      ! iLev

  ENDIF

! finalize

999  CONTINUE

  CALL deregisterfunction( global )

END SUBROUTINE turb_rflo_ransallocdatabuffers

!******************************************************************************
!
! RCS Revision history:
!
! $Log: TURB_rFLO_RansAllocDataBuffers.F90,v $
! Revision 1.4  2008/12/06 08:44:44  mtcampbe
! Updated license.
!
! Revision 1.3  2008/11/19 22:17:56  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.2  2006/08/19 15:40:53  mparmar
! Renamed patch variables
!
! Revision 1.1  2004/03/11 03:26:33  wasistho
! changed rocturb nomenclature
!
! Revision 1.1  2004/03/08 23:35:45  wasistho
! changed turb nomenclature
!
! Revision 1.2  2004/01/23 00:27:58  wasistho
! add data allocations for RaNS variables at edge and corners
!
! Revision 1.1  2003/10/07 02:17:02  wasistho
! initial installation of RaNS-SA and DES
!
!
!******************************************************************************