RFLU_ReadStat.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: read in time averaged solution
!
! Description: file to be read in contains statistics solution in 
!              interior cells; only binary format is supported
!
! Input: region      = region data (dimensions)
!        integrTime  = integrated time from file
!        mixttav     = time averaged mixture data from file
!        turbtav     = time averaged TURB data from file
!
! Output: region%mixt%tav     = time averaged mixture variables
!         region%turb%tav     = time averaged TURB variables
!         global%integrTime   = integrated time
!
! Notes: each region has statistics solution file
!
!******************************************************************************
!
! $Id: RFLU_ReadStat.F90,v 1.11 2008/12/06 08:44:12 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************

SUBROUTINE rflu_readstat( region )

  USE moddatatypes
  USE moddatastruct, ONLY : t_region
  USE modglobal, ONLY     : t_global
  USE moderror
  USE modmpi
  USE modparameters
  IMPLICIT NONE

! ... parameters
  TYPE(t_region) :: region

! ... loop variables
  INTEGER :: ijk, ind, l

! ... local variables
  CHARACTER(CHRLEN+23) :: fname
  CHARACTER(CHRLEN)    :: rcsidentstring,msg,timestring1,timestring2

  INTEGER :: errorflag,ireg, ijkbeg, ijkend, ncells
  INTEGER :: ntavgvar
  INTEGER :: mixtvarid(2,region%global%mixtnstat)
  INTEGER :: turbvarid(2,region%global%turbnstat)

  REAL(RFREAL)          :: currenttime
  REAL(RFREAL), POINTER :: mixttav(:,:), turbtav(:,:) 

  TYPE(t_global), POINTER :: global

!******************************************************************************

  rcsidentstring = '$RCSfile: RFLU_ReadStat.F90,v $'

  global => region%global

  CALL registerfunction(global,'RFLU_ReadStat',&
  'RFLU_ReadStat.F90')

! open file -----------------------------------------------------------------
  
  ireg = region%iRegionGlobal
  WRITE(fname,'(A,I5.5,A,1PE11.5)') trim(global%outDir)// & 
                                    trim(global%casename)//'.statb_',ireg, &
                                    '_',global%currentTime

  OPEN(if_stat,file=fname,form='unformatted',status='old',iostat=errorflag)
  global%error = errorflag   
  IF (global%error /= 0) &
    CALL errorstop(global,err_file_open,__line__,'File: '//trim(fname))

! read physical time and integrated time ------------------------------------

  READ(if_stat,err=10,end=10) currenttime
  READ(if_stat,err=10,end=10) global%integrTime
  WRITE(timestring1,'(1PE11.5)') global%currentTime
  WRITE(timestring2,'(1PE11.5)') currenttime          

  IF ( trim(timestring1) /= trim(timestring2) ) THEN
    WRITE(msg,1010) ireg,currenttime,global%currentTime
    CALL errorstop(global,err_time_solution,__line__, & 
                   msg//' File: '//trim(fname) )
  ENDIF

! read dimensions & check them ----------------------------------------------

  READ(if_stat,err=10,end=10) ncells

  IF (ncells /= region%grid%nCells) THEN
    WRITE(msg,1000) ireg, ncells, region%grid%nCells
    CALL errorstop(global,err_grid_dimensions,__line__,msg)
  ENDIF

! mixture NSTAT and ID

  IF (global%mixtNStat > 0) THEN
    READ(if_stat,err=10,end=10) ntavgvar,mixtvarid(1,:)
    mixtvarid(2,:) = mod(mixtvarid(1,:),10)
    mixtvarid(1,:) = (mixtvarid(1,:)-mixtvarid(2,:))/10

    IF (ntavgvar /= global%mixtNStat) THEN
      CALL errorstop(global,err_stats_restart,__line__)
    ENDIF

    DO ind=1,2
      DO l=1,global%mixtNStat
        IF (mixtvarid(ind,l)  /= global%mixtStatId(ind,l)) THEN
          CALL errorstop(global,err_stats_restart,__line__)
        ENDIF
      ENDDO
    ENDDO
  ENDIF

! turbulence NSTAT and ID

#ifdef TURB
  IF (global%turbNStat > 0) THEN
    READ(if_stat,err=10,end=10) ntavgvar,turbvarid(1,:)
    turbvarid(2,:) = mod(turbvarid(1,:),10)
    turbvarid(1,:) = (turbvarid(1,:)-turbvarid(2,:))/10

    IF (ntavgvar /= global%turbNStat) THEN
      CALL errorstop(global,err_stats_restart,__line__)
    ENDIF

    DO ind=1,2
      DO l=1,global%turbNStat
        IF (turbvarid(ind,l)  /= global%turbStatId(ind,l)) THEN
          CALL errorstop(global,err_stats_restart,__line__)
        ENDIF
      ENDDO
    ENDDO
  ENDIF
#endif

! read time averaged variables ----------------------------------------------

  IF (global%myProcid==masterproc .AND. global%verbLevel>=verbose_high) &
    WRITE(stdout,'(A)') solver_name,'  - read statistics'

  ijkbeg = 1
  ijkend = region%grid%nCells

  IF (global%mixtNStat > 0) THEN
    mixttav => region%mixt%tav
    READ(if_stat,err=10,end=10) ((mixttav(l,ijk), ijk=ijkbeg,ijkend), &
                                  l=1,global%mixtNStat)
  ENDIF
#ifdef TURB
  IF (global%turbNStat > 0) THEN
    turbtav => region%turb%tav
    READ(if_stat,err=10,end=10) ((turbtav(l,ijk), ijk=ijkbeg,ijkend), &
                                  l=1,global%turbNStat)
  ENDIF
#endif


! close file ----------------------------------------------------------------

  CLOSE(if_stat,iostat=errorflag)
  global%error = errorflag   
  IF (global%error /= 0) &
    CALL errorstop(global,err_file_close,__line__,'File: '//trim(fname))

! finalization & error handling ---------------------------------------------

  CALL deregisterfunction(global)
  goto 999

10   CONTINUE
  CALL errorstop(global,err_file_read,__line__,'File: '//trim(fname))

999  CONTINUE
1000 FORMAT('Region ',i5,', nCells= ',i10,', nCellExpected= ',i10)
1010 FORMAT('Region ',i5,', time in file is= ',1pe12.5, &
            ' but it should be= ',e12.5,'.')

END SUBROUTINE rflu_readstat

!******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLU_ReadStat.F90,v $
! Revision 1.11  2008/12/06 08:44:12  mtcampbe
! Updated license.
!
! Revision 1.10  2008/11/19 22:17:25  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.9  2006/01/02 11:22:09  wasistho
! changed timeStamp to currentTime
!
! Revision 1.8  2002/11/02 01:51:40  wasistho
! Added TURB statistics
!
! Revision 1.7  2002/10/08 15:48:57  haselbac
! {IO}STAT=global%error replaced by {IO}STAT=errorFlag - SGI problem
!
! Revision 1.6  2002/10/05 18:52:34  haselbac
! Cosmetic changes only
!
! Revision 1.5  2002/09/09 14:15:01  haselbac
! global now under regions
!
! Revision 1.4  2002/07/22 15:45:50  wasistho
! Cleaned-up conforming Coding Rule
!
! Revision 1.3  2002/06/18 00:37:07  wasistho
! Added prefix SOLVER NAME to satistics STDOutput
!
! Revision 1.2  2002/06/17 18:33:34  wasistho
! modified times matching check
!
! Revision 1.1  2002/06/14 21:23:56  wasistho
! Added time avg statistics
!
!
!******************************************************************************