RFLU_ReadPostInfo.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
! ******************************************************************************
!
! Purpose: Read file with with post-processor information.
!
! Description: None.
!
! Input: 
!   pRegion              Pointer to region data
!   readMode             Reading mode
!
! Output: None.
!
! Notes: 
!   1. Need to have two reading modes because for the activation flag to be
!      useful, need to do this before any quantities are read or allocated, 
!      but this means that nCellsSpecial will be overwritten when grid is 
!      created. So read twice, first for activation flag only, and then after 
!      grid is created, read nCellsSpecial and the actual indices of the 
!      special cells.
!
! ******************************************************************************
!
! $Id: RFLU_ReadPostInfo.F90,v 1.7 2008/12/06 08:45:06 mtcampbe Exp $
!
! Copyright: (c) 2003-2004 by the University of Illinois
!
! ******************************************************************************

SUBROUTINE rflu_readpostinfo(pRegion,readMode)

  USE moddatatypes
  USE moderror
  USE moddatastruct, ONLY: t_region
  USE modgrid, ONLY: t_grid
  USE modglobal, ONLY: t_global
  USE modparameters
  USE modmpi
  
  IMPLICIT NONE

! ******************************************************************************
! Definitions and declarations
! ******************************************************************************

! ==============================================================================
! Arguments
! ==============================================================================

  INTEGER, INTENT(IN) :: readmode
  TYPE(t_region), POINTER :: pregion

! ==============================================================================
! Locals
! ==============================================================================

  LOGICAL :: dummylogical
  CHARACTER(CHRLEN) :: dummystring,dummystring2,iregionstring,rcsidentstring
  INTEGER :: dummyinteger,dummyinteger2,ics,ifile,ifs,indx,ireg,iregionglobal, &
             ncellsspecial
  TYPE(t_global), POINTER :: global
  TYPE(t_grid), POINTER :: pgrid

! ******************************************************************************
! Start
! ******************************************************************************

  rcsidentstring = '$RCSfile: RFLU_ReadPostInfo.F90,v $ $Revision: 1.7 $'

  global => pregion%global

  CALL registerfunction(global,'RFLU_ReadPostInfo',&
  'RFLU_ReadPostInfo.F90')

  IF ( global%myProcid == masterproc .AND. & 
       global%verbLevel > verbose_none ) THEN
    WRITE(stdout,'(A,1X,A)') solver_name,'Reading post-processor info...'
    WRITE(stdout,'(A,3X,A,1X,I5.5)') solver_name,'Global region:', & 
                                     pregion%iRegionGlobal 
  END IF ! global%verbLevel

! ******************************************************************************
! Set grid pointer and variables
! ******************************************************************************

  pgrid => pregion%grid

  ifile = if_postinfo

! ******************************************************************************
! Rewind file - must be done because stays open while read several times
! ******************************************************************************

  rewind(ifile)

! ******************************************************************************
! Read from file
! ******************************************************************************

  DO ireg = 1,global%nRegionsLocal
    READ(ifile,'(A)') dummystring

    WRITE(iregionstring,'(I5.5)') pregion%iRegionGlobal
    indx = index(dummystring,trim(iregionstring))
    
    IF ( indx /= 0 ) THEN
      dummystring2 = dummystring(indx:indx+len_trim(iregionstring)-1)
      READ(dummystring2,*) iregionglobal
    ELSE 
      iregionglobal = crazy_value_int ! Anything but pRegion%iRegionGlobal
    END IF ! indx
        
! ==============================================================================
!   Found entry for my region
! ==============================================================================

    IF ( iregionglobal == pregion%iRegionGlobal ) THEN
    
