SPEC_RFLU_PrintFlowInfo.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
! ******************************************************************************
!
! Purpose: Display minimum and maximum values of species state vector for 
!   given local domain.
!
! Description: None.
!
! Input: 
!   pRegion     Pointer to region
! 
! Output: N/A.
!
! Notes: None. 
!
!******************************************************************************
!
! $Id: SPEC_RFLU_PrintFlowInfo.F90,v 1.3 2008/12/06 08:44:40 mtcampbe Exp $
!
! Copyright: (c) 2003 by the University of Illinois
!
!******************************************************************************

SUBROUTINE spec_rflu_printflowinfo(pRegion)

  USE modglobal, ONLY: t_global
  USE moddatatypes
  USE modparameters
  USE moderror
  USE modgrid, ONLY: t_grid
  USE moddatastruct, ONLY: t_region 
    
  USE modinterfaces, ONLY: rflu_printlocinfo   

  IMPLICIT NONE
  
! ******************************************************************************
! Declarations and definitions
! ******************************************************************************  

! ==============================================================================
! Parameters
! ==============================================================================   

  TYPE(t_region), POINTER :: pregion 

! ==============================================================================
! Local variables
! ==============================================================================
 
  CHARACTER(CHRLEN) :: rcsidentstring
  INTEGER :: errorflag,ispec,nspecies,upplim
  INTEGER :: dummy(1) 
  INTEGER, DIMENSION(:,:), ALLOCATABLE :: loc
  REAL(RFREAL), DIMENSION(:,:), POINTER :: pcv
  TYPE(t_grid), POINTER :: pgrid  
  TYPE(t_global), POINTER :: global
  
  rcsidentstring = '$RCSfile: SPEC_RFLU_PrintFlowInfo.F90,v $ $Revision: 1.3 $'
  
! ******************************************************************************
! Start
! ******************************************************************************

  global => pregion%global

  CALL registerfunction(global,'SPEC_RFLU_PrintFlowInfo',&
  'SPEC_RFLU_PrintFlowInfo.F90')

  IF ( global%verbLevel > verbose_none ) THEN 
    WRITE(stdout,'(A,1X,A)') solver_name,'Printing species information...'
    WRITE(stdout,'(A,3X,A,1X,I5.5)') solver_name,'Global region:', & 
                                     pregion%iRegionGlobal 
    IF ( global%flowType == flow_unsteady ) THEN 
      WRITE(stdout,'(A,3X,A,1X,1PE11.5)') solver_name,'Current time:', & 
                                          global%currentTime
    END IF ! global%flowType
  END IF ! global%verbLevel

! ==============================================================================
! Set pointers and variables
! ==============================================================================

  pcv   => pregion%spec%cv
  pgrid => pregion%grid

! ==============================================================================
! Allocate memory for location array
! ==============================================================================

  nspecies = pregion%specInput%nSpecies
  
  ALLOCATE(loc(nspecies,min_val:max_val),stat=errorflag)
  global%error = errorflag
  IF ( global%error /= err_none ) THEN 
    CALL errorstop(global,err_allocate,__line__,'loc')
  END IF ! global%error

! ==============================================================================
! Set upper limit: useful for checking of cell/dummy cell values
! ==============================================================================

  upplim = pgrid%nCells ! Only internal cells
!  uppLim = pGrid%nCellsTot ! Also dummy cells

! ==============================================================================
! Find locations of extrema: NOTE Asinine coding needed because of poor 
! FORTRAN interface for MINLOC and MAXLOC functions... 
! ==============================================================================

  DO ispec = 1,nspecies
    dummy              = minloc(pcv(ispec,1:upplim))
    loc(ispec,min_val) = dummy(1)

    dummy              = maxloc(pcv(ispec,1:upplim))
    loc(ispec,max_val) = dummy(1)
  END DO ! iSpec
  
! ==============================================================================
! Print locations of extrema
! ==============================================================================  
  
  DO ispec = 1,nspecies
    WRITE(stdout,'(A,3X,A,2(1X,E23.16),2(1X,I9))') & 
                  solver_name,'Density (kg/m^3):', & 
                  minval(pcv(ispec,1:upplim)),maxval(pcv(ispec,1:upplim)), & 
                  loc(ispec,min_val),loc(ispec,max_val)
  END DO ! iSpec  
    
! ==============================================================================
! Print out locations of cells at which extrema occur
! ==============================================================================  
     
  IF ( global%verbLevel /= verbose_low ) THEN   
    CALL rflu_printlocinfo(pregion,loc,nspecies,locinfo_mode_silent, &
                           output_mode_master_only)
  END IF ! global%verbLevel
      
! ==============================================================================
! Deallocate memory for location array
! ==============================================================================
  
  DEALLOCATE(loc,stat=errorflag)
  global%error = errorflag
  IF ( global%error /= err_none ) THEN 
    CALL errorstop(global,err_deallocate,__line__,'loc')
  END IF ! global%error      
      
! ******************************************************************************
! End
! ******************************************************************************  
  
  IF ( global%verbLevel > verbose_none ) THEN 
    WRITE(stdout,'(A,1X,A)') solver_name,'Printing species information done.'
  END IF ! global%verbLevel  
    
  CALL deregisterfunction(global)  
    
END SUBROUTINE spec_rflu_printflowinfo


! ******************************************************************************
!
! RCS Revision history:
!
!   $Log: SPEC_RFLU_PrintFlowInfo.F90,v $
!   Revision 1.3  2008/12/06 08:44:40  mtcampbe
!   Updated license.
!
!   Revision 1.2  2008/11/19 22:17:53  mtcampbe
!   Added Illinois Open Source License/Copyright
!
!   Revision 1.1  2003/11/25 21:08:37  haselbac
!   Initial revision
!
! ******************************************************************************