RFLU_SetDependentVars.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
! ******************************************************************************
!
! Purpose: Set dependent variables.
!
! Description: None.
!
! Input: 
!  pRegion      Pointer to region
!  icgBeg       Beginning cell index
!  icgEnd       Ending cell index
!
! Output: None.
!
! Notes: 
!   1. Restricted to perfect gas.
!
! ******************************************************************************
!
! $Id: RFLU_SetDependentVars.F90,v 1.11 2008/12/06 08:44:13 mtcampbe Exp $
!
! Copyright: (c) 2004-2006 by the University of Illinois
!
! ******************************************************************************

SUBROUTINE rflu_setdependentvars(pRegion,icgBeg,icgEnd)

  USE moddatatypes
  USE modparameters
  USE moderror
  USE modglobal, ONLY: t_global
  USE moddatastruct, ONLY: t_region
  USE modgrid, ONLY: t_grid

#ifdef SPEC
  USE modspecies, ONLY: t_spec_type
#endif

  USE modinterfaces, ONLY: mixtgasliq_c, &
                           mixtgasliq_p, &
                           mixtliq_c2_bp, &
                           mixtliq_d_dobpppobttto, &
                           mixtperf_c_grt, &
                           mixtperf_c2_grt, &
                           mixtperf_cv_cpr, &                       
                           mixtperf_d_prt, &
                           mixtperf_g_cpr, & 
                           mixtperf_p_deogvm2, & 
                           mixtperf_r_m, &
                           mixtperf_t_cveovm2, & 
                           mixtperf_t_dpr
                                 
  IMPLICIT NONE

! ******************************************************************************
! Definitions and declarations
! ******************************************************************************

! ==============================================================================  
! Arguments 
! ==============================================================================  

  INTEGER, INTENT(IN) :: icgbeg,icgend
  TYPE(t_region), POINTER :: pregion

! ==============================================================================  
! Locals
! ==============================================================================  

  CHARACTER(CHRLEN) :: rcsidentstring
  INTEGER :: icg,indcp,indmol
  REAL(RFREAL) :: eo,g,gc,ir,r,rg,term,vm2
  REAL(RFREAL), DIMENSION(:,:), POINTER :: pcv,pdv,pgv
  TYPE(t_global), POINTER :: global

#ifdef SPEC
  INTEGER :: ispec
  REAL(RFREAL) :: bg2,bl2,bp,bt,bv2,cg2,cl2,cpg,cpm,cv2,cvg,cvl,cvm,cvv, &
                  gcg,gcm,gcv,gm,immg,mmg,mmm,phip,po,rl,ro,rv,ryg,ryi,ryl, &
                  ryv,to,vfg,vfl,vfv,yg
  REAL(RFREAL), DIMENSION(:,:), POINTER :: pcvspec
  TYPE(t_spec_type), POINTER :: pspectype
#endif

! ******************************************************************************
! Start
! ******************************************************************************

  rcsidentstring = '$RCSfile: RFLU_SetDependentVars.F90,v $ $Revision: 1.11 $'

  global => pregion%global

  CALL registerfunction(global,'RFLU_SetDependentVars',&
  'RFLU_SetDependentVars.F90')

! ******************************************************************************
! Set variables and pointers
! ******************************************************************************

  pcv => pregion%mixt%cv
  pdv => pregion%mixt%dv 
  pgv => pregion%mixt%gv 
  
#ifdef SPEC  
  pcvspec => pregion%spec%cv
#endif

  indcp  = pregion%mixtInput%indCp
  indmol = pregion%mixtInput%indMol
  
! ******************************************************************************  
! Compute dependent variables
! ******************************************************************************

  SELECT CASE ( pregion%mixtInput%fluidModel )
  
! ==============================================================================  
!   Incompressible fluid model
! ==============================================================================  
   
    CASE ( fluid_model_incomp ) 

! ==============================================================================  
!   Compressible fluid model. NOTE check state of solution vector.
! ==============================================================================  

    CASE ( fluid_model_comp )
      SELECT CASE ( pregion%mixtInput%gasModel ) 
      
! ------------------------------------------------------------------------------
!       Thermally and calorically perfect gas (single species)
! ------------------------------------------------------------------------------     
      
        CASE ( gas_model_tcperf ) 
          IF ( pregion%mixt%cvState /= cv_mixt_state_cons ) THEN 
            CALL errorstop(global,err_cv_state_invalid,__line__)
          END IF ! pRegion%mixt%cvState    

          DO icg = icgbeg,icgend
            gc = mixtperf_r_m(pgv(gv_mixt_mol,icg*indmol))
            g  = mixtperf_g_cpr(pgv(gv_mixt_cp,icg*indcp),gc)

            r  = pcv(cv_mixt_dens,icg)
            ir = 1.0_rfreal/r
            eo = ir*pcv(cv_mixt_ener,icg)

            vm2 = ir*ir*(pcv(cv_mixt_xmom,icg)*pcv(cv_mixt_xmom,icg) + &
                         pcv(cv_mixt_ymom,icg)*pcv(cv_mixt_ymom,icg) + &
                         pcv(cv_mixt_zmom,icg)*pcv(cv_mixt_zmom,icg))

            pdv(dv_mixt_pres,icg) = mixtperf_p_deogvm2(r,eo,g,vm2)
            pdv(dv_mixt_temp,icg) = mixtperf_t_dpr(r,pdv(dv_mixt_pres,icg),gc)
            pdv(dv_mixt_soun,icg) = mixtperf_c_grt(g,gc, &
                                                   pdv(dv_mixt_temp,icg))    
          END DO ! icg

