TURB_StatFCollector.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: Collect variables of interest to be time averaged for verification
!
! Description: As a generic routine, number and kind of collected variables
!              are not specified. The cell values are obtained by averaging 
!              the face values, including dummy cells. Data is accumulated
!              in I, J and K direction, respectively, through three subsquent
!              calls.
!
! Input: region = data of current region
!        ijk    = averaging direction
!        iBegSv = begin index of averaged field sv
!        iEndSv = end index of averaged field sv
!        colVar = array of collected variables
!
! Output: turb%st(iBegSv:iEndSv,:) at cell centers including dummy cells.
!
! Notes: none.
!
!******************************************************************************
!
! $Id: TURB_StatFCollector.F90,v 1.6 2008/12/06 08:44:42 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************

#ifdef RFLO
SUBROUTINE turb_statfcollector( region,ijk,iBegSt,iEndSt,colVar )
#endif
#ifdef RFLU
SUBROUTINE turb_statfcollector( region,ijk,iBegSt,iEndSt,colVar,colBVar )
#endif

  USE moddatatypes
  USE moddatastruct, ONLY : t_region
  USE modglobal, ONLY     : t_global
#ifdef RFLO
  USE modinterfaces, ONLY : rflo_getdimensdummy, &
                            rflo_getcelloffset, rflo_getnodeoffset

#include "Indexing.h"
#endif
  USE moderror
  USE modparameters
  USE turb_modparameters
  IMPLICIT NONE

! ... parameters
  TYPE(t_region) :: region
  INTEGER        :: ijk, ibegst, iendst
  REAL(RFREAL), POINTER :: colvar(:,:)
#ifdef RFLU
  REAL(RFREAL), POINTER :: colbvar(:,:)  ! collected variables at boundaries
#endif

! ... loop variables
  INTEGER :: i, j, k, l, m

! ... local variables
  CHARACTER(CHRLEN)       :: rcsidentstring
  TYPE(t_global), POINTER :: global

  INTEGER :: ijkc, ijkn
  REAL(RFREAL) :: factor
  REAL(RFREAL), POINTER :: st(:,:)

#ifdef RFLO
  INTEGER :: idcbeg, idcend, jdcbeg, jdcend, kdcbeg, kdcend
  INTEGER :: ilev,icoff,ijcoff,inoff,ijnoff,ijknp,iadd
#endif
#ifdef RFLU
  INTEGER :: ict, icl, ipatch, nfacespercell
  INTEGER, POINTER :: c2f(:,:,:)
#endif

!******************************************************************************

  rcsidentstring = '$RCSfile: TURB_StatFCollector.F90,v $'

  global => region%global
  CALL registerfunction( global,'Turb_StatFCollector',&
  'TURB_StatFCollector.F90' )

! check some input arguments --------------------------------------------------

  IF (iendst > region%turbInput%nSt) THEN
    CALL errorstop( global,err_turb_statsinput,__line__, &
        'index of collected vars larger than nSt (allocated nmbr stats vars)' )
  ENDIF
  IF (ibegst > iendst) THEN
    CALL errorstop( global,err_turb_statsinput,__line__, &
        'begin index of collected vars larger than end index' )
  ENDIF

#ifdef RFLO
! get parameters --------------------------------------------------------

  ilev  = region%currLevel

! get dimensions and pointers

  CALL rflo_getdimensdummy( region,ilev,idcbeg,idcend, &
                            jdcbeg,jdcend,kdcbeg,kdcend )
  CALL rflo_getcelloffset( region,ilev,icoff,ijcoff )
  CALL rflo_getnodeoffset( region,ilev,inoff,ijnoff )

  st => region%levels(ilev)%turb%st

! interpolate from face to cell

  factor = 1._rfreal/6._rfreal
  IF (ijk == diri) THEN
    st = 0._rfreal
    iadd = 1
  ELSEIF (ijk == dirj) THEN
    iadd = inoff
  ELSEIF (ijk == dirk) THEN
    iadd = ijnoff
  ENDIF

  DO k=kdcbeg,kdcend
    DO j=jdcbeg,jdcend
      DO i=idcbeg,idcend

        ijkc  = indijk(i     ,j     ,k     ,icoff,ijcoff)
        ijkn  = indijk(i     ,j     ,k     ,inoff,ijnoff)
        ijknp = ijkn + iadd

        DO l=ibegst,iendst   
          m = l - ibegst + 1  
          st(l,ijkc) = st(l,ijkc)+factor*(colvar(m,ijkn)+colvar(m,ijknp))
        ENDDO

      ENDDO ! i
    ENDDO   ! j
  ENDDO     ! k
#endif
#ifdef RFLU
! get dimensions and pointers ------------------------------------------

  st => region%turb%st
  st =  0._rfreal

  DO ijkc=1,region%grid%nCells

! - region (here denoted as 'global') to local (type) mapping

    ict = region%grid%cellGlob2Loc(1,ijkc) ! cell type
    icl = region%grid%cellGlob2Loc(2,ijkc) ! local (type) cell index
    SELECT CASE ( ict ) 
      CASE ( cell_type_tet ) 
        nfacespercell = 4
        c2f => region%grid%tet2f              
      CASE ( cell_type_hex ) 
        nfacespercell = 6
        c2f => region%grid%hex2f              
      CASE ( cell_type_pri ) 
        nfacespercell = 5    
        c2f => region%grid%pri2f                         
      CASE ( cell_type_pyr ) 
        nfacespercell = 5
        c2f => region%grid%pyr2f                
      CASE default  
        CALL errorstop(global,err_reached_default,__line__)
    END SELECT ! ict

    DO l=ibegst,iendst   
      m = l - ibegst + 1  
      DO k=1,nfacespercell
        ipatch = c2f(1,k,icl)    ! patch #, ipatch=0 denotes interior faces
        ijkn   = c2f(2,k,icl)    ! global face index

        IF ( ipatch == 0 ) THEN  ! Interior face
          st(l,ijkc) = st(l,ijkc)+colvar(m,ijkn)
        ELSE ! Boundary face
          st(l,ijkc) = st(l,ijkc)+colbvar(m,ijkn)
        ENDIF
      ENDDO
      st(l,ijkc) = st(l,ijkc)/nfacespercell
    ENDDO   ! l
  ENDDO     ! ijkC
#endif

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( global )

END SUBROUTINE turb_statfcollector

!******************************************************************************
!
! RCS Revision history:
! 
! $Log: TURB_StatFCollector.F90,v $
! Revision 1.6  2008/12/06 08:44:42  mtcampbe
! Updated license.
!
! Revision 1.5  2008/11/19 22:17:54  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.4  2004/10/22 23:19:34  wasistho
! fixed devision by 6 faces
!
! Revision 1.3  2004/05/28 02:01:48  wasistho
! update unstructured grid LES
!
! Revision 1.2  2004/03/23 03:35:00  wasistho
! prepared for RFLU
!
! Revision 1.1  2004/03/05 04:37:00  wasistho
! changed nomenclature
!
! Revision 1.1  2003/05/24 02:30:28  wasistho
! turbulence statistics expanded
!
!
!******************************************************************************