SPEC_RFLU_SourceTerms_GL.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
! ******************************************************************************
!
! Purpose: Compute cavitation source terms.
!
! Description: None.
!
! Input: 
!   pRegion     Pointer to region data 
!
! Output: None. 
!
! Notes: Calculate vapor saturation pressure based from Goff (1957). 
!
! ******************************************************************************
!
! $Id: SPEC_RFLU_SourceTerms_GL.F90,v 1.5 2008/12/06 08:44:40 mtcampbe Exp $
!
! Copyright: (c) 2006 by the University of Illinois
!
! ******************************************************************************

SUBROUTINE spec_rflu_sourceterms_gl(pRegion)

  USE moddatatypes
  USE moddatastruct, ONLY: t_region
  USE modglobal, ONLY: t_global
  USE moderror
  USE modparameters

  USE modinterfaces, ONLY: mixtliq_d_dobpppobttto, &
                           mixtperf_cv_cpr, &
                           mixtperf_d_prt, &
                           mixtperf_r_cpg, &
                           mixtperf_r_m

  IMPLICIT NONE

! ******************************************************************************
! Declarations and definitions
! ******************************************************************************

! ==============================================================================
! Arguments
! ==============================================================================

  TYPE(t_region), POINTER :: pregion
  TYPE(t_global), POINTER :: global

! ==============================================================================
! Locals
! ==============================================================================
  
  CHARACTER(CHRLEN) :: rcsidentstring  
  INTEGER :: icg
  REAL(RFREAL):: bp,bt,cavno,cvg,cvl,cvv,dinf,fac,fvol,k,kf,kv,linf,n,p, &
                 pinfpe,po,pv,rg,rhov,rhol,ro,rv,ryl,sv,t,tauf,tauv,to,ts, &
                 vinf,vlinf,vfv
  REAL(RFREAL), DIMENSION(:), POINTER :: vol          
  REAL(RFREAL), DIMENSION(:,:), POINTER :: pcvmixt,pcvspec,pdvmixt,rhsmixt, &
                                           rhsspec

! ******************************************************************************
! Start
! ******************************************************************************

  rcsidentstring = & 
    '$RCSfile: SPEC_RFLU_SourceTerms_GL.F90,v $ $Revision: 1.5 $'
  
  global => pregion%global

  CALL registerfunction(global,'SPEC_RFLU_SourceTerms_GL',&
  'SPEC_RFLU_SourceTerms_GL.F90')

! ******************************************************************************
! Set pointers and variables
! ******************************************************************************

  pcvmixt => pregion%mixt%cv
  pcvspec => pregion%spec%cv
  pdvmixt => pregion%mixt%dv

  rhsmixt => pregion%mixt%rhs
  rhsspec => pregion%spec%rhs
  
  vol  => pregion%grid%vol

! ******************************************************************************
! Define constants
! ******************************************************************************
    
  ro  = global%refDensityLiq
  po  = global%refPressLiq
  to  = global%refTempLiq
  bp  = global%refBetaPLiq
  bt  = global%refBetaTLiq
  cvl = global%refCvLiq

  rg  = mixtperf_r_m(pregion%specInput%specType(1)%pMaterial%molw)
  cvg = mixtperf_cv_cpr(pregion%specInput%specType(1)%pMaterial%spht,rg)

  rv  = mixtperf_r_m(pregion%specInput%specType(2)%pMaterial%molw)
  cvv = mixtperf_cv_cpr(pregion%specInput%specType(2)%pMaterial%spht,rv)

  fac = 1.5_rfreal/global%dtMin

  DO icg = 1,pregion%grid%nCellsTot
    p   = pdvmixt(dv_mixt_pres,icg)
    t   = pdvmixt(dv_mixt_temp,icg)
    ryl = pcvmixt(cv_mixt_dens,icg) - pcvspec(1,icg) - pcvspec(2,icg)
 
    ts = 273.16_rfreal ! steam point temperature in K
    pv = 100.0_rfreal*(10.0_rfreal**(10.79574_rfreal*(1.0_rfreal-ts/t) &
                     - 5.02800_rfreal*log10(t/ts) &
                     + 1.50475e-04_rfreal*(1.0_rfreal &
                     - 10.0_rfreal**(-8.2969_rfreal*(t/ts-1.0_rfreal))) &
                     + 0.42873e-03_rfreal &
                     * (10.0_rfreal**(4.76955*(1.0_rfreal-ts/t))-1.0_rfreal) &
                     + 0.78614))       

! ******************************************************************************
!   Model 1 
! ******************************************************************************

    dinf   = 882.655_rfreal  ! Hard Coded for Now
    vinf   = 23.728_rfreal
    linf   = 2.0e-03_rfreal
    vlinf  = vinf/linf
    pinfpe = 0.5_rfreal*dinf*vinf*vinf
    cavno  = 0.4_rfreal      ! 0.3, 0.2
    tauv   = 0.00001_rfreal  ! base line rate (b=.001), 
    tauf   = 0.00001_rfreal  ! faster: bx10, slower: bx0.1 

    kf = ((0.5_rfreal*( sign(1.0_rfreal,p-pv) & 
       - 1.0_rfreal)*(p-pv))/(tauf*(pinfpe)))*vlinf
    kv = ((0.5_rfreal*(-sign(1.0_rfreal,p-pv) &
       - 1.0_rfreal)*(p-pv))/(tauv*(pinfpe)))*vlinf

    sv = kf*ryl + kv*pcvspec(2,icg)

    rhsspec(2,icg) = rhsspec(2,icg) - vol(icg)*sv

! ******************************************************************************
!   Model 2
! ******************************************************************************

!   rhol  = MixtLiq_D_DoBpPPoBtTTo(ro,Bp,Bt,P,po,T,to)
!   rhov  = MixtPerf_D_PRT(P,Rv,T)
!   vfv   = rYl/rhol 
!    
!   N  = 1.0_RFREAL   ! bubble number density
!   K  = 3.85_RFREAL*(rhol/SQRT(rhov))*(N**0.333_RFREAL)
!    
!   Sv = SIGN(1.0_RFREAL,P-Pv)*K*(vfv**0.666_RFREAL)*SQRT(ABS(P-Pv))
!   rhsSpec(2,icg) = rhsSpec(2,icg) - vol(icg)*Sv
  END DO ! icg

! ******************************************************************************
! End
! ******************************************************************************

  CALL deregisterfunction(global)

END SUBROUTINE spec_rflu_sourceterms_gl

! ******************************************************************************
!
! RCS Revision history:
!
! $Log: SPEC_RFLU_SourceTerms_GL.F90,v $
! Revision 1.5  2008/12/06 08:44:40  mtcampbe
! Updated license.
!
! Revision 1.4  2008/11/19 22:17:53  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.3  2006/04/07 15:19:25  haselbac
! Removed tabs
!
! Revision 1.2  2006/03/30 20:52:40  haselbac
! Cosmetics
!
! Revision 1.1  2006/03/26 20:21:05  haselbac
! Initial revision
!
! ******************************************************************************