! ------------------------------------------------------------------------------
!     Read activation flag only
! ------------------------------------------------------------------------------
    
      IF ( readmode == infofile_readmode_flag ) THEN
        READ(ifile,'(L1)') pregion%postActiveFlag
        
        IF ( pregion%postActiveFlag .EQV. .true. ) THEN
          IF ( global%myProcid == masterproc .AND. & 
               global%verbLevel > verbose_low ) THEN
            WRITE(stdout,'(A,3X,A)') solver_name,'Region is active.'
          END IF ! global%verbLevel          
                         
          READ(ifile,*) dummyinteger ! Special cells

          DO ics = 1,dummyinteger
            READ(ifile,*) dummyinteger2
          END DO ! ics
          
          READ(ifile,*) dummyinteger ! Special faces

          DO ifs = 1,dummyinteger
            READ(ifile,*) dummyinteger2
          END DO ! ifs          
        ELSE 
          IF ( global%myProcid == masterproc .AND. & 
               global%verbLevel > verbose_low ) THEN
            WRITE(stdout,'(A,3X,A)') solver_name,'Region is not active.'
          END IF ! global%verbLevel         
        END IF ! pRegion%postActiveFlag   

! ------------------------------------------------------------------------------
!     Read special cells and faces only
! ------------------------------------------------------------------------------

      ELSE IF ( readmode == infofile_readmode_data ) THEN
        READ(ifile,'(L1)') dummylogical
            
        IF ( dummylogical .EQV. .true. ) THEN 
          READ(ifile,*) pgrid%nCellsSpecial

          IF ( global%myProcid == masterproc .AND. & 
               global%verbLevel > verbose_low ) THEN
            WRITE(stdout,'(A,3X,A,1X,I3)') solver_name, &
                                           'Number of special cells:', &
                                           pgrid%nCellsSpecial
          END IF ! global%verbLevel

          DO ics = 1,pgrid%nCellsSpecial
            READ(ifile,*) pgrid%cellsSpecial(ics)
          END DO ! ics 
          
          READ(ifile,*) pgrid%nFacesSpecial

          IF ( global%myProcid == masterproc .AND. & 
               global%verbLevel > verbose_low ) THEN
            WRITE(stdout,'(A,3X,A,1X,I3)') solver_name, &
                                           'Number of special faces:', &
                                           pgrid%nFacesSpecial
          END IF ! global%verbLevel

          DO ifs = 1,pgrid%nFacesSpecial
            READ(ifile,*) pgrid%facesSpecial(1,ifs), & 
                          pgrid%facesSpecial(2,ifs)
          END DO ! ifs                                        
        ELSE 
          pgrid%nCellsSpecial = 0
          pgrid%nFacesSpecial = 0          
        END IF ! dummyLogical
      ELSE 
        CALL errorstop(global,err_reached_default,__line__)
      END IF ! readMode
      
! ==============================================================================
!   Found entry for other region(s) - skip by reading dummy variables
! ==============================================================================

    ELSE 
      READ(ifile,'(L1)') dummylogical
    
      IF ( dummylogical .EQV. .true. ) THEN 
        READ(ifile,*) dummyinteger ! Special cells

        DO ics = 1,dummyinteger
          READ(ifile,*) dummyinteger2
        END DO ! ics 
        
        READ(ifile,*) dummyinteger ! Special faces

        DO ifs = 1,dummyinteger
          READ(ifile,*) dummyinteger2
        END DO ! ifs          
      END IF ! dummyLogical    
    END IF ! iRegionGlobal
  END DO ! iReg

! ******************************************************************************
! End
! ******************************************************************************

  IF ( global%myProcid == masterproc .AND. & 
       global%verbLevel > verbose_none ) THEN
    WRITE(stdout,'(A,1X,A)') solver_name,'Reading post-processor info done.'
  END IF ! global%verbLevel

  CALL deregisterfunction(global)

END SUBROUTINE rflu_readpostinfo

! ******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLU_ReadPostInfo.F90,v $
! Revision 1.7  2008/12/06 08:45:06  mtcampbe
! Updated license.
!
! Revision 1.6  2008/11/19 22:18:17  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.5  2006/04/07 15:19:26  haselbac
! Removed tabs
!
! Revision 1.4  2004/09/27 01:43:50  haselbac
! Modified to read info about special faces
!
! Revision 1.3  2004/03/23 03:17:34  haselbac
! Changed format statements
!
! Revision 1.2  2003/08/07 15:37:16  haselbac
! Changed var names
!
! Revision 1.1  2003/06/04 22:44:14  haselbac
! Initial revision
!
! ******************************************************************************