SPEC_DerivedInputValues.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
! ******************************************************************************
!
! Purpose: Set derived input values for species.
!
! Description: None.
!
! Input:
!   regions     Data associated with regions
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************
!
! $Id: SPEC_DerivedInputValues.F90,v 1.12 2008/12/06 08:44:40 mtcampbe Exp $
!
! Copyright: (c) 2003-2005 by the University of Illinois
!
! ******************************************************************************

SUBROUTINE spec_derivedinputvalues(regions)

  USE moddatatypes
  USE moderror
  USE modparameters
  USE modglobal, ONLY: t_global
  USE moddatastruct, ONLY: t_region  
  USE modspecies, ONLY: t_spec_type

  IMPLICIT NONE

! ******************************************************************************
! Definitions and declarations
! ******************************************************************************

! ==============================================================================
! Arguments
! ==============================================================================

  TYPE(t_region), DIMENSION(:), POINTER :: regions

! ==============================================================================
! Locals
! ==============================================================================

  CHARACTER(CHRLEN) :: rcsidentstring
  INTEGER :: ireg,ispec
  TYPE(t_global), POINTER :: global
  TYPE(t_spec_type), POINTER :: pspectype

! ******************************************************************************
! Start
! ******************************************************************************

  rcsidentstring = '$RCSfile: SPEC_DerivedInputValues.F90,v $ $Revision: 1.12 $'

  global => regions(1)%global

  CALL registerfunction(global,'SPEC_DerivedInputValues',&
  'SPEC_DerivedInputValues.F90')

! ******************************************************************************
! Loop over regions
! ******************************************************************************

  DO ireg = lbound(regions,1),ubound(regions,1)
    regions(ireg)%spec%nSpecEqs = regions(ireg)%specInput%nSpecies

! ==============================================================================
!   Loop over species
! ==============================================================================

    regions(ireg)%specInput%nSpeciesEE = 0

    DO ispec = 1,regions(ireg)%specInput%nSpecies
      pspectype => regions(ireg)%specInput%specType(ispec)

! ------------------------------------------------------------------------------
!     Set source flag
! ------------------------------------------------------------------------------

      SELECT CASE ( pspectype%sourceType )
        CASE ( spec_source_type_none )
          regions(ireg)%specInput%sourceFlag = .false.  
        CASE ( spec_source_type_chem )
          regions(ireg)%specInput%sourceFlag = .true.
        CASE ( spec_source_type_cavi )
          regions(ireg)%specInput%sourceFlag = .true.
        CASE default
          CALL errorstop(global,err_reached_default,__line__, &
                         'Invalid input value for SOURCETYPE')
      END SELECT ! sourceType

! ------------------------------------------------------------------------------
!     Set discreteFlag and related variables
! ------------------------------------------------------------------------------

      pspectype%discreteFlag = (pspectype%pMaterial%phase /= 1) ! i.e., not Gas

      IF ( pspectype%discreteFlag .EQV. .false. ) THEN 
        pspectype%iCont = 1
      ELSE 
        pspectype%iCont = 0
      END IF ! pSpecType%discreteFlag

! --- Discrete species ---------------------------------------------------------

      IF ( pspectype%discreteFlag .EQV. .true. ) THEN 
        pspectype%effectiveDensity = pspectype%pMaterial%dens/  &
                                     pspectype%puffFactor
        pspectype%effectiveVolume  = global%pi*pspectype%diameter**3/ &
                                     6.0_rfreal
        pspectype%materialVolume   = pspectype%effectiveVolume/ &
                                     pspectype%puffFactor

! ----- Include pressure correction: (1 - beta) factor. We have chosen *not* 
!       to set this to 0 for the fluid vel case

        pspectype%tauCoefficient = pspectype%diameter**2* &
          (pspectype%effectiveDensity-1.0_rfreal)/18.0_rfreal

