SPEC_RFLU_EnforceBounds.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
! ******************************************************************************
!
! Purpose: Enforce bounds on species.
!
! Description: None.
!
! Input: 
!   pRegion     Pointer to region
! 
! Output: None.
!
! Notes: 
!   1. At present, only enforce minimum bound. In future, could also enforce
!      maximum bound on each individual component, and that the sum is equal
!      to the mixture density.
!
!******************************************************************************
!
! $Id: SPEC_RFLU_EnforceBounds.F90,v 1.3 2008/12/06 08:44:40 mtcampbe Exp $
!
! Copyright: (c) 2004 by the University of Illinois
!
!******************************************************************************

SUBROUTINE spec_rflu_enforcebounds(pRegion)

  USE modglobal, ONLY: t_global
  USE moddatatypes
  USE modparameters
  USE moderror
  USE modgrid, ONLY: t_grid
  USE moddatastruct, ONLY: t_region 
  USE modmpi
  
  USE modinterfaces, ONLY: rflu_decideprint
    
  IMPLICIT NONE
  
! ******************************************************************************
! Declarations and definitions
! ******************************************************************************  

! ==============================================================================
! Parameters
! ==============================================================================   

  TYPE(t_region), POINTER :: pregion 

! ==============================================================================
! Local variables
! ==============================================================================
 
  CHARACTER(CHRLEN) :: rcsidentstring
  INTEGER :: icg,ispec,negvalcntr
  REAL(RFREAL) :: negvalmin
  REAL(RFREAL), DIMENSION(:,:), POINTER :: pcvmixt,pcvspec
  TYPE(t_grid), POINTER :: pgrid  
  TYPE(t_global), POINTER :: global
  
  rcsidentstring = '$RCSfile: SPEC_RFLU_EnforceBounds.F90,v $ $Revision: 1.3 $'
  
! ******************************************************************************
! Start
! ******************************************************************************

  global => pregion%global

  CALL registerfunction(global,'SPEC_RFLU_EnforceBounds',&
  'SPEC_RFLU_EnforceBounds.F90')

! ==============================================================================
! Set pointers and variables
! ==============================================================================

  pcvmixt => pregion%mixt%cv
  pcvspec => pregion%spec%cv
  pgrid   => pregion%grid
  
  negvalcntr = 0
  negvalmin  = huge(1.0_rfreal)
  
! ******************************************************************************
! Enforce bounds
! ******************************************************************************

  DO icg = 1,pgrid%nCells
    DO ispec = 1,pregion%specInput%nSpecies
      IF ( pcvspec(ispec,icg) < 0.0_rfreal ) THEN
        negvalcntr = negvalcntr + 1 
        negvalmin = min(negvalmin,pcvspec(ispec,icg))        
        pcvspec(ispec,icg) = 0.0_rfreal                   
      END IF ! pCvSpec
    END DO ! iSpec
  END DO ! icg
           
! ******************************************************************************
! Write information
! ******************************************************************************
           
  IF ( (global%verbLevel > verbose_low) .AND. &
       (global%myProcid == masterproc) ) THEN 
    IF ( (rflu_decideprint(global) .EQV. .true.) .AND. (negvalcntr > 0) ) THEN
      global%warnCounter = global%warnCounter + 1
     
      WRITE(stdout,'(A,1X,A)') solver_name, & 
            '*** WARNING *** Detected negative species mass fractions!'
            
      WRITE(stdout,'(A,3X,A,1X,I5.5)') solver_name,'Global region:', & 
                                       pregion%iRegionGlobal 
      IF ( global%flowType == flow_unsteady ) THEN 
        WRITE(stdout,'(A,3X,A,1X,1PE11.5)') solver_name,'Current time:', & 
                                            global%currentTime
      END IF ! global%flowType
      
      WRITE(stdout,'(A,3X,A,1X,I1)') solver_name,'Runge-Kutta stage:', &
                                     pregion%irkStep      

      WRITE(stdout,'(A,3X,A,1X,I6)') solver_name, & 
            'Number of locations with negative species mass fractions:', &
            negvalcntr
      WRITE(stdout,'(A,3X,A,1X,E23.16)') solver_name, &
            'Largest negative species mass fraction:',negvalmin
      WRITE(stdout,'(A,3X,A)') solver_name, &
            'Negative species mass fractions set to zero.'            
    END IF ! RFLU_DecidePrint
  END IF ! global%verbLevel           
           
! ******************************************************************************
! End
! ******************************************************************************  
      
  CALL deregisterfunction(global)  
    
END SUBROUTINE spec_rflu_enforcebounds


! ******************************************************************************
!
! RCS Revision history:
!
!   $Log: SPEC_RFLU_EnforceBounds.F90,v $
!   Revision 1.3  2008/12/06 08:44:40  mtcampbe
!   Updated license.
!
!   Revision 1.2  2008/11/19 22:17:52  mtcampbe
!   Added Illinois Open Source License/Copyright
!
!   Revision 1.1  2004/01/29 22:59:29  haselbac
!   Initial revision
!
! ******************************************************************************