SPEC_ReadInputFile.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
! ******************************************************************************
!
! Purpose: Read user input, store it in the data structure and check.
!
! Description: None.
!
! Input:
!   regions                Data associated with regions
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************
!
! $Id: SPEC_ReadInputFile.F90,v 1.6 2008/12/06 08:44:41 mtcampbe Exp $
!
! Copyright: (c) 2003-2005 by the University of Illinois
!
! ******************************************************************************

SUBROUTINE spec_readinputfile(regions)

  USE modglobal, ONLY: t_global
  USE moddatatypes
  USE moddatastruct, ONLY: t_region
  USE moderror
  USE modparameters

  USE modbuildfilenames, ONLY: buildfilenameplain

  USE spec_modinterfaces, ONLY: spec_initinputvaluesspectype, &
                                spec_readspecsection, &
                                spec_readspectypesection
  IMPLICIT NONE

! ******************************************************************************
! Definitions and declarations
! ******************************************************************************

! ==============================================================================
! Arguments
! ==============================================================================

  TYPE(t_region), DIMENSION(:), POINTER :: regions

! ==============================================================================
! Locals
! ==============================================================================

  CHARACTER(CHRLEN) :: ifilename,rcsidentstring
  CHARACTER(256) :: line
  INTEGER :: errorflag,ipass,ireg,ispec,ispectype,nspecies
  LOGICAL :: usedsomewhere,unusedsomewhere
  TYPE(t_global), POINTER :: global

! ******************************************************************************
! Start
! ******************************************************************************

  rcsidentstring = '$RCSfile: SPEC_ReadInputFile.F90,v $ $Revision: 1.6 $'

  global => regions(1)%global

  CALL registerfunction(global,'SPEC_ReadInputFile',&
  'SPEC_ReadInputFile.F90')

! ******************************************************************************
! Read user input for species
! ******************************************************************************

! ==============================================================================
! Build file name
! ==============================================================================

  CALL buildfilenameplain(global,filedest_indir,'.inp',ifilename)

! ==============================================================================
! Look for keywords and read appropriate sections, read in two passes
! ==============================================================================

  outer: DO ipass = 1,2
    ispectype = 0

! ------------------------------------------------------------------------------
!   Open file
! ------------------------------------------------------------------------------

    OPEN(if_input,file=ifilename,form='FORMATTED',status='UNKNOWN', &
         iostat=errorflag)
    global%error = errorflag
    IF ( global%error /= 0 ) THEN
      CALL errorstop(global,err_file_open,__line__,'File: '//trim(ifilename))
    END IF ! global%error

! ------------------------------------------------------------------------------
!   In each pass, look for keywords
! ------------------------------------------------------------------------------

    inner: DO
      READ(if_input,'(A256)',iostat=errorflag) line

      IF ( errorflag > 0 ) THEN ! Error occurred
        CALL errorstop(global,err_file_read,__line__,'File: '//trim(ifilename))
      ELSE IF ( errorflag < 0 ) THEN ! Encountered end of file
        EXIT inner
      END IF ! errorFlag

! --- First pass: Read only SPECIES section ------------------------------------

      IF ( ipass == 1 ) THEN
        SELECT CASE( trim(line) )
          CASE ( '# SPECIES' )
            CALL spec_readspecsection(regions)
        END SELECT

! --- Second pass: Read only SPECIES_TYPE sections -----------------------------

      ELSE IF ( ipass == 2 ) THEN
        SELECT CASE( trim(line) )
          CASE ( '# SPECIES_TYPE' )
            ispectype = ispectype + 1
            CALL spec_readspectypesection(regions,ispectype)
        END SELECT

! --- Invalid pass number (defensive coding) -----------------------------------

      ELSE
        CALL errorstop(global,err_reached_default,__line__)
      END IF ! iPass
    END DO inner

! ------------------------------------------------------------------------------
!   End of pass 1: Allocate memory for species-specific input and initialize
! ------------------------------------------------------------------------------

    IF ( ipass == 1 ) THEN
      DO ireg = lbound(regions,1),ubound(regions,1)
        nspecies = regions(ireg)%specInput%nSpecies

        IF ( nspecies > 0 ) THEN
          ALLOCATE(regions(ireg)%specInput%specType(nspecies),stat=errorflag)
          global%error = errorflag
          IF ( global%error /= err_none ) THEN
            CALL errorstop(global,err_allocate,__line__, &
                           'regions%specInput%specType')
          END IF ! global%error

          DO ispec = 1,nspecies
            CALL spec_initinputvaluesspectype(regions(ireg),ispec)
          END DO ! iSpec
        ELSE
          nullify(regions(ireg)%specInput%specType)
        END IF ! nSpecies
      END DO ! iReg
    END IF ! iPass

! ------------------------------------------------------------------------------
!   Check that have enough SPECIES_TYPE sections if species USED
! ------------------------------------------------------------------------------

    IF ( ipass == 2 ) THEN

      usedsomewhere   = .false.
      unusedsomewhere = .false.

      DO ireg = lbound(regions,1),ubound(regions,1)
        nspecies = regions(ireg)%specInput%nSpecies
        IF ( regions(ireg)%specInput%usedFlag ) THEN
! ------- if USED, then require number of sections to be consistent
          IF ( ispectype /= nspecies ) THEN
            CALL errorstop(global,err_spec_ntypes,__line__)
          END IF ! iSpecType
          IF ( nspecies == 0 ) regions(ireg)%specInput%usedFlag = .false.
        ELSE
! ------- if not USED, then no consistency check, but check nSpecies set to 0
          IF ( nspecies /= 0 )  THEN
            CALL errorstop(global,err_spec_ntypes,__line__)
          END IF ! nSpecies
        END IF ! usedFlag

        usedsomewhere   = usedsomewhere   .OR. &
                                  regions(ireg)%specInput%usedFlag
        unusedsomewhere = unusedsomewhere .OR. &
                            .NOT. regions(ireg)%specInput%usedFlag
      END DO ! iReg

      IF (usedsomewhere.AND.unusedsomewhere) THEN
        CALL errorstop( global,err_mp_allornone,__line__ )
      END IF ! usedSomewhere.AND.unusedSomewhere

      global%specUsed = usedsomewhere

    END IF ! iPass

! ------------------------------------------------------------------------------
!   Close file
! ------------------------------------------------------------------------------

    CLOSE(if_input,iostat=errorflag)
    global%error = errorflag
    IF ( global%error /= 0 ) THEN
      CALL errorstop(global,err_file_close,__line__,'File: '//trim(ifilename))
    END IF ! global%error
  END DO outer

! ******************************************************************************
! End
! ******************************************************************************

  CALL deregisterfunction(global)

END SUBROUTINE spec_readinputfile

! ******************************************************************************
!
! RCS Revision history:
!
! $Log: SPEC_ReadInputFile.F90,v $
! Revision 1.6  2008/12/06 08:44:41  mtcampbe
! Updated license.
!
! Revision 1.5  2008/11/19 22:17:53  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.4  2005/11/10 02:38:30  haselbac
! Clean-up
!
! Revision 1.3  2004/07/28 15:29:21  jferry
! created global variable for spec use
!
! Revision 1.2  2004/06/16 20:01:29  haselbac
! Added use of ModBuildFileNames, cosmetics
!
! Revision 1.1  2003/11/25 21:08:37  haselbac
! Initial revision
!
! ******************************************************************************