RkUpdatePointScalar.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: Updates particle velocity with classical 4-stage Runge-Kutta method.
!
! Description: None.
!
! Input: 
!   region      Region data
!   iStage      Runge-Kutta stage
!   ivBeg       Beginning index for variable update
!   ivEnd       Ending index for variable update
!   var         Conserved variables
!   varOld      Old conserved variables
!   rhs         Residual
!   rhsSum      Residual sum
!
!
! Output: 
!   var         Variables
!   rhsSum      Residual sum
!
! Notes: None.
!
!******************************************************************************
!
! $Id: RkUpdatePointScalar.F90,v 1.3 2008/12/06 08:44:10 mtcampbe Exp $
!
! Copyright: (c) 2005 by the University of Illinois
!
!******************************************************************************

SUBROUTINE rkupdatepointscalar(region,iStage,ivBeg,ivEnd,var,varOld,rhs,rhsSum)

  USE moddatatypes
  USE moddatastruct, ONLY: t_region
  USE modglobal, ONLY: t_global
  USE moderror
  USE modparameters
  
  IMPLICIT NONE

! *****************************************************************************
! Definitions and declarations
! *****************************************************************************

! =============================================================================
! Arguments
! =============================================================================

  TYPE(t_region) :: region
  INTEGER, INTENT(IN) :: istage,ivbeg,ivend
  REAL(RFREAL), DIMENSION(:), POINTER :: var,varold,rhs,rhssum

! =============================================================================
! Locals
! =============================================================================

  CHARACTER(CHRLEN) :: rcsidentstring
  INTEGER :: iv
  REAL(RFREAL) :: fac
  REAL(RFREAL) :: ark(5),grk(5)
  TYPE(t_global), POINTER :: global

! *****************************************************************************
! Start
! *****************************************************************************

  rcsidentstring = '$RCSfile: RkUpdatePointScalar.F90,v $ $Revision: 1.3 $'

  global => region%global

  CALL registerfunction(global,'RkUpdatePointScalar',&
  'RkUpdatePointScalar.F90')

! *****************************************************************************
! Set pointers and variables
! *****************************************************************************

  ark(:) = region%mixtInput%ark(:)
  grk(:) = region%mixtInput%grk(:)

! *****************************************************************************
! Update
! *****************************************************************************

  fac = ark(istage)*global%dtMin

  SELECT CASE ( global%rkScheme ) 
  CASE ( rk_scheme_4_classical ) 
    IF ( istage == 1 ) THEN
      DO iv = ivbeg,ivend                               
        var(iv)     = varold(iv) + fac*rhs(iv)
        rhssum(iv)  = rhs(iv)
      END DO ! iv
    ELSE IF ( istage == global%nrkSteps ) THEN
      DO iv = ivbeg,ivend                               
        var(iv)     = varold(iv) + fac*(rhs(iv) + rhssum(iv))
      END DO ! iv
    ELSE
      DO iv = ivbeg,ivend                               
        var(iv)     = varold(iv) + fac*rhs(iv)
        rhssum(iv)  = rhssum(iv) + grk(istage)*rhs(iv)
      END DO ! iv
    END IF ! iStage
  CASE ( rk_scheme_3_wray ) 
    IF ( istage == 1 ) THEN
      DO iv = ivbeg,ivend                               
        var(iv)     = varold(iv) + fac*rhs(iv)
        rhssum(iv)  = rhs(iv)
      END DO ! iv
    ELSE IF ( istage == 2 ) THEN
      DO iv = ivbeg,ivend                               
        var(iv)     = varold(iv) + fac*(rhs(iv) - grk(istage)*rhssum(iv))
        rhssum(iv)  = rhs(iv)
      END DO ! iv
    ELSE
      DO iv = ivbeg,ivend                               
        var(iv)     = varold(iv) + fac*(rhs(iv) - grk(istage)*rhssum(iv))
      END DO ! iv
    END IF ! iStage      
  CASE default
    CALL errorstop(global,err_reached_default,__line__)
  END SELECT ! global%rkScheme

! *****************************************************************************
! End
! *****************************************************************************

 CALL deregisterfunction(global)

END SUBROUTINE rkupdatepointscalar

! ******************************************************************************
!
! RCS Revision history:
!
! $Log: RkUpdatePointScalar.F90,v $
! Revision 1.3  2008/12/06 08:44:10  mtcampbe
! Updated license.
!
! Revision 1.2  2008/11/19 22:17:23  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.1  2006/08/19 15:37:27  mparmar
! Initial revision
!
! ******************************************************************************