SPEC_RFLU_SetEEv.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
! ******************************************************************************
!
! Purpose: Compute EE approximation to velocity and temperature of particulate
!   species.
!
! Description: None.
!
! Input:
!   pRegion        Pointer to data of current region
!   iSpec          Index of species
!
! Output: None.
!
! Notes: 
!   1. Use nomenclature (gas instead of mixture) of document describing
!      governing equations for compressible multiphase flow.
!
! ******************************************************************************
!
! $Id: SPEC_RFLU_SetEEv.F90,v 1.5 2008/12/06 08:44:40 mtcampbe Exp $
!
! Copyright: (c) 2005 by the University of Illinois
!
! ******************************************************************************

SUBROUTINE spec_rflu_seteev(pRegion,iSpec)

  USE moddatatypes
  USE modglobal, ONLY: t_global
  USE moddatastruct, ONLY: t_region
  USE modgrid, ONLY: t_grid
  USE moderror
  USE modparameters

  USE modspecies, ONLY: t_spec_type
  
  USE spec_modparameters

  IMPLICIT NONE

! ******************************************************************************
! Definitions and declarations
! ******************************************************************************

! ==============================================================================
! Arguments
! ==============================================================================

  INTEGER, INTENT(IN) :: ispec
  TYPE(t_region), POINTER :: pregion

! ==============================================================================
! Locals
! ==============================================================================

  CHARACTER(CHRLEN) :: rcsidentstring
  INTEGER :: icg,ispeceev
  REAL(RFREAL) :: gx,gy,gz,irg,tau,taucoef,tee,tg,ug,uee,vg,vee,wg,wee            
  REAL(RFREAL), DIMENSION(:,:), POINTER :: pcvg,pdvg,psd,ptvg
  REAL(RFREAL), DIMENSION(:,:,:), POINTER :: peev  
  TYPE(t_global), POINTER :: global
  TYPE(t_grid), POINTER :: pgrid
  TYPE(t_spec_type), POINTER :: pspectype

! ******************************************************************************
! Start
! ******************************************************************************

  rcsidentstring = '$RCSfile: SPEC_RFLU_SetEEv.F90,v $ $Revision: 1.5 $'

  global => pregion%global

  CALL registerfunction(global,'SPEC_RFLU_SetEEv',&
  'SPEC_RFLU_SetEEv.F90')

! ******************************************************************************
! Set dimensions and pointers
! ******************************************************************************

  pgrid => pregion%grid
  psd   => pregion%mixt%sd
  pcvg  => pregion%mixt%cv
  pdvg  => pregion%mixt%dv    
  ptvg  => pregion%mixt%tv
  peev  => pregion%spec%eev

  pspectype => pregion%specInput%specType(ispec)  

  taucoef  = pspectype%tauCoefficient
  ispeceev = pspectype%iSpec2iSpecEEv

! ******************************************************************************
! Checks: Defensive coding, should never occur
! ******************************************************************************

  IF ( pspectype%discreteFlag .EQV. .false. ) THEN
    CALL errorstop(global,err_illegal_value,__line__)
  END IF ! pSpecType%discreteFlag

  IF ( pspectype%velocityMethod /= spec_methv_eqeul ) THEN
    CALL errorstop(global,err_illegal_value,__line__)
  END IF ! pSpecType%velocityMethod

  IF ( taucoef <= 0.0_rfreal ) THEN
    CALL errorstop(global,err_illegal_value,__line__)
  END IF ! tauCoef

  IF ( pregion%mixtInput%indSd /= 1 ) THEN
    CALL errorstop(global,err_illegal_value,__line__)
  END IF ! pRegion%mixtInput%indSd

  IF ( pregion%mixt%cvState /= cv_mixt_state_cons ) THEN
    CALL errorstop(global,err_cv_state_invalid,__line__)
  END IF ! pRegion%mixt%cvState

! ******************************************************************************
! Set gravity vector for settling velocity contribution
! ******************************************************************************

  IF ( pspectype%settlingFlag .EQV. .true. ) THEN 
    IF ( global%accelOn .EQV. .true. ) THEN 
      gx = global%accelX
      gy = global%accelY
      gz = global%accelZ
    ELSE 
      gx = 0.0_rfreal
      gy = 0.0_rfreal
      gz = 0.0_rfreal
    END IF ! global%accelOn
  ELSE 
    gx = 0.0_rfreal
    gy = 0.0_rfreal
    gz = 0.0_rfreal              
  END IF ! pSpecType%settlingFlag

! ******************************************************************************
! Compute EE variables
! ******************************************************************************

  DO icg = 1,pgrid%nCellsTot
    irg = 1.0_rfreal/pcvg(cv_mixt_dens,icg)
    ug  = irg*pcvg(cv_mixt_xmom,icg)
    vg  = irg*pcvg(cv_mixt_ymom,icg)
    wg  = irg*pcvg(cv_mixt_zmom,icg)
    tg  =     pdvg(dv_mixt_temp,icg)

    tau = taucoef/ptvg(tv_mixt_muel,icg)

    uee = ug - tau*(psd(sd_xmom,icg) - gx)
    vee = vg - tau*(psd(sd_ymom,icg) - gy)
    wee = wg - tau*(psd(sd_zmom,icg) - gz)

    tee = tg ! TEMPORARY               
    
    peev(eev_spec_xvel,ispeceev,icg) = uee
    peev(eev_spec_yvel,ispeceev,icg) = vee
    peev(eev_spec_zvel,ispeceev,icg) = wee
    peev(eev_spec_temp,ispeceev,icg) = tee 
  END DO ! icg

! ******************************************************************************
! End
! ******************************************************************************

  CALL deregisterfunction(global)

END SUBROUTINE spec_rflu_seteev

! ******************************************************************************
!
! RCS Revision history:
!
! $Log: SPEC_RFLU_SetEEv.F90,v $
! Revision 1.5  2008/12/06 08:44:40  mtcampbe
! Updated license.
!
! Revision 1.4  2008/11/19 22:17:53  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.3  2006/04/07 15:19:25  haselbac
! Removed tabs
!
! Revision 1.2  2006/01/06 22:43:14  haselbac
! Bug fix: Incorrect declaration of iSpecEEv
!
! Revision 1.1  2005/11/27 01:47:26  haselbac
! Initial revision
!
! ******************************************************************************