RFLU_ScalarFirstPatch.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
! ******************************************************************************
!
! Purpose: Compute first-order accurate discretization of scalar inviscid flux 
!   through boundary faces.
!
! Description: None.
!
! Input: 
!   pRegion     Pointer to data of current region
!   pPatch      Pointer to data of current patch
!   nVarScal    Number of scalars
!   cvScal      Vector of conserved scalar variables
!   valScal     Boundary values of scalar variables     
!
! Output: 
!   resScal     Residual of scalar variables
!
! Notes: None.
!
! ******************************************************************************
!
! $Id: RFLU_ScalarFirstPatch.F90,v 1.7 2008/12/06 08:44:12 mtcampbe Exp $
!
! Copyright: (c) 2004-2006 by the University of Illinois
!
! ******************************************************************************

SUBROUTINE rflu_scalarfirstpatch(pRegion,pPatch,nVarScal,cvScal,valScal,resScal)

  USE modglobal, ONLY: t_global
  USE moddatatypes
  USE modbndpatch, ONLY: t_bcvalues,t_patch
  USE moddatastruct, ONLY: t_region
  USE modgrid, ONLY: t_grid
  USE moderror
  USE modparameters
    
  IMPLICIT NONE

! ******************************************************************************
! Definitions and declarations
! ******************************************************************************

! ==============================================================================
! Arguments
! ==============================================================================

  INTEGER, INTENT(IN) :: nvarscal
  REAL(RFREAL), DIMENSION(:,:), INTENT(IN) :: cvscal
  REAL(RFREAL), DIMENSION(:,:), INTENT(INOUT) :: resscal
  TYPE(t_bcvalues) :: valscal
  TYPE(t_patch), POINTER :: ppatch
  TYPE(t_region), POINTER :: pregion

! ==============================================================================
! Locals
! ==============================================================================

  CHARACTER(CHRLEN) :: rcsidentstring
  INTEGER :: c1,bctype,distscal,ifc,ivarscal
  REAL(RFREAL) :: flx,mf
  REAL(RFREAL), DIMENSION(:), POINTER :: pmfmixt
  REAL(RFREAL), DIMENSION(:,:), POINTER :: rhs
  TYPE(t_global), POINTER :: global
  TYPE(t_grid), POINTER :: pgrid
  
! ******************************************************************************
! Start
! ******************************************************************************

  rcsidentstring = '$RCSfile: RFLU_ScalarFirstPatch.F90,v $ $Revision: 1.7 $'

  global => pregion%global

  CALL registerfunction(global,'RFLU_ScalarFirstPatch',&
  'RFLU_ScalarFirstPatch.F90')

! ******************************************************************************
! Checks: Defensive coding, should never occur
! ******************************************************************************
 
  IF ( pregion%mixtInput%indMfMixt /= 1 ) THEN 
    CALL errorstop(global,err_indmfmixt_invalid,__line__)
  END IF ! pRegion%mixtInput%indMfMixt
  
! ******************************************************************************
! Set pointers and variables
! ******************************************************************************
      
  pgrid   => pregion%grid    
  pmfmixt => ppatch%mfMixt
  
  bctype   = ppatch%bcType  
  distscal = valscal%distrib  

! ******************************************************************************
! Select boundary type
! ******************************************************************************

  SELECT CASE ( bctype )

! ==============================================================================  
!   Inflow
! ==============================================================================

    CASE ( bc_inflow_totang,bc_inflow_veltemp ) 
      DO ifc = 1,ppatch%nBFaces
        c1 = ppatch%bf2c(ifc)

        mf = pmfmixt(ifc) 
                                                                
        DO ivarscal = 1,nvarscal                                      
          flx = mf*valscal%vals(ivarscal,distscal*ifc)
          
          resscal(ivarscal,c1) = resscal(ivarscal,c1) + flx
        END DO ! iVarScal
      END DO ! ifc
            
! ==============================================================================  
!   Outflow
! ==============================================================================

    CASE ( bc_outflow )        
      DO ifc = 1,ppatch%nBFaces
        c1 = ppatch%bf2c(ifc)
        
        mf = pmfmixt(ifc)                   
                                          
        DO ivarscal = 1,nvarscal                
          flx = mf*cvscal(ivarscal,c1)
                                  
          resscal(ivarscal,c1) = resscal(ivarscal,c1) + flx
        END DO ! iVarScal 
      END DO ! ifc

! ==============================================================================  
!   Slip wall 
! ==============================================================================
    
    CASE ( bc_slipwall ) 

! ==============================================================================  
!   No-slip wall
! ==============================================================================
 
    CASE ( bc_noslipwall_hflux,bc_noslipwall_temp ) 

! ==============================================================================  
!   Farfield
! ==============================================================================

    CASE ( bc_farfield )
      DO ifc = 1,ppatch%nBFaces
        c1 = ppatch%bf2c(ifc)                                              

        mf = pmfmixt(ifc)
                   
        IF ( mf > 0.0_rfreal ) THEN ! Outflow
          DO ivarscal = 1,nvarscal        
            flx = mf*cvscal(ivarscal,c1)
                        
            resscal(ivarscal,c1) = resscal(ivarscal,c1) + flx
          END DO ! iVarScal                      
        ELSE ! Inflow
          DO ivarscal = 1,nvarscal 
            flx = mf*valscal%vals(ivarscal,distscal*ifc)
                      
            resscal(ivarscal,c1) = resscal(ivarscal,c1) + flx
          END DO ! iVarScal
        END IF ! mf   
      END DO ! ifc      
    
! ==============================================================================  
!   Injection
! ==============================================================================

    CASE ( bc_injection )
      DO ifc = 1,ppatch%nBFaces
        c1 = ppatch%bf2c(ifc)

        mf = pmfmixt(ifc)
                                                
        DO ivarscal = 1,nvarscal                
          flx = mf*valscal%vals(ivarscal,distscal*ifc)
                                  
          resscal(ivarscal,c1) = resscal(ivarscal,c1) + flx
        END DO ! iVarScal                           
      END DO ! ifc

! ==============================================================================
!   Boundaries for which fluxes must not or need not be computed
! ==============================================================================

    CASE ( bc_periodic, &
           bc_symmetry, & 
           bc_virtual )
           
! ==============================================================================  
!   Default
! ==============================================================================

    CASE default 
      CALL errorstop(global,err_reached_default,__line__)
  END SELECT ! bcType

! ******************************************************************************
! End
! ******************************************************************************

  CALL deregisterfunction(global)

END SUBROUTINE rflu_scalarfirstpatch

! ******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLU_ScalarFirstPatch.F90,v $
! Revision 1.7  2008/12/06 08:44:12  mtcampbe
! Updated license.
!
! Revision 1.6  2008/11/19 22:17:26  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.5  2006/04/07 15:19:16  haselbac
! Removed tabs
!
! Revision 1.4  2006/03/25 21:43:47  haselbac
! Added CASEs for sype patches
!
! Revision 1.3  2005/11/10 02:03:16  haselbac
! Added virtual boundary, cleaned up CASE statements
!
! Revision 1.2  2005/04/20 14:40:15  haselbac
! Removed CHECK_UNIFLOW code section, cosmetics
!
! Revision 1.1  2004/01/29 22:56:10  haselbac
! Initial revision
!
! ******************************************************************************