RFLU_SetGasVars.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
! ******************************************************************************
!
! Purpose: Set gas variables.
!
! Description: None.
!
! Input: 
!  pRegion      Pointer to region
!  icgBeg       Beginning cell index
!  icgEnd       Ending cell index
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************
!
! $Id: RFLU_SetGasVars.F90,v 1.10 2008/12/06 08:44:13 mtcampbe Exp $
!
! Copyright: (c) 2004-2006 by the University of Illinois
!
! ******************************************************************************

SUBROUTINE rflu_setgasvars(pRegion,icgBeg,icgEnd)

  USE moddatatypes
  USE modparameters
  USE moderror
  USE modglobal, ONLY: t_global
  USE moddatastruct, ONLY: t_region
  USE modgrid, ONLY: t_grid

#ifdef SPEC
  USE modspecies, ONLY: t_spec_type
#endif

  USE modinterfaces, ONLY: mixtperf_m_r, & 
                           mixtperf_r_cpg, &
                           mixtperf_r_m
                                 
  IMPLICIT NONE

! ******************************************************************************
! Definitions and declarations
! ******************************************************************************

! ==============================================================================  
! Arguments 
! ==============================================================================  

  INTEGER, INTENT(IN) :: icgbeg,icgend
  TYPE(t_region), POINTER :: pregion

! ==============================================================================  
! Locals
! ==============================================================================  

  CHARACTER(CHRLEN) :: rcsidentstring
  INTEGER :: icg,indcp,indmol
  REAL(RFREAL) :: cpgasref,gc,ggas,ggasref
  REAL(RFREAL), DIMENSION(:,:), POINTER :: pcv,pgv
  TYPE(t_global), POINTER :: global

#ifdef SPEC
  INTEGER :: ispec
  REAL(RFREAL) :: cp,gcg,gcm,imm,immg,mmg,phip,r,yg,yi
  REAL(RFREAL), DIMENSION(:,:), POINTER :: pcvspec
  TYPE(t_spec_type), POINTER :: pspectype
#endif

! ******************************************************************************
! Start
! ******************************************************************************

  rcsidentstring = '$RCSfile: RFLU_SetGasVars.F90,v $ $Revision: 1.10 $'

  global => pregion%global

  CALL registerfunction(global,'RFLU_SetGasVars',&
  'RFLU_SetGasVars.F90')

! ******************************************************************************
! Set variables and pointers
! ******************************************************************************

  pcv => pregion%mixt%cv 
  pgv => pregion%mixt%gv 

#ifdef SPEC
  pcvspec => pregion%spec%cv
#endif

  indcp  = pregion%mixtInput%indCp
  indmol = pregion%mixtInput%indMol
  
  cpgasref = global%refCp
  ggasref  = global%refGamma
  
! ******************************************************************************  
! Compute dependent variables
! ******************************************************************************

  SELECT CASE ( pregion%mixtInput%fluidModel ) 

! ==============================================================================  
!   Incompressible fluid model
! ==============================================================================  

    CASE ( fluid_model_incomp ) 

! ==============================================================================  
!   Compressible fluid model
! ==============================================================================  
    
    CASE ( fluid_model_comp ) 
      SELECT CASE ( pregion%mixtInput%gasModel )
      
! ------------------------------------------------------------------------------
!       Thermally and calorically perfect gas
! ------------------------------------------------------------------------------     
       
        CASE ( gas_model_tcperf ) 
          gc = mixtperf_r_cpg(cpgasref,ggasref)
  
          DO icg = icgbeg,icgend
            pgv(gv_mixt_mol,icg*indmol) = mixtperf_m_r(gc)
            pgv(gv_mixt_cp ,icg*indcp ) = cpgasref    
          END DO ! icg

! ------------------------------------------------------------------------------
!       Mixture of thermally and calorically perfect gases
! ------------------------------------------------------------------------------     

        CASE ( gas_model_mixt_tcperf )         
#ifdef SPEC
          IF ( pregion%spec%cvState /= cv_mixt_state_prim ) THEN 
            CALL errorstop(global,err_cv_state_invalid,__line__)
          END IF ! pRegion%spec%cvState  

          DO icg = icgbeg,icgend            
            imm = 0.0_rfreal
            cp  = 0.0_rfreal
            
            DO ispec = 1,pregion%specInput%nSpecies
              pspectype => pregion%specInput%specType(ispec)
                        
              imm = imm + pcvspec(ispec,icg)/pspectype%pMaterial%molw
              cp  = cp  + pcvspec(ispec,icg)*pspectype%pMaterial%spht
            END DO ! iSpec
          
            pgv(gv_mixt_mol,icg) = 1.0_rfreal/imm
            pgv(gv_mixt_cp ,icg) = cp
          END DO ! icg
