SPLT_CopyPatchData.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: copy topology data associated with old patch onto a new patch
!          created by splitting the domain.
!
! Description: none.
!
! Input: regionNew = new region
!        patchOld  = patch of old grid
!        l1Off     = offset of the old patch in l1-direction
!        l2Off     = offset of the old patch in l2-direction
!        l1Cells   = max. number of cells in l1-direction
!        l2Cells   = max. number of cells in l2-direction.
!
! Output: regionNew%levels(1)%patch = new topology.
!
! Notes: routine can handle periodic boundaries or interior cuts, but NOT
!        boundaries between regions.
!
!******************************************************************************
!
! $Id: SPLT_CopyPatchData.F90,v 1.3 2008/12/06 08:44:51 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************

SUBROUTINE copypatchdata( regionsNew,patchOld,splitDirection,iReg, &
                          l1off,l2off,l1cells,l2cells )

  USE moddatatypes
  USE modbndpatch, ONLY   : t_patch
  USE moddatastruct, ONLY : t_region
  USE modparameters
  IMPLICIT NONE

! ... parameters
  TYPE(t_region), POINTER :: regionsnew(:)
  TYPE(t_patch), POINTER  :: patchold

  INTEGER :: splitdirection, ireg, l1off, l2off, l1cells, l2cells

! ... loop variables
  INTEGER :: ir

! ... local variables
  INTEGER :: bctype, lbound, lboundsrc
  INTEGER :: ibeg, jbeg, kbeg, l1offsrc, l2offsrc, l1cellssrc, l2cellssrc

  TYPE(t_patch), POINTER :: patchnew

!******************************************************************************

  patchnew => regionsnew(ireg)%levels(1)%patches(regionsnew(ireg)%nPatches)

  patchnew%bcType    = patchold%bcType
  patchnew%lbound    = patchold%lbound
  patchnew%bcCoupled = patchold%bcCoupled
  patchnew%l1beg     = max(patchold%l1beg-l1off+1,1)
  patchnew%l1end     = min(patchold%l1end-l1off+1,l1cells)
  patchnew%l2beg     = max(patchold%l2beg-l2off+1,1)
  patchnew%l2end     = min(patchold%l2end-l2off+1,l2cells)

! zero out data of source patch

  patchnew%align     = patchold%align
  patchnew%srcLbound = 0
  patchnew%srcRegion = 0
  patchnew%srcL1beg  = 0
  patchnew%srcL1end  = 0
  patchnew%srcL2beg  = 0
  patchnew%srcL2end  = 0

  bctype = patchnew%bcType

! source patch is periodic boundary -------------------------------------------

  IF ((bctype>=bc_tra_peri .AND. bctype<=bc_tra_peri+bc_range) .OR. &
      (bctype>=bc_rot_peri .AND. bctype<=bc_rot_peri+bc_range)) THEN

    patchnew%srcLbound = patchold%srcLbound
    lboundsrc          = patchold%srcLbound

! - split between the boundaries

    IF (((lboundsrc==1 .OR. lboundsrc==2) .AND. splitdirection==1) .OR. &
        ((lboundsrc==3 .OR. lboundsrc==4) .AND. splitdirection==2) .OR. &
        ((lboundsrc==5 .OR. lboundsrc==6) .AND. splitdirection==3)) THEN
      IF (lboundsrc==1 .OR. lboundsrc==3 .OR. lboundsrc==5) THEN
        patchnew%srcRegion = 1
      ELSE
        patchnew%srcRegion = regionsnew(ireg)%global%nRegions
      ENDIF
      patchnew%srcL1beg = patchold%srcL1beg
      patchnew%srcL1end = patchold%srcL1end
      patchnew%srcL2beg = patchold%srcL2beg
      patchnew%srcL2end = patchold%srcL2end

! - split along the boundaries

    ELSE
      patchnew%srcRegion = ireg
      patchnew%srcL1beg  = max(patchold%srcL1beg-l1off+1,1)
      patchnew%srcL1end  = min(patchold%srcL1end-l1off+1,l1cells)
      patchnew%srcL2beg  = max(patchold%srcL2beg-l2off+1,1)
      patchnew%srcL2end  = min(patchold%srcL2end-l2off+1,l2cells)
    ENDIF

! source patch is interior cut ------------------------------------------------

  ELSE IF (bctype>=bc_regionconf .AND. bctype<=bc_regionconf+bc_range) THEN

    patchnew%srcLbound = patchold%srcLbound
    lbound             = patchold%lbound
    lboundsrc          = patchold%srcLbound

! - source patch on the same boundary (C-grid)

    IF (lbound == lboundsrc) THEN

! --- boundary cannot have been splitted

      IF (((lbound==1 .OR. lbound==2) .AND. splitdirection==1) .OR. &
          ((lbound==3 .OR. lbound==4) .AND. splitdirection==2) .OR. &
          ((lbound==5 .OR. lbound==6) .AND. splitdirection==3)) THEN
        patchnew%srcRegion = ireg
        patchnew%srcL1beg  = patchold%srcL1beg
        patchnew%srcL1end  = patchold%srcL1end
        patchnew%srcL2beg  = patchold%srcL2beg
        patchnew%srcL2end  = patchold%srcL2end

