RFLU_ReadRestartInfo.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
! ******************************************************************************
!
! Purpose: Read restart info file to get last output iteration or time.
!
! Description: None.
!
! Input: 
!   global              Pointer to global data
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************
!
! $Id: RFLU_ReadRestartInfo.F90,v 1.6 2008/12/06 08:44:12 mtcampbe Exp $
!
! Copyright: (c) 2003-2004 by the University of Illinois
!
! ******************************************************************************

SUBROUTINE rflu_readrestartinfo(global)

  USE moddatatypes
  USE modglobal, ONLY: t_global
  USE modparameters
  USE moderror
  USE modmpi
  
  USE modinterfaces, ONLY: rflu_closerestartinfo, & 
                           rflu_openrestartinfo

! ******************************************************************************
! Declarations and definitions
! ******************************************************************************

! ==============================================================================
! Arguments
! ==============================================================================

  TYPE(t_global), POINTER :: global

! ==============================================================================
! Locals
! ==============================================================================

  LOGICAL :: fileexists
  CHARACTER(CHRLEN) :: rcsidentstring
  INTEGER :: dummyinteger,errorflag
  REAL(RFREAL) :: dummyrfreal

! ******************************************************************************
! Start
! ******************************************************************************

  rcsidentstring = '$RCSfile: RFLU_ReadRestartInfo.F90,v $ $Revision: 1.6 $'

  CALL registerfunction(global,'RFLU_ReadRestartInfo',&
  'RFLU_ReadRestartInfo.F90')

  IF ( global%myProcid == masterproc .AND. & 
       global%verbLevel > verbose_none ) THEN
    WRITE(stdout,'(A,1X,A)') solver_name, &
                             'Reading restart info file...'
  END IF ! global%verbLevel

! ==============================================================================
! Open file
! ==============================================================================

  CALL rflu_openrestartinfo(global,file_position_start,fileexists)

! ==============================================================================
! Set or read restart iteration or time
! ==============================================================================

  IF ( global%flowType == flow_steady ) THEN ! steady flow
    global%currentIter = 0

    IF ( fileexists .EQV. .true. ) THEN
      DO 
        READ(if_restinfo,*,iostat=errorflag) dummyinteger
        
        IF ( errorflag /= err_none ) THEN 
          EXIT
        ELSE 
          global%currentIter = dummyinteger
        END IF ! errorFlag
      END DO ! <empty>
    END IF ! fileExists
  ELSE ! unsteady flow
    global%currentTime = 0.0_rfreal
  
    IF ( fileexists .EQV. .true. ) THEN
      DO 
        READ(if_restinfo,*,iostat=errorflag) dummyrfreal
        
        IF ( errorflag /= err_none ) THEN 
          EXIT
        ELSE 
          global%currentTime = dummyrfreal
        END IF ! errorFlag
      END DO ! <empty>
    END IF ! fileExists
  END IF ! global%flowType

! ==============================================================================
! Write info
! ==============================================================================

  IF ( global%myProcid == masterproc .AND. & 
       global%verbLevel > verbose_low ) THEN
    IF ( global%flowType == flow_steady ) THEN 
      WRITE(stdout,'(A,3X,A,1X,I6.6)') solver_name, & 
                                       'Restart iteration:',global%currentIter
    ELSE 
      WRITE(stdout,'(A,3X,A,1X,1PE11.5)') solver_name, & 
                                          'Restart time:',global%currentTime      
    END IF ! global%flowType
  END IF ! global%myProcid

! ==============================================================================
! Close file
! ==============================================================================

  CALL rflu_closerestartinfo(global)        

! ******************************************************************************
! End
! ******************************************************************************

  IF ( global%myProcid == masterproc .AND. & 
       global%verbLevel > verbose_none ) THEN
    WRITE(stdout,'(A,1X,A)') solver_name, & 
                             'Reading restart info file done.'
  END IF ! global%verbLevel

  CALL deregisterfunction(global)

END SUBROUTINE rflu_readrestartinfo


! ******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLU_ReadRestartInfo.F90,v $
! Revision 1.6  2008/12/06 08:44:12  mtcampbe
! Updated license.
!
! Revision 1.5  2008/11/19 22:17:25  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.4  2006/04/07 15:19:16  haselbac
! Removed tabs
!
! Revision 1.3  2004/06/25 20:04:51  haselbac
! Removed some code and put into RFLU_SetRestartTimeFlag
!
! Revision 1.2  2004/06/16 20:00:33  haselbac
! Added variables to make file handling easier, cosmetics
!
! Revision 1.1  2003/06/20 22:32:30  haselbac
! Initial revision
!
! ******************************************************************************