! ----- Do not waste Eq Eul method on cases with tau *exactly* equal to 0

        IF ( pspectype%tauCoefficient == 0.0_rfreal ) THEN
          pspectype%velocityMethod = spec_methv_fluidvel
        END IF ! pSpecType%tauCoefficient

! --- Continuous species -------------------------------------------------------

      ELSE
        pspectype%diameter         = REAL(crazy_value_int,kind=rfreal)
        pspectype%puffFactor       = REAL(crazy_value_int,kind=rfreal)
        pspectype%effectiveDensity = REAL(crazy_value_int,kind=rfreal)
        pspectype%effectiveVolume  = REAL(crazy_value_int,kind=rfreal)
        pspectype%materialVolume   = REAL(crazy_value_int,kind=rfreal)
        pspectype%tauCoefficient   = REAL(crazy_value_int,kind=rfreal)

        IF ( pspectype%velocityMethod /= spec_methv_fluidvel ) THEN
          CALL errorstop(global,err_illegal_value,__line__, &
            'Continuum species must use fluid velocity for advection')
        END IF ! velocityMethod
      END IF ! discreteFlag

! ------------------------------------------------------------------------------
!     Set indSd to address substantial derivative
! ------------------------------------------------------------------------------

      SELECT CASE ( pspectype%velocityMethod )
        CASE ( spec_methv_fluidvel )
          regions(ireg)%mixtInput%indSd = 0     
        CASE ( spec_methv_eqeul )
          regions(ireg)%mixtInput%indSd = 1

          regions(ireg)%specInput%nSpeciesEE = & 
            regions(ireg)%specInput%nSpeciesEE + 1
          pspectype%iSpec2iSpecEEv = regions(ireg)%specInput%nSpeciesEE
          pspectype%iSpecEEv2iSpec = ispec         
        CASE default
          CALL errorstop(global,err_reached_default,__line__, &
                         'Invalid input value for VELOCITYMETHOD')
      END SELECT ! velocityMethod
    END DO ! iSpec

! - require viscosity to be computed if Equilibrium Eulerian velocity is used

    IF ( regions(ireg)%mixtInput%indSd == 1 ) THEN
      regions(ireg)%mixtInput%computeTv = .true.
      
      IF ( regions(ireg)%mixtInput%nTv < 2 ) THEN
        regions(ireg)%mixtInput%nTv = 2
      END IF ! nTv
    END IF ! indSd
  END DO ! iReg

! ******************************************************************************
! End
! ******************************************************************************

  CALL deregisterfunction(global)

END SUBROUTINE spec_derivedinputvalues

! ******************************************************************************
!
! RCS Revision history:
!
! $Log: SPEC_DerivedInputValues.F90,v $
! Revision 1.12  2008/12/06 08:44:40  mtcampbe
! Updated license.
!
! Revision 1.11  2008/11/19 22:17:52  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.10  2006/04/07 15:19:24  haselbac
! Removed tabs
!
! Revision 1.9  2006/03/30 20:50:41  haselbac
! Added setting of sourceFlag for cavitation src term
!
! Revision 1.8  2005/11/27 01:53:40  haselbac
! Added setting of EEv-related variables
!
! Revision 1.7  2005/11/14 17:02:17  haselbac
! Clean-up, added setting of iCont
!
! Revision 1.6  2004/08/02 16:38:40  jferry
! Added pressure correction to tau coefficient
!
! Revision 1.5  2004/07/30 22:47:37  jferry
! Implemented Equilibrium Eulerian method for Rocflu
!
! Revision 1.4  2004/07/28 15:31:34  jferry
! added USED field to SPECIES input section
!
! Revision 1.3  2004/07/23 22:43:17  jferry
! Integrated rocspecies into rocinteract
!
! Revision 1.2  2004/04/01 21:31:18  haselbac
! Added setting of sourceFlag
!
! Revision 1.1  2003/11/25 21:08:37  haselbac
! Initial revision
!
! ******************************************************************************