#else
          CALL errorstop(global,err_reached_default,__line__) ! Defensive coding
#endif              

! ------------------------------------------------------------------------------
!       Mixture of thermally and calorically perfect gaseous species and 
!       particulate species, treated as pseudo-gas
! ------------------------------------------------------------------------------     

        CASE ( gas_model_mixt_pseudo )         
#ifdef SPEC
          IF ( pregion%spec%cvState /= cv_mixt_state_prim ) THEN 
            CALL errorstop(global,err_cv_state_invalid,__line__)
          END IF ! pRegion%spec%cvState  

          DO icg = icgbeg,icgend
            r = pcv(cv_mixt_dens,icg)

            immg = 0.0_rfreal
            cp   = 0.0_rfreal
            yg   = 0.0_rfreal
            phip = 0.0_rfreal

            DO ispec = 1,pregion%specInput%nSpecies
              pspectype => pregion%specInput%specType(ispec)

              yi = pcvspec(ispec,icg)

              cp = cp + yi*pspectype%pMaterial%spht

              IF ( pspectype%discreteFlag .EQV. .true. ) THEN 
                phip = phip + r*yi/pspectype%pMaterial%dens
              ELSE 
                immg = immg + yi/pspectype%pMaterial%molw
                yg   = yg   + yi                                                              
              END IF ! pSpecType%discreteFlag
            END DO ! iSpec

            mmg = yg/immg
            gcg = mixtperf_r_m(mmg)
            gcm = yg*gcg

            pgv(gv_mixt_mol,icg) = mixtperf_m_r(gcm)
            pgv(gv_mixt_cp ,icg) = cp
          END DO ! icg
#else
          CALL errorstop(global,err_reached_default,__line__) ! Defensive coding
#endif                   

! ------------------------------------------------------------------------------     
!       Gas-liquid mixture fluid model
! ------------------------------------------------------------------------------     

        CASE ( gas_model_mixt_gasliq ) 
#ifdef SPEC
          IF ( pregion%spec%cvState /= cv_mixt_state_prim ) THEN 
            CALL errorstop(global,err_cv_state_invalid,__line__)
          END IF ! pRegion%spec%cvState  

          DO icg = icgbeg,icgend
            pgv(gv_mixt_mol,icg*indmol) = &
              pregion%specInput%specType(1)%pMaterial%molw
            pgv(gv_mixt_cp ,icg*indcp ) = &
              pregion%specInput%specType(1)%pMaterial%spht 
          END DO ! icg

#else
          CALL errorstop(global,err_reached_default,__line__) ! Defensive coding
#endif 

! ------------------------------------------------------------------------------
!       Default
! ------------------------------------------------------------------------------     

        CASE default
          CALL errorstop(global,err_reached_default,__line__)
      END SELECT ! pRegion%mixtInput%gasModel
      
! ==============================================================================  
!   Default
! ==============================================================================  

    CASE default
      CALL errorstop(global,err_reached_default,__line__)    
  END SELECT ! pRegion%mixtInput%fluidModel


! ******************************************************************************
! End
! ******************************************************************************

  CALL deregisterfunction(global)

END SUBROUTINE rflu_setgasvars

! ******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLU_SetGasVars.F90,v $
! Revision 1.10  2008/12/06 08:44:13  mtcampbe
! Updated license.
!
! Revision 1.9  2008/11/19 22:17:26  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.8  2006/08/15 15:23:54  haselbac
! Cosmetic changes only
!
! Revision 1.7  2006/04/07 15:19:16  haselbac
! Removed tabs
!
! Revision 1.6  2006/03/26 20:21:44  haselbac
! Added support for GL model
!
! Revision 1.5  2005/11/14 16:55:17  haselbac
! Added support for pseudo-gas model
!
! Revision 1.4  2005/11/10 02:15:33  haselbac
! Added support for different gas models
!
! Revision 1.3  2005/04/15 15:06:21  haselbac
! Added range arguments, removed pGrid declaration
!
! Revision 1.2  2004/11/14 19:43:09  haselbac
! Added setting of gv for incompressible fluid model
!
! Revision 1.1  2004/10/19 19:23:55  haselbac
! Initial revision
!
! ******************************************************************************