! ------------------------------------------------------------------------------
!       Mixture of thermally and calorically perfect gases
! ------------------------------------------------------------------------------     
      
        CASE ( gas_model_mixt_tcperf ) 
          IF ( pregion%mixt%cvState /= cv_mixt_state_cons ) THEN 
            CALL errorstop(global,err_cv_state_invalid,__line__)
          END IF ! pRegion%mixt%cvState    

          DO icg = icgbeg,icgend
            gc = mixtperf_r_m(pgv(gv_mixt_mol,icg))
            g  = mixtperf_g_cpr(pgv(gv_mixt_cp,icg),gc)

            r  = pcv(cv_mixt_dens,icg)
            ir = 1.0_rfreal/r
            eo = ir*pcv(cv_mixt_ener,icg)

            vm2 = ir*ir*(pcv(cv_mixt_xmom,icg)*pcv(cv_mixt_xmom,icg) + &
                         pcv(cv_mixt_ymom,icg)*pcv(cv_mixt_ymom,icg) + &
                         pcv(cv_mixt_zmom,icg)*pcv(cv_mixt_zmom,icg))

            pdv(dv_mixt_pres,icg) = mixtperf_p_deogvm2(r,eo,g,vm2)
            pdv(dv_mixt_temp,icg) = mixtperf_t_dpr(r,pdv(dv_mixt_pres,icg),gc)
            pdv(dv_mixt_soun,icg) = mixtperf_c_grt(g,gc, &
                                                   pdv(dv_mixt_temp,icg))    
          END DO ! icg

! ------------------------------------------------------------------------------
!       Pseudogas
! ------------------------------------------------------------------------------     
      
        CASE ( gas_model_mixt_pseudo ) 
#ifdef SPEC        
          IF ( pregion%mixt%cvState /= cv_mixt_state_cons ) THEN 
            CALL errorstop(global,err_cv_state_invalid,__line__)
          END IF ! pRegion%mixt%cvState    

          DO icg = icgbeg,icgend
            mmm = pgv(gv_mixt_mol,icg)
            cpm = pgv(gv_mixt_cp ,icg)            
            gcm = mixtperf_r_m(mmm)
            gm  = mixtperf_g_cpr(cpm,gcm)

            r  = pcv(cv_mixt_dens,icg)
            ir = 1.0_rfreal/r
            eo = ir*pcv(cv_mixt_ener,icg)

            cpg  = 0.0_rfreal
            yg   = 0.0_rfreal
            phip = 0.0_rfreal

            DO ispec = 1,pregion%specInput%nSpecies
              pspectype => pregion%specInput%specType(ispec)

              ryi = pcvspec(ispec,icg)

              IF ( pspectype%discreteFlag .EQV. .true. ) THEN 
                phip = phip + ryi/pspectype%pMaterial%dens
              ELSE 
                cpg  = cpg  + ir*ryi*pspectype%pMaterial%spht 
                yg   = yg   + ir*ryi                                                              
              END IF ! pSpecType%discreteFlag
            END DO ! iSpec

            cpg = cpg/yg
            
            vm2 = ir*ir*(pcv(cv_mixt_xmom,icg)*pcv(cv_mixt_xmom,icg) + &
                         pcv(cv_mixt_ymom,icg)*pcv(cv_mixt_ymom,icg) + &
                         pcv(cv_mixt_zmom,icg)*pcv(cv_mixt_zmom,icg))

            term = mixtperf_p_deogvm2(r,eo,gm,vm2)
            pdv(dv_mixt_pres,icg) = cpm/cpg*term/(1.0_rfreal-phip)
            
            term = mixtperf_t_dpr(r,pdv(dv_mixt_pres,icg),gcm)            
            pdv(dv_mixt_temp,icg) = term*(1.0_rfreal-phip)
            
            term = mixtperf_c_grt(gm,gcm,pdv(dv_mixt_temp,icg))
            pdv(dv_mixt_soun,icg) = term/(1.0_rfreal-phip)
          END DO ! icg
#else
          CALL errorstop(global,err_reached_default,__line__) ! Defensive coding
#endif

! ------------------------------------------------------------------------------
!       Mixture of gas, liquid, and vapor
! ------------------------------------------------------------------------------     
      
        CASE ( gas_model_mixt_gasliq ) 
