RkUpdateGeneric.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: Updates solution with classical 4-stage Runge-Kutta method.
!
! Description: None.
!
! Input: 
!   region      Region data
!   varType     Variable type to be updated
!   iStage      Runge-Kutta stage
!   icBeg       Beginning index for cell update
!   icEnd       Ending index for cell update
!   ivBeg       Beginning index for variable update
!   ivEnd       Ending index for variable update
!   cv          Conserved variables
!   cvOld       Old conserved variables
!   rhs         Residual
!   rhsSum      Residual sum
!
! Output: 
!   cv          Conserved variables
!   rhsSum      Residual sum
!
! Notes: None.
!
!******************************************************************************
!
! $Id: RkUpdateGeneric.F90,v 1.4 2008/12/06 08:44:10 mtcampbe Exp $
!
! Copyright: (c) 2003 by the University of Illinois
!
!******************************************************************************

SUBROUTINE rkupdategeneric(region,varType,iStage,icBeg,icEnd,ivBeg,ivEnd, &
                           cv,cvold,rhs,rhssum)

  USE moddatatypes
  USE moddatastruct, ONLY: t_region
  USE modglobal, ONLY: t_global
  USE moderror
  USE modparameters
  
  IMPLICIT NONE

! *****************************************************************************
! Definitions and declarations
! *****************************************************************************

! =============================================================================
! Arguments
! =============================================================================

  TYPE(t_region) :: region
  INTEGER, INTENT(IN) :: icbeg,icend,istage,ivbeg,ivend,vartype
  REAL(RFREAL), DIMENSION(:,:), POINTER :: cv,cvold,rhs,rhssum

! =============================================================================
! Locals
! =============================================================================

  LOGICAL :: movegrid
  CHARACTER(CHRLEN) :: rcsidentstring
  INTEGER :: ic,iv
#ifdef RFLO
  INTEGER :: ilev
#endif  
  REAL(RFREAL) :: adtv,fac,volrat  
  REAL(RFREAL) :: ark(5),grk(5)
  REAL(RFREAL), DIMENSION(:), POINTER :: vol,volold
  TYPE(t_global), POINTER :: global

! *****************************************************************************
! Start
! *****************************************************************************

  rcsidentstring = '$RCSfile: RkUpdateGeneric.F90,v $ $Revision: 1.4 $'

  global => region%global

  CALL registerfunction(global,'RkUpdateGeneric',&
  'RkUpdateGeneric.F90')

! *****************************************************************************
! Set pointers and variables
! *****************************************************************************

  ark(:) = region%mixtInput%ark(:)
  grk(:) = region%mixtInput%grk(:)

! =============================================================================
! Set volume(s) when updating cell-based variables
! =============================================================================

  IF ( vartype == var_type_cell ) THEN 
    movegrid = region%mixtInput%moveGrid

#ifdef RFLO
    ilev = region%currLevel

    vol => region%levels(ilev)%grid%vol

    IF ( movegrid .EQV. .true. ) THEN 
      volold => region%levels(ilev)%gridOld%vol
    END IF ! moveGrid
#endif

#ifdef RFLU
    vol => region%grid%vol

    IF ( movegrid .EQV. .true. ) THEN 
      volold => region%gridOld%vol
    END IF ! moveGrid
#endif
  END IF ! varType

! *****************************************************************************
! Update
! *****************************************************************************

  fac = ark(istage)*global%dtMin

  SELECT CASE ( vartype ) 
  
! =============================================================================
!   Update cell-based variables, for which we need the volume (and volume 
!   ratio for moving grid computations). 
! =============================================================================
  
    CASE ( var_type_cell )   
        