! --- boundary possibly splitted

      ELSE
        patchnew%srcRegion = regionsnew(ireg)%global%nRegions - ireg + 1
        IF (patchold%srcL1beg > patchold%srcL1End) THEN    ! l1 reversed
          IF (((lbound==1 .OR. lbound==2) .AND. splitdirection==3) .OR. &
              ((lbound==3 .OR. lbound==4) .AND. splitdirection==1) .OR. &
              ((lbound==5 .OR. lbound==6) .AND. splitdirection==2)) THEN
            patchnew%srcRegion = ireg
          ENDIF
        ELSE                                               ! l2 reversed
          IF (((lbound==1 .OR. lbound==2) .AND. splitdirection==2) .OR. &
              ((lbound==3 .OR. lbound==4) .AND. splitdirection==3) .OR. &
              ((lbound==5 .OR. lbound==6) .AND. splitdirection==1)) THEN
            patchnew%srcRegion = ireg
          ENDIF
        ENDIF
        ibeg = 1
        jbeg = 1
        kbeg = 1
        DO ir=1,patchnew%srcRegion-1
          IF (splitdirection == 1) THEN
            ibeg = ibeg + regionsnew(ir)%levels(1)%grid%ipc
          ELSE IF (splitdirection == 2) THEN
            jbeg = jbeg + regionsnew(ir)%levels(1)%grid%jpc
          ELSE
            kbeg = kbeg + regionsnew(ir)%levels(1)%grid%kpc
          ENDIF
        ENDDO
        IF (lbound==1 .OR. lbound==2) THEN
          l1offsrc   = jbeg
          l2offsrc   = kbeg
          l1cellssrc = regionsnew(patchnew%srcRegion)%levels(1)%grid%jpc
          l2cellssrc = regionsnew(patchnew%srcRegion)%levels(1)%grid%kpc
        ELSE IF (lbound==3 .OR. lbound==4) THEN
          l1offsrc   = kbeg
          l2offsrc   = ibeg
          l1cellssrc = regionsnew(patchnew%srcRegion)%levels(1)%grid%kpc
          l2cellssrc = regionsnew(patchnew%srcRegion)%levels(1)%grid%ipc
        ELSE IF (lbound==5 .OR. lbound==6) THEN
          l1offsrc   = ibeg
          l2offsrc   = jbeg
          l1cellssrc = regionsnew(patchnew%srcRegion)%levels(1)%grid%ipc
          l2cellssrc = regionsnew(patchnew%srcRegion)%levels(1)%grid%jpc
        ENDIF
        patchnew%srcL1beg = max(patchold%srcL1beg-l1offsrc+1,1)
        patchnew%srcL1beg = min(patchnew%srcL1beg,l1cellssrc)
        patchnew%srcL1end = min(patchold%srcL1end-l1offsrc+1,l1cellssrc)
        patchnew%srcL1end = max(patchnew%srcL1end,1)
        patchnew%srcL2beg = max(patchold%srcL2beg-l2offsrc+1,1)
        patchnew%srcL2beg = min(patchnew%srcL2beg,l2cellssrc)
        patchnew%srcL2end = min(patchold%srcL2end-l2offsrc+1,l2cellssrc)
        patchnew%srcL2end = max(patchnew%srcL2end,1)
      ENDIF

! - source patch on different boundary (O-grid)

    ELSE

! --- boundary cannot have been splitted

      IF (((lbound==1 .OR. lbound==2) .AND. splitdirection==1) .OR. &
          ((lbound==3 .OR. lbound==4) .AND. splitdirection==2) .OR. &
          ((lbound==5 .OR. lbound==6) .AND. splitdirection==3)) THEN
        IF (lboundsrc==1 .OR. lboundsrc==3 .OR. lboundsrc==5) THEN
          patchnew%srcRegion = 1
        ELSE
          patchnew%srcRegion = regionsnew(ireg)%global%nRegions
        ENDIF
        patchnew%srcL1beg  = patchold%srcL1beg
        patchnew%srcL1end  = patchold%srcL1end
        patchnew%srcL2beg  = patchold%srcL2beg
        patchnew%srcL2end  = patchold%srcL2end

! --- boundary splitted

      ELSE
        patchnew%srcRegion = ireg
        patchnew%srcL1beg  = max(patchold%srcL1beg-l1off+1,1)
        patchnew%srcL1end  = min(patchold%srcL1end-l1off+1,l1cells)
        patchnew%srcL2beg  = max(patchold%srcL2beg-l2off+1,1)
        patchnew%srcL2end  = min(patchold%srcL2end-l2off+1,l2cells)
      ENDIF

    ENDIF  ! lbound == lboundSrc

  ENDIF    ! bcType

END SUBROUTINE copypatchdata

!******************************************************************************
!
! RCS Revision history:
!
! $Log: SPLT_CopyPatchData.F90,v $
! Revision 1.3  2008/12/06 08:44:51  mtcampbe
! Updated license.
!
! Revision 1.2  2008/11/19 22:18:01  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.1  2004/12/03 02:41:15  wasistho
! added prefix
!
! Revision 1.1  2004/12/03 00:45:30  wasistho
! lower to upper case
!
! Revision 1.4  2003/05/15 02:57:07  jblazek
! Inlined index function.
!
! Revision 1.3  2002/09/27 00:57:11  jblazek
! Changed makefiles - no makelinks needed.
!
! Revision 1.2  2002/09/05 17:40:22  jblazek
! Variable global moved into regions().
!
! Revision 1.1  2002/07/12 21:50:07  jblazek
! Added tool to split single grid into multiple regions.
!
!******************************************************************************