RFLU_ScalarSecond.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: Compute second-order accurate discretization of scalar inviscid flux.
!
! Description: None.
!
! Input: 
!  pRegion              Pointer to region data
!  nVarScal             Number of scalar variables
!  cvScal               Conserved scalar variables
!  gradCellScal         Cell gradients of scalar variables
!  resScal              Residual due to central scalar fluxes
!
! Output: None.
!
! Notes: None.
!
!******************************************************************************
!
! $Id: RFLU_ScalarSecond.F90,v 1.4 2008/12/06 08:44:13 mtcampbe Exp $
!
! Copyright: (c) 2004 by the University of Illinois
!
!******************************************************************************

SUBROUTINE rflu_scalarsecond(pRegion,nVarScal,cvScal,gradCellScal,resScal)

  USE moddatatypes
  USE modglobal, ONLY: t_global
  USE moddatastruct, ONLY: t_region
  USE modgrid, ONLY: t_grid
  USE moderror
  USE modparameters
    
  IMPLICIT NONE

! *****************************************************************************
! Definitions and declarations
! *****************************************************************************

! =============================================================================
! Arguments
! =============================================================================

  INTEGER, INTENT(IN) :: nvarscal
  REAL(RFREAL), DIMENSION(:,:), INTENT(IN) :: cvscal
  REAL(RFREAL), DIMENSION(:,:), INTENT(INOUT) :: resscal
  REAL(RFREAL), DIMENSION(:,:,:), INTENT(IN) :: gradcellscal
  TYPE(t_region), POINTER :: pregion

! =============================================================================
! Locals
! =============================================================================

  CHARACTER(CHRLEN) :: rcsidentstring
  INTEGER :: c1,c2,ifc,ivarscal
  REAL(RFREAL) :: dx1,dx2,dy1,dy2,dz1,dz2,flx,mf,mfn,mfp,sl,sr,xc,yc,zc
  REAL(RFREAL), DIMENSION(:), POINTER :: pmf     
  TYPE(t_global), POINTER :: global
  TYPE(t_grid), POINTER :: pgrid

! *****************************************************************************
! Start
! *****************************************************************************

  rcsidentstring = '$RCSfile: RFLU_ScalarSecond.F90,v $ $Revision: 1.4 $'

  global => pregion%global

  CALL registerfunction(global,'RFLU_ScalarSecond',&
  'RFLU_ScalarSecond.F90')

! *****************************************************************************
! Checks: Defensive coding, should never occur
! *****************************************************************************
 
  IF ( pregion%mixtInput%indMfMixt /= 1 ) THEN 
    CALL errorstop(global,err_indmfmixt_invalid,__line__)
  END IF ! pRegion%mixtInput%indMfMixt
  
! *****************************************************************************
! Set dimensions and pointers 
! *****************************************************************************

  pgrid => pregion%grid
  pmf   => pregion%mixt%mfMixt

! *****************************************************************************
! Compute fluxes
! *****************************************************************************

  DO ifc = 1,pgrid%nFaces
    c1 = pgrid%f2c(1,ifc)
    c2 = pgrid%f2c(2,ifc)

! =============================================================================  
!   Get face geometry and relative position vectors
! =============================================================================  

    xc = pgrid%fc(xcoord,ifc)
    yc = pgrid%fc(ycoord,ifc)
    zc = pgrid%fc(zcoord,ifc)

    dx1 = xc - pgrid%cofg(xcoord,c1)
    dy1 = yc - pgrid%cofg(ycoord,c1)
    dz1 = zc - pgrid%cofg(zcoord,c1)

    dx2 = xc - pgrid%cofg(xcoord,c2)
    dy2 = yc - pgrid%cofg(ycoord,c2)
    dz2 = zc - pgrid%cofg(zcoord,c2)

! =============================================================================  
!   Get mass flux 
! =============================================================================  

    mf  = pmf(ifc)
    mfp = max(mf,0.0_rfreal)
    mfn = min(mf,0.0_rfreal)
        
! =============================================================================  
!   Compute flux and accumulate into residual
! =============================================================================  
     
    DO ivarscal = 1,nvarscal
      sl = cvscal(ivarscal,c1)
      sr = cvscal(ivarscal,c2)

      sl = sl + gradcellscal(xcoord,ivarscal,c1)*dx1 & 
              + gradcellscal(ycoord,ivarscal,c1)*dy1 & 
              + gradcellscal(zcoord,ivarscal,c1)*dz1            
      
      sr = sr + gradcellscal(xcoord,ivarscal,c2)*dx2 & 
              + gradcellscal(ycoord,ivarscal,c2)*dy2 & 
              + gradcellscal(zcoord,ivarscal,c2)*dz2            
          
      flx = mfp*sl + mfn*sr

      resscal(ivarscal,c1) = resscal(ivarscal,c1) + flx
      resscal(ivarscal,c2) = resscal(ivarscal,c2) - flx
    END DO ! iVarScal
  END DO  ! ifc
  
! *****************************************************************************
! End
! *****************************************************************************

  CALL deregisterfunction(global)

END SUBROUTINE rflu_scalarsecond

!******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLU_ScalarSecond.F90,v $
! Revision 1.4  2008/12/06 08:44:13  mtcampbe
! Updated license.
!
! Revision 1.3  2008/11/19 22:17:26  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.2  2006/04/07 15:19:16  haselbac
! Removed tabs
!
! Revision 1.1  2004/01/29 22:56:12  haselbac
! Initial revision
!
!******************************************************************************