Rocburn_1D_APN.f90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
  MODULE m_rocburn_1d_apn
! ----------------------------------------------------------------
!
! This module provides the following subroutines for ROCBURN_1D_APN  
! to support ROCBURN_2D:
!
!     INITIALIZE_0D
!     INITIALIZE_1D
!     GET_BURNING_RATE_1D
!
!
! The combustion model used in this quasi-steady empirical model
! rb=a*P^n
!
!   Creation Date    :  Sep. 10, 2002
!
!   Modifications    :
!
!    No.     Date         Authors       Description
!
! ----------------------------------------------------------------
!
!

  USE m_rocburn_apn_global_data

  IMPLICIT NONE

  include 'mpif.h'


  CONTAINS

!
!     ------------------------------------------------------------------------
!                             INTERNAL PROCEDURES
!     ------------------------------------------------------------------------

    SUBROUTINE check_alloc( ierr)
      INTEGER, INTENT(IN) :: ierr
      IF(ierr /= 0) print *, "ROCBRUN_APN ERROR: unable to allocate memory"
      CALL mpi_abort( mpi_comm_world, -1)
    END SUBROUTINE check_alloc
! ============================================================================






    SUBROUTINE initialize_0d( G_APN, comm, Indir, nxmax, To_read)
      TYPE (g_burn_1d), POINTER :: g_apn
      INTEGER, INTENT(IN)       :: comm
      CHARACTER(*), INTENT(IN)  :: indir
      INTEGER, INTENT(OUT)      :: nxmax
      REAL(DBL), INTENT (OUT)   :: to_read

! ---------------------------------------------------------------------------
!     local variables
!


      INTEGER :: ierror

      INTERFACE 
        SUBROUTINE apn_input_0d(G_APN, Indir)
          USE m_rocburn_apn_global_data
          TYPE(g_burn_1d), POINTER :: g_apn
          CHARACTER(*), INTENT(IN) :: indir
        END SUBROUTINE apn_input_0d

      END INTERFACE

      ALLOCATE(g_apn)

!
!     read Rocburn_APN 0d data
!

      g_apn%MPI_COMM_ROCBURN  = comm
      CALL mpi_comm_rank(comm, g_apn%rank, ierror)

      CALL apn_input_0d(g_apn, indir)

      nxmax   = g_apn%nxmax
      to_read = g_apn%To

      RETURN

    END SUBROUTINE initialize_0d
! ============================================================================






    SUBROUTINE initialize_1d( G_APN, bflag, P_mks, To, rhoc_mks, p_coor, rb_mks, Toa, fr, Tn, Tflame)


      IMPLICIT NONE

      TYPE (g_burn_1d), POINTER :: g_apn
      INTEGER, INTENT(INOUT)     :: bflag
      REAL(DBL), INTENT (IN)  :: p_mks, to, rhoc_mks, p_coor(3)
      REAL(DBL), INTENT (OUT) :: rb_mks, toa, fr
      REAL(DBL), INTENT (OUT) :: tn(:)
      REAL(DBL), INTENT (OUT) :: tflame

! ---------------------------------------------------------------------------
!     local variables

      INTEGER :: mat

! ---------------------------------------------------------------------------

      IF( bflag == 0 ) THEN
!
!        not burning or ignition simulation required
!        set condensed phase temperature profile to initial temperature
!

         rb_mks = 0.
         tn = g_apn%To
         tflame = g_apn%To

      ELSE
!
!        burning from onset and no ignition simulation required
!        
!        P    = P_mks *9.869232667E-6           ! Pa to atm

!RAF
!RAF Find out which material applies for this face.  I need the x coord.
!RAF
 
         DO mat=1,g_apn%nmat
           IF (p_coor(1) <= g_apn%xmax(mat)) EXIT
         END DO
         mat = min(mat, g_apn%nmat)

         rb_mks = (g_apn%a_p(mat)*(p_mks*9.869232667e-6)**g_apn%n_p(mat))*0.01   ! cm/s to m/s
         tflame = g_apn%Tf_adiabatic(mat)

         tn = 700.0                             ! do not acutually need temperature profile
                                                ! and do not use in the code

      END IF

      RETURN

    END SUBROUTINE initialize_1d
!! ============================================================================






    SUBROUTINE get_burning_rate_1d( G_APN, delt, P_mks, To, Tn,   &
              qc_mks, qc_old_mks, qr_mks, qr_old_mks, rhoc_mks, &
              toa, rb_mks, fr, bflag, tnp1, tflame, p_coor)
      TYPE (g_burn_1d), POINTER :: g_apn
      REAL(DBL), INTENT (IN)      :: delt, p_mks, to
      REAL(DBL), INTENT (IN)      :: tn(:)
      REAL(DBL), INTENT (IN)      :: qc_mks, qc_old_mks, qr_mks, qr_old_mks
      REAL(DBL), INTENT (IN)      :: rhoc_mks
      REAL(DBL), INTENT (INOUT)   :: toa, rb_mks, fr
      INTEGER,   INTENT (INOUT)   :: bflag
      REAL(DBL), INTENT (OUT)     :: tnp1(:)
      REAL(DBL), INTENT (OUT)     :: tflame
      REAL(DBL), INTENT (IN)      :: p_coor(3)


! ---------------------------------------------------------------------------
!     local variables

      INTEGER :: mat

! ---------------------------------------------------------------------------



      IF(bflag == 1) THEN

!
!        propellant burning already, calculate burning rate using 
!
!        P      = P_mks *9.869232667E-6           ! Pa to atm

!RAF
!RAF Find out which material applies for this face.  I need the x coord.
!RAF
 
         DO mat=1,g_apn%nmat
           IF (p_coor(1) <= g_apn%xmax(mat)) EXIT
         END DO
         mat = min(mat, g_apn%nmat)

         rb_mks = (g_apn%a_p(mat)*(p_mks*9.869232667e-6)**g_apn%n_p(mat))*0.01   ! cm/s to m/s
         tflame = g_apn%Tf_adiabatic(mat)

      ELSE 
!
!        propellant not burning yet
!
  
         rb_mks = 0.0
         tflame = g_apn%To

      END IF

      RETURN

    END SUBROUTINE get_burning_rate_1d

    SUBROUTINE finalize_0d( G_APN)
      TYPE (g_burn_1d), POINTER :: g_apn

      DEALLOCATE( g_apn)
    END SUBROUTINE finalize_0d


  END MODULE m_rocburn_1d_apn