! -----------------------------------------------------------------------------
!     Update for moving grid
! -----------------------------------------------------------------------------

      IF ( movegrid .EQV. .true. ) THEN
        SELECT CASE ( global%rkScheme ) 
          CASE ( rk_scheme_4_classical ) 
            IF ( istage == 1 ) THEN
              DO ic = icbeg,icend
                adtv   = fac/vol(ic)
                volrat = volold(ic)/vol(ic)

                DO iv = ivbeg,ivend
                  cv(iv,ic)     = volrat*cvold(iv,ic) - adtv*rhs(iv,ic)
                  rhssum(iv,ic) = rhs(iv,ic)
                END DO ! iv
              END DO ! ic      
            ELSE IF ( istage == global%nrkSteps ) THEN
              DO ic = icbeg,icend
                adtv   = fac/vol(ic)
                volrat = volold(ic)/vol(ic)

                DO iv = ivbeg,ivend                                       
                  cv(iv,ic) = volrat*cvold(iv,ic) & 
                            - adtv*(rhs(iv,ic)+rhssum(iv,ic))
                END DO ! iv
              END DO ! ic      
            ELSE
              DO ic = icbeg,icend
                adtv   = fac/vol(ic)
                volrat = volold(ic)/vol(ic)

                DO iv = ivbeg,ivend
                  cv(iv,ic)     = volrat*cvold(iv,ic) - adtv*rhs(iv,ic)
                  rhssum(iv,ic) = rhssum(iv,ic) + grk(istage)*rhs(iv,ic)
                END DO ! iv
              END DO ! ic
            END IF ! iStage
          CASE ( rk_scheme_3_wray ) 
            IF ( istage == 1 ) THEN
              DO ic = icbeg,icend
                adtv   = fac/vol(ic)
                volrat = volold(ic)/vol(ic)

                DO iv = ivbeg,ivend
                  cv(iv,ic)     = volrat*cvold(iv,ic) - adtv*rhs(iv,ic)
                  rhssum(iv,ic) = rhs(iv,ic)
                END DO ! iv
              END DO ! ic      
            ELSE IF ( istage == 2 ) THEN
              DO ic = icbeg,icend
                adtv   = fac/vol(ic)
                volrat = volold(ic)/vol(ic)

                DO iv = ivbeg,ivend                                       
                  cv(iv,ic)     = volrat*cvold(iv,ic) & 
                                - adtv*(rhs(iv,ic) - grk(istage)*rhssum(iv,ic))
                  rhssum(iv,ic) = rhs(iv,ic)              
                END DO ! iv
              END DO ! ic      
            ELSE
              DO ic = icbeg,icend
                adtv   = fac/vol(ic)
                volrat = volold(ic)/vol(ic)

                DO iv = ivbeg,ivend
                  cv(iv,ic) = volrat*cvold(iv,ic) & 
                            - adtv*(rhs(iv,ic) - grk(istage)*rhssum(iv,ic))
                END DO ! iv
              END DO ! ic
            END IF ! iStage      
          CASE default 
            CALL errorstop(global,err_reached_default,__line__)
        END SELECT ! global%rkScheme

! =============================================================================
!     Update for non-moving grid
! =============================================================================

      ELSE 
        SELECT CASE ( global%rkScheme ) 
          CASE ( rk_scheme_4_classical ) 
            IF ( istage == 1 ) THEN
              DO ic = icbeg,icend
                adtv = fac/vol(ic) 

                DO iv = ivbeg,ivend                               
                  cv(iv,ic)     = cvold(iv,ic) - adtv*rhs(iv,ic)
                  rhssum(iv,ic) = rhs(iv,ic)
                END DO ! iv
              END DO ! ic
            ELSE IF ( istage == global%nrkSteps ) THEN
              DO ic = icbeg,icend
                adtv = fac/vol(ic)

                DO iv = ivbeg,ivend
                  cv(iv,ic) = cvold(iv,ic) - adtv*(rhs(iv,ic) + rhssum(iv,ic))
                END DO ! iv
              END DO !ic      
            ELSE
              DO ic = icbeg,icend
                adtv = fac/vol(ic) 

                DO iv = ivbeg,ivend          
                  cv(iv,ic)     = cvold(iv,ic) - adtv*rhs(iv,ic)
                  rhssum(iv,ic) = rhssum(iv,ic) + grk(istage)*rhs(iv,ic)
                END DO ! iv
              END DO !ic      
            END IF ! iStage
          CASE ( rk_scheme_3_wray ) 
            IF ( istage == 1 ) THEN
              DO ic = icbeg,icend
                adtv = fac/vol(ic) 

                DO iv = ivbeg,ivend                               
                  cv(iv,ic)     = cvold(iv,ic) - adtv*rhs(iv,ic)
                  rhssum(iv,ic) = rhs(iv,ic)
                END DO ! iv
              END DO ! ic
            ELSE IF ( istage == 2 ) THEN
              DO ic = icbeg,icend
                adtv = fac/vol(ic)

                DO iv = ivbeg,ivend
                  cv(iv,ic)     = cvold(iv,ic) & 
                                - adtv*(rhs(iv,ic) - grk(istage)*rhssum(iv,ic))
                  rhssum(iv,ic) = rhs(iv,ic)              
                END DO ! iv
              END DO !ic      
            ELSE
              DO ic = icbeg,icend
                adtv = fac/vol(ic) 

                DO iv = ivbeg,ivend          
                  cv(iv,ic) = cvold(iv,ic) & 
                            - adtv*(rhs(iv,ic) - grk(istage)*rhssum(iv,ic))
                END DO ! iv
              END DO !ic      
            END IF ! iStage      
          CASE default
            CALL errorstop(global,err_reached_default,__line__)
        END SELECT ! global%rkScheme
      END IF ! moveGrid

