RFLU_ScalarViscousFluxes.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: Compute viscous fluxes of scalar for actual faces.
!
! Description: None.
!
! Input: 
!  pRegion      Pointer to region
!  nVarScal     Number of scalar variables
!  tvScal       Scalar transport variables
!  gradScal     Scalar face gradients
!  resScal      Scalar residuals
!
! Output: None.
!
! Notes: 
!   1. The viscosity must be a dynamic viscosity!
!
!******************************************************************************
!
! $Id: RFLU_ScalarViscousFluxes.F90,v 1.4 2008/12/06 08:44:13 mtcampbe Exp $
!
! Copyright: (c) 2004 by the University of Illinois
!
!******************************************************************************

SUBROUTINE rflu_scalarviscousfluxes(pRegion,nVarScal,tvScal,gradScal,resScal)

  USE moddatatypes
  USE modparameters
  USE moderror
  USE modglobal, ONLY: t_global
  USE moddatastruct, ONLY: t_region
  USE modgrid, ONLY: t_grid
   
  IMPLICIT NONE

! *****************************************************************************
! Declarations
! *****************************************************************************

! =============================================================================  
! Arguments 
! =============================================================================  

  INTEGER, INTENT(IN) :: nvarscal
  REAL(RFREAL), DIMENSION(:,:), INTENT(IN) :: tvscal
  REAL(RFREAL), DIMENSION(:,:), INTENT(INOUT) :: resscal 
  REAL(RFREAL), DIMENSION(:,:,:), INTENT(IN) :: gradscal   
  TYPE(t_region), POINTER :: pregion

! =============================================================================  
! Locals
! =============================================================================  

  CHARACTER(CHRLEN) :: rcsidentstring
  INTEGER :: c1,c2,ifg,ivarscal
  REAL(RFREAL) :: beta,flx,mu,nm,nx,ny,nz
  TYPE(t_global), POINTER :: global
  TYPE(t_grid), POINTER :: pgrid

! *****************************************************************************
! Start
! *****************************************************************************

  rcsidentstring = '$RCSfile: RFLU_ScalarViscousFluxes.F90,v $ $Revision: 1.4 $'

  global => pregion%global

  CALL registerfunction(global,'RFLU_ScalarViscousFluxes',&
  'RFLU_ScalarViscousFluxes.F90')

! *****************************************************************************
! Set variables and pointers
! *****************************************************************************

  pgrid => pregion%grid
    
  beta = pregion%mixtInput%betrk(pregion%irkStep)  
  
! *****************************************************************************  
! Loop over faces and compute viscous fluxes
! *****************************************************************************

  DO ifg = 1,pgrid%nFaces
    c1 = pgrid%f2c(1,ifg)
    c2 = pgrid%f2c(2,ifg)

! =============================================================================   
!   Get face geometry
! =============================================================================    
    
    nx = pgrid%fn(xcoord,ifg)
    ny = pgrid%fn(ycoord,ifg)
    nz = pgrid%fn(zcoord,ifg) 
    nm = pgrid%fn(xyzmag,ifg)        

! =============================================================================   
!   Get face state. NOTE this simple average is not accurate for non-uniform 
!   grids, so this will have to be replaced by a proper interpolation.
! =============================================================================

    DO ivarscal = 1,nvarscal
      mu = 0.5_rfreal*(tvscal(ivarscal,c1) + tvscal(ivarscal,c2)) 
     
! -----------------------------------------------------------------------------
!     Compute fluxes
! -----------------------------------------------------------------------------
    
      flx = mu*(  gradscal(xcoord,ivarscal,ifg)*nx     & 
                + gradscal(ycoord,ivarscal,ifg)*ny     & 
                + gradscal(zcoord,ivarscal,ifg)*nz)*nm
  
! -----------------------------------------------------------------------------
!     Accumulate into residual     
! -----------------------------------------------------------------------------

      resscal(ivarscal,c1) = resscal(ivarscal,c1) + beta*flx    
      resscal(ivarscal,c2) = resscal(ivarscal,c2) - beta*flx
    END DO ! iVarScal
  END DO ! ifg

! *****************************************************************************
! End
! *****************************************************************************

  CALL deregisterfunction(global)

END SUBROUTINE rflu_scalarviscousfluxes

!******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLU_ScalarViscousFluxes.F90,v $
! Revision 1.4  2008/12/06 08:44:13  mtcampbe
! Updated license.
!
! Revision 1.3  2008/11/19 22:17:26  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.2  2006/04/07 15:19:16  haselbac
! Removed tabs
!
! Revision 1.1  2004/01/29 22:56:17  haselbac
! Initial revision
!
!******************************************************************************