TURB_fluCv2Cons.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: Convert primitive state vector to consverved variables.
!
! Description: None.
!
! Input: region        = Pointer to data of current region
!        cvStateFuture = Future state of conserved variables
!
! Output: None.
!
! Notes: 
!   1. Strictly speaking, cvStateFuture is not needed (there is only one
!      state for conserved variables), but kept for consistency with 
!      TURB_FluCv2Prim.
!
!******************************************************************************
  
SUBROUTINE turb_flucv2cons(pRegion,cvStateFuture)

  USE moddatatypes
  USE modglobal, ONLY    : t_global
  USE moddatastruct, ONLY: t_region
  USE modgrid, ONLY      : t_grid
  USE modinterfaces, ONLY: mixtperf_eo_dgpuvw, mixtperf_g_cpr, mixtperf_r_m
  USE modparameters
  USE moderror
  IMPLICIT NONE

! =============================================================================
! Arguments
! =============================================================================

  TYPE(t_region), TARGET :: pregion
  INTEGER, INTENT(IN) :: cvstatefuture

! =============================================================================
! Locals
! =============================================================================

  CHARACTER(CHRLEN) :: rcsidentstring
  INTEGER :: ic,indcp,indmol
  REAL(RFREAL) :: cp,g,mol,p,r,rgas,u,v,w
  REAL(RFREAL), DIMENSION(:,:), POINTER :: pcv,pdv,pgv
  TYPE(t_grid),   POINTER :: pgrid
  TYPE(t_global), POINTER :: global

! *****************************************************************************
! Start
! *****************************************************************************

  rcsidentstring = '$RCSfile: TURB_fluCv2Cons.F90,v $ $Revision: 1.4 $'

  global => pregion%global

  CALL registerfunction(global,'TURB_FluCv2Cons',&
  'TURB_fluCv2Cons.F90')

! *****************************************************************************
! Set pointers and variables
! *****************************************************************************

  pgrid => pregion%grid
  pcv   => pregion%mixt%cv
  pdv   => pregion%mixt%dv
  pgv   => pregion%mixt%gv

  indcp  = pregion%mixtInput%indCp
  indmol = pregion%mixtInput%indMol

! *****************************************************************************
! Actual conversion
! *****************************************************************************
     
  IF ( pregion%mixt%cvState == cv_mixt_state_duvwp .OR. & 
       pregion%mixt%cvState == cv_mixt_state_duvwt ) THEN 
    
! =============================================================================
!   Convert from primitive to conservative form 
! =============================================================================

    SELECT CASE (cvstatefuture)
      CASE (cv_mixt_state_cons)
        pregion%mixt%cvState = cv_mixt_state_cons          

        SELECT CASE (pregion%mixtInput%gasModel)

! ------- Perfect gas

          CASE (gas_model_tcperf)
            DO ic = 1,pgrid%nCellsTot
              r = pcv(cv_mixt_dens,ic)
              u = pcv(cv_mixt_xvel,ic)
              v = pcv(cv_mixt_yvel,ic)
              w = pcv(cv_mixt_zvel,ic)
              p = pdv(dv_mixt_pres,ic)

              pcv(cv_mixt_xmom,ic) = r*u
              pcv(cv_mixt_ymom,ic) = r*v
              pcv(cv_mixt_zmom,ic) = r*w

              cp   = pgv(gv_mixt_cp,indcp*ic)
              mol  = pgv(gv_mixt_mol,indmol*ic)                  
              rgas = mixtperf_r_m(mol)
              g    = mixtperf_g_cpr(cp,rgas)

              pcv(cv_mixt_ener,ic) = r*mixtperf_eo_dgpuvw(r,g,p,u,v,w)
            END DO ! ic 

! ------- Other or invalid gas models                

          CASE default 
            CALL errorstop(global,err_reached_default,__line__)
        END SELECT ! pRegion%mixtInput

      CASE default
        CALL errorstop(global,err_reached_default,__line__)
    END SELECT ! cvStateFuture

! =============================================================================
! Error - invalid input
! =============================================================================

  ELSE
    CALL errorstop(global,err_reached_default,__line__)
  END IF ! pRegion%mixt%cvState

! *****************************************************************************
! End
! *****************************************************************************

  CALL deregisterfunction(global)

END SUBROUTINE turb_flucv2cons


! ******************************************************************************
!
! RCS Revision history:
!
!   $Log: TURB_fluCv2Cons.F90,v $
!   Revision 1.4  2008/12/06 08:44:44  mtcampbe
!   Updated license.
!
!   Revision 1.3  2008/11/19 22:17:56  mtcampbe
!   Added Illinois Open Source License/Copyright
!
!   Revision 1.2  2005/10/31 21:09:37  haselbac
!   Changed specModel and SPEC_MODEL_NONE
!
!   Revision 1.1  2004/03/29 21:10:01  wasistho
!   add flu routines
!
!
! ******************************************************************************