TURB_fluCv2Prim.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: Convert conserved state vector to primitive variables.
!
! Description: None.
!
! Input:  region        = Pointer to data of current region
!         cvStateFuture = Future state of conserved variables
!
! Output: None.
!
! Notes: None.
!
!******************************************************************************
  
SUBROUTINE turb_flucv2prim( pRegion,cvStateFuture )

  USE moddatatypes
  USE modglobal, ONLY    : t_global
  USE moddatastruct, ONLY: t_region
  USE modgrid, ONLY      : t_grid
  USE modinterfaces, ONLY: mixtperf_r_m, mixtperf_t_dpr
  USE modparameters
  USE moderror
  IMPLICIT NONE


! =============================================================================
! Arguments
! =============================================================================

  TYPE(t_region), TARGET :: pregion
  INTEGER, INTENT(IN) :: cvstatefuture

! =============================================================================
! Locals
! =============================================================================

  CHARACTER(CHRLEN) :: rcsidentstring
  INTEGER :: ic,indmol
  REAL(RFREAL) :: ir,mol,p,r,rgas
  REAL(RFREAL), DIMENSION(:,:), POINTER :: pcv,pdv,pgv
  TYPE(t_grid),   POINTER :: pgrid
  TYPE(t_global), POINTER :: global

! *****************************************************************************
! Start
! *****************************************************************************

  rcsidentstring = '$RCSfile: TURB_fluCv2Prim.F90,v $ $Revision: 1.4 $'

  global => pregion%global

  CALL registerfunction(global,'TURB_FluCv2Prim',&
  'TURB_fluCv2Prim.F90')

! *****************************************************************************
! Set pointers and variables
! *****************************************************************************

  pgrid => pregion%grid
  pcv   => pregion%mixt%cv
  pdv   => pregion%mixt%dv
  pgv   => pregion%mixt%gv

  indmol = pregion%mixtInput%indMol

! *****************************************************************************
! Actual conversion
! *****************************************************************************

  SELECT CASE (pregion%mixt%cvState)

! =============================================================================
!   Convert from conservative to primitive form 
! =============================================================================

    CASE (cv_mixt_state_cons) 
      SELECT CASE (cvstatefuture)

! -----------------------------------------------------------------------------      
!       Convert to duvwp form        
! -----------------------------------------------------------------------------

        CASE (cv_mixt_state_duvwp)
          pregion%mixt%cvState = cv_mixt_state_duvwp          
          
          DO ic = 1,pgrid%nCellsTot
            ir = 1.0_rfreal/pcv(cv_mixt_dens,ic)

            pcv(cv_mixt_xvel,ic) = ir*pcv(cv_mixt_xmom,ic)
            pcv(cv_mixt_yvel,ic) = ir*pcv(cv_mixt_ymom,ic)
            pcv(cv_mixt_zvel,ic) = ir*pcv(cv_mixt_zmom,ic)

            pcv(cv_mixt_pres,ic) = pdv(dv_mixt_pres,ic)
          END DO ! ic

! -----------------------------------------------------------------------------          
!       Convert to duvwt form             
! -----------------------------------------------------------------------------

        CASE (cv_mixt_state_duvwt) 
          pregion%mixt%cvState = cv_mixt_state_duvwt                
                            
          SELECT CASE (pregion%mixtInput%gasModel)

! --------- Perfect gas          

            CASE (gas_model_tcperf)
              DO ic = 1,pgrid%nCellsTot                
                r  = pcv(cv_mixt_dens,ic)
                p  = pdv(dv_mixt_pres,ic)                
                ir = 1.0_rfreal/r

                pcv(cv_mixt_xvel,ic) = ir*pcv(cv_mixt_xmom,ic)
                pcv(cv_mixt_yvel,ic) = ir*pcv(cv_mixt_ymom,ic)
                pcv(cv_mixt_zvel,ic) = ir*pcv(cv_mixt_zmom,ic)

                mol  = pgv(gv_mixt_mol,indmol*ic)
                rgas = mixtperf_r_m(mol)

                pcv(cv_mixt_temp,ic) = mixtperf_t_dpr(r,p,rgas)
              END DO ! ic
                                
            CASE default
              CALL errorstop(global,err_reached_default,__line__)
          END SELECT ! pRegion%mixtInput
        CASE default
          CALL errorstop(global,err_reached_default,__line__)   
      END SELECT ! cvStateFuture

! =============================================================================
!   Error - invalid input
! =============================================================================

    CASE default
      CALL errorstop(global,err_reached_default,__line__)
  END SELECT ! pRegion%mixt%cvStates

! *****************************************************************************
!   End
! *****************************************************************************

  CALL deregisterfunction(global)

END SUBROUTINE turb_flucv2prim


! ******************************************************************************
!
! RCS Revision history:
!
!   $Log: TURB_fluCv2Prim.F90,v $
!   Revision 1.4  2008/12/06 08:44:44  mtcampbe
!   Updated license.
!
!   Revision 1.3  2008/11/19 22:17:56  mtcampbe
!   Added Illinois Open Source License/Copyright
!
!   Revision 1.2  2005/10/31 21:09:37  haselbac
!   Changed specModel and SPEC_MODEL_NONE
!
!   Revision 1.1  2004/03/29 21:10:01  wasistho
!   add flu routines
!
!
! ******************************************************************************