#ifdef SPEC
          IF ( pregion%mixt%cvState /= cv_mixt_state_cons ) THEN 
            CALL errorstop(global,err_cv_state_invalid,__line__)
          END IF ! pRegion%mixt%cvState  

          ro  = global%refDensityLiq
          po  = global%refPressLiq
          to  = global%refTempLiq
          bp  = global%refBetaPLiq
          bt  = global%refBetaTLiq
          cvl = global%refCvLiq

          gcg = mixtperf_r_m(pregion%specInput%specType(1)%pMaterial%molw)
          cvg = mixtperf_cv_cpr(pregion%specInput%specType(1)%pMaterial%spht, &
                                 gcg)

          gcv = mixtperf_r_m(pregion%specInput%specType(2)%pMaterial%molw)
          cvv = mixtperf_cv_cpr(pregion%specInput%specType(2)%pMaterial%spht, &
                                 gcv)

          DO icg = icgbeg,icgend
            r   = pcv(cv_mixt_dens,icg)
            ir  = 1.0_rfreal/r
            eo  = ir*pcv(cv_mixt_ener,icg)
            
            ryg = r*pcvspec(1,icg)
            ryv = r*pcvspec(2,icg) 
            ryl = r - ryg - ryv

            vm2 = ir*ir*(pcv(cv_mixt_xmom,icg)*pcv(cv_mixt_xmom,icg) + &
                         pcv(cv_mixt_ymom,icg)*pcv(cv_mixt_ymom,icg) + &
                         pcv(cv_mixt_zmom,icg)*pcv(cv_mixt_zmom,icg))
            cvm = (ryl*cvl + ryv*cvv + ryg*cvg)/r

            pdv(dv_mixt_temp,icg) = mixtperf_t_cveovm2(cvm,eo,vm2) 

            cl2 = mixtliq_c2_bp(bp) 
            cv2 = mixtperf_c2_grt(1.0_rfreal,gcv,pdv(dv_mixt_temp,icg))
            cg2 = mixtperf_c2_grt(1.0_rfreal,gcg,pdv(dv_mixt_temp,icg))
            pdv(dv_mixt_pres,icg) = mixtgasliq_p(ryl,ryv,ryg,cl2,cv2,cg2,r, &
                                                 ro,po,to,bp,bt, &
                                                 pdv(dv_mixt_temp,icg))

            rl = mixtliq_d_dobpppobttto(ro,bp,bt,pdv(dv_mixt_pres,icg),po, &
                                        pdv(dv_mixt_temp,icg),to)
            rv = mixtperf_d_prt(pdv(dv_mixt_pres,icg),gcv, &
                                pdv(dv_mixt_temp,icg))
            rg = mixtperf_d_prt(pdv(dv_mixt_pres,icg),gcg, &
                                pdv(dv_mixt_temp,icg))

            vfg = ryg/rg
            vfv = ryv/rv
            vfl = ryl/rl    

            bl2 = -bt/bp
            bv2 = rv*gcv
            bg2 = rg*gcg

            pdv(dv_mixt_soun,icg) = mixtgasliq_c(cvm,r,pdv(dv_mixt_pres,icg), &
                                                 rl,rv,rg,vfl,vfv,vfg,cl2, &
                                                 cv2,cg2,bl2,bv2,bg2)
          END DO ! icg
#else
          CALL errorstop(global,err_reached_default,__line__) ! Defensive coding
#endif

! ------------------------------------------------------------------------------
!       Default
! ------------------------------------------------------------------------------     

        CASE default
          CALL errorstop(global,err_reached_default,__line__) 
      END SELECT ! pRegion%mixtInput%gasModel

! ==============================================================================  
!   Default
! ==============================================================================  

    CASE default 
      CALL errorstop(global,err_reached_default,__line__)
  END SELECT ! pRegion%mixtInput%fluidModel 

! ******************************************************************************
! End
! ******************************************************************************

  CALL deregisterfunction(global)

END SUBROUTINE rflu_setdependentvars

! ******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLU_SetDependentVars.F90,v $
! Revision 1.11  2008/12/06 08:44:13  mtcampbe
! Updated license.
!
! Revision 1.10  2008/11/19 22:17:26  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.9  2006/08/16 19:16:39  haselbac
! Bug fix: bad check-in, declarations missing
!
! Revision 1.8  2006/08/15 15:23:19  haselbac
! Bug fix: dv was computed incorrectly for pseudo-gas
!
! Revision 1.7  2006/04/07 15:19:16  haselbac
! Removed tabs
!
! Revision 1.6  2006/03/26 20:21:40  haselbac
! Added support for GL model
!
! Revision 1.5  2005/11/14 16:55:17  haselbac
! Added support for pseudo-gas model
!
! Revision 1.4  2005/11/10 02:14:49  haselbac
! Added SELECT CASE on gasModel
!
! Revision 1.3  2005/04/15 15:06:20  haselbac
! Added range arguments, removed pGrid declaration
!
! Revision 1.2  2004/11/14 19:41:20  haselbac
! Added setting of dv for incompressible fluid model
!
! Revision 1.1  2004/10/19 19:23:53  haselbac
! Initial revision
!
! ******************************************************************************