RFLU_ScalarCheckPositivity.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: Check for posivity of scalar variables
!
! Description: None.
!
! Input: 
!   pRegion     Region data
!   moduleType  Type of module
!   nVarScal    Number of scalar variables
!   cvScal      Conserved scalar variables
!
! Output: None.
!
! Notes: None.
!
!******************************************************************************
!
! $Id: RFLU_ScalarCheckPositivity.F90,v 1.4 2008/12/06 08:44:12 mtcampbe Exp $
!
! Copyright: (c) 2002-2004 by the University of Illinois
!
!******************************************************************************

SUBROUTINE rflu_scalarcheckpositivity(pRegion,moduleType,nVarScal,cvScal)

  USE moddatatypes
  USE moderror
  USE modglobal, ONLY: t_global
  USE moddatastruct, ONLY: t_region
  USE modgrid, ONLY: t_grid  
  USE modparameters
  USE modmpi
    
  USE modinterfaces, ONLY: rflu_printlocinfo  
    
  IMPLICIT NONE

! *****************************************************************************
! Definitions and declarations
! *****************************************************************************

! =============================================================================
! Arguments
! =============================================================================

  INTEGER, INTENT(IN) :: moduletype,nvarscal
  REAL(RFREAL), DIMENSION(:,:), INTENT(IN) :: cvscal
  TYPE(t_region), POINTER :: pregion

! =============================================================================
! Locals
! =============================================================================

  CHARACTER(CHRLEN) :: rcsidentstring
  INTEGER, PARAMETER :: max_negative_locs = 10
  INTEGER :: icg,ivarscal,nlocs
  INTEGER :: loc(max_negative_locs,min_val:max_val)
  TYPE(t_global), POINTER :: global
  TYPE(t_grid), POINTER :: pgrid

! *****************************************************************************
! Start
! *****************************************************************************

  rcsidentstring = '$RCSfile: RFLU_ScalarCheckPositivity.F90,v $ $Revision: 1.4 $'

  global => pregion%global

  CALL registerfunction(global,'RFLU_ScalarCheckPositivity',&
  'RFLU_ScalarCheckPositivity.F90')

! *****************************************************************************
! Set pointers and variables
! *****************************************************************************

  pgrid => pregion%grid

  nlocs = 0

! *****************************************************************************
! Loop over cells and check for positivity
! *****************************************************************************

  cellloop: DO icg = 1,pgrid%nCells        
    varloop: DO ivarscal = 1,nvarscal
      IF ( cvscal(ivarscal,icg) < 0.0_rfreal ) THEN
        nlocs = nlocs + 1

        IF ( nlocs == 1 ) THEN 
          WRITE(stdout,'(A,1X,A)') solver_name, & 
                'Negative positive-definite variables detected!'
                
          SELECT CASE ( moduletype ) 
            CASE ( ftype_spec ) 
              WRITE(stdout,'(A,3X,A)') solver_name,'Module: Species.'
            CASE default 
              CALL errorstop(global,err_reached_default,__line__)
          END SELECT ! moduleType                    

          IF ( global%flowType == flow_unsteady ) THEN 
            WRITE(stdout,'(A,3X,A,1X,1PE12.5)') solver_name,'Current time:', &
                                                global%currentTime              
          ELSE 
            WRITE(stdout,'(A,3X,A,1X,I6)') solver_name, &
                                           'Current iteration number:', &
                                           global%currentIter           
          END IF ! global%flowType                 

          WRITE(stdout,'(A,3X,A,1X,I5.5)') solver_name,'Global region:', & 
                                           pregion%iRegionGlobal 
!          WRITE(STDOUT,'(A,6X,A,6(1X,A))') SOLVER_NAME,'#', &
!                                           '   Density   ', &
!                                           '  x-velocity ', &
!                                           '  y-velocity ', &
!                                           '  z-velocity ', &
!                                           '   Pressure  ', &
!                                           ' Temperature '       
        END IF ! nLocs

        IF ( nlocs <= max_negative_locs ) THEN 
          WRITE(stdout,'(A,4X,I3,6(1X,E13.6))') solver_name,nlocs, & 
                                                cvscal(1:nvarscal,icg)

          loc(nlocs,min_val:max_val) = icg
          
          EXIT varloop ! NOTE this EXIT statement                                   
        END IF ! nLocs
      END IF ! cvScal
    END DO varloop    
  END DO cellloop

! *****************************************************************************
! Write out message and call error handling routine
! *****************************************************************************

  IF ( nlocs > 0 ) THEN 
    IF ( nlocs > max_negative_locs ) THEN 
       WRITE(stdout,'(A,3X,A,1X,I3,1X,A,1X,I9,1X,A)') solver_name, & 
             'Only wrote the first',max_negative_locs,'of',nlocs, & 
             'cells with negative positive-definite variables.'    
      CALL rflu_printlocinfo(pregion,loc,max_negative_locs, & 
                             locinfo_mode_silent,output_mode_anybody)
    ELSE 
      CALL rflu_printlocinfo(pregion,loc(1:nlocs,min_val:max_val),nlocs, & 
                             locinfo_mode_silent,output_mode_anybody)
    END IF ! nLocs
    
    CALL errorstop(global,err_negative_posdef,__line__)   
  END IF ! nLocs

! *****************************************************************************
! End
! *****************************************************************************

  CALL deregisterfunction(global)

END SUBROUTINE rflu_scalarcheckpositivity

!******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLU_ScalarCheckPositivity.F90,v $
! Revision 1.4  2008/12/06 08:44:12  mtcampbe
! Updated license.
!
! Revision 1.3  2008/11/19 22:17:26  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.2  2006/04/07 15:19:16  haselbac
! Removed tabs
!
! Revision 1.1  2004/01/29 22:56:05  haselbac
! Initial revision
!
!******************************************************************************