! =============================================================================
!   Update point-based variables, for which we DO NOT need the volume (and 
!   volume ratio for moving grid computations). 
! =============================================================================
  
    CASE ( var_type_point )
      adtv = fac

      SELECT CASE ( global%rkScheme ) 
        CASE ( rk_scheme_4_classical ) 
          IF ( istage == 1 ) THEN
            DO ic = icbeg,icend
              DO iv = ivbeg,ivend                               
                cv(iv,ic)     = cvold(iv,ic) - adtv*rhs(iv,ic)
                rhssum(iv,ic) = rhs(iv,ic)
              END DO ! iv
            END DO ! ic
          ELSE IF ( istage == global%nrkSteps ) THEN
            DO ic = icbeg,icend
              DO iv = ivbeg,ivend
                cv(iv,ic) = cvold(iv,ic) - adtv*(rhs(iv,ic) + rhssum(iv,ic))
              END DO ! iv
            END DO !ic      
          ELSE
            DO ic = icbeg,icend
              DO iv = ivbeg,ivend          
                cv(iv,ic)     = cvold(iv,ic) - adtv*rhs(iv,ic)
                rhssum(iv,ic) = rhssum(iv,ic) + grk(istage)*rhs(iv,ic)
              END DO ! iv
            END DO !ic      
          END IF ! iStage
        CASE ( rk_scheme_3_wray ) 
          IF ( istage == 1 ) THEN
            DO ic = icbeg,icend
              DO iv = ivbeg,ivend                               
                cv(iv,ic)     = cvold(iv,ic) - adtv*rhs(iv,ic)
                rhssum(iv,ic) = rhs(iv,ic)
              END DO ! iv
            END DO ! ic
          ELSE IF ( istage == 2 ) THEN
            DO ic = icbeg,icend
              DO iv = ivbeg,ivend
                cv(iv,ic)     = cvold(iv,ic) & 
                              - adtv*(rhs(iv,ic) - grk(istage)*rhssum(iv,ic))
                rhssum(iv,ic) = rhs(iv,ic)              
              END DO ! iv
            END DO !ic      
          ELSE
            DO ic = icbeg,icend
              DO iv = ivbeg,ivend          
                cv(iv,ic) = cvold(iv,ic) & 
                          - adtv*(rhs(iv,ic) - grk(istage)*rhssum(iv,ic))
              END DO ! iv
            END DO !ic      
          END IF ! iStage      
        CASE default
          CALL errorstop(global,err_reached_default,__line__)
      END SELECT ! global%rkScheme
    CASE default 
      CALL errorstop(global,err_reached_default,__line__)       
  END SELECT ! varType

! *****************************************************************************
! End
! *****************************************************************************

 CALL deregisterfunction(global)

END SUBROUTINE rkupdategeneric

!******************************************************************************
!
! RCS Revision history:
!
! $Log: RkUpdateGeneric.F90,v $
! Revision 1.4  2008/12/06 08:44:10  mtcampbe
! Updated license.
!
! Revision 1.3  2008/11/19 22:17:23  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.2  2006/04/07 15:19:15  haselbac
! Removed tabs
!
! Revision 1.1  2004/12/01 16:51:08  haselbac
! Initial revision after changing case
!
! Revision 1.2  2004/11/17 16:24:30  haselbac
! Added varType and RK3
!
! Revision 1.1  2003/11/25 21:01:50  haselbac
! Initial revision
!
!******************************************************************************