RFLU_PickSpecialFaces.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
! ******************************************************************************
!
! Purpose: Pick special faces.
!
! Description: None.
!
! Input:
!   pRegion             Pointer to region data
! 
! Output: None.
!
! Notes: None.
!
! ******************************************************************************
!
! $Id: RFLU_PickSpecialFaces.F90,v 1.3 2008/12/06 08:45:04 mtcampbe Exp $
!
! Copyright: (c) 2004 by the University of Illinois
!
! ******************************************************************************

SUBROUTINE rflu_pickspecialfaces(pRegion)

  USE modglobal, ONLY: t_global
  USE moddatatypes
  USE modparameters
  USE moderror  
  USE modbndpatch, ONLY: t_patch
  USE modgrid, ONLY: t_grid
  USE moddatastruct, ONLY: t_region
  USE modsortsearch

  USE rflu_modgrid

  IMPLICIT NONE

! ******************************************************************************
! Declarations and definitions
! ******************************************************************************  

! ==============================================================================
! Arguments
! ==============================================================================

  TYPE(t_region), POINTER :: pregion
 
! ==============================================================================
! Locals
! ==============================================================================

  CHARACTER :: infotype,stenciltype
  CHARACTER(CHRLEN) :: rcsidentstring  
  INTEGER :: errorflag,faceindx,ifacesspecial,patchindx
  TYPE(t_global), POINTER :: global
  TYPE(t_grid), POINTER :: pgrid
  TYPE(t_patch), POINTER :: ppatch

! ******************************************************************************
! Start
! ******************************************************************************

  rcsidentstring = '$RCSfile: RFLU_PickSpecialFaces.F90,v $ $Revision: 1.3 $'

  global => pregion%global

  CALL registerfunction(global,'RFLU_PickSpecialFaces', &
                        'RFLU_PickSpecialFaces.F90')

  IF ( global%verbLevel > verbose_none ) THEN
    WRITE(stdout,'(A,1X,A)') solver_name,'Picking special faces...'
    WRITE(stdout,'(A,3X,A,1X,I5.5)') solver_name,'Global region:', & 
                                     pregion%iRegionGlobal  
  END IF ! global%verbLevel

! ******************************************************************************
! Set pointers and initialize
! ******************************************************************************

  pgrid => pregion%grid

  ifacesspecial = 0 
  pgrid%facesSpecial(1:2,1:nfaces_special_max) = 0

! ******************************************************************************
! Get information from user
! ******************************************************************************

  WRITE(stdout,'(A,5X,A)') solver_name,'Enter information on special faces:' 
  WRITE(stdout,'(A,7X,A)') solver_name,'b - boundary face'    
  WRITE(stdout,'(A,7X,A)') solver_name,'i - interior face'      
  WRITE(stdout,'(A,7X,A)') solver_name,'q - quit'

! ******************************************************************************
! Set up infinite loop
! ******************************************************************************

  DO
  
! ==============================================================================
!   Enter information type
! ==============================================================================
   
    WRITE(stdout,'(A,3X,A)') solver_name,'Enter information type:'
    READ(stdin,'(A)') infotype
  
    SELECT CASE ( infotype )

! ------------------------------------------------------------------------------    
!     Boundary face
! ------------------------------------------------------------------------------

      CASE ( 'b' ) 
        WRITE(stdout,'(A,5X,A)') solver_name,'Enter patch index:'
        READ(stdin,*,iostat=errorflag) patchindx

        IF ( errorflag /= err_none ) THEN 
          global%warnCounter = global%warnCounter + 1         
        
          WRITE(stdout,'(A,5X,A)') solver_name,'*** WARNING *** Invalid input.'
          cycle
        END IF ! errorFlag        
          
        IF ( patchindx > 0 .AND. patchindx <= pgrid%nPatches ) THEN
          ppatch => pregion%patches(patchindx)
         
          WRITE(stdout,'(A,5X,A)') solver_name,'Enter face index:'
          READ(stdin,*,iostat=errorflag) faceindx           

          IF ( errorflag /= err_none ) THEN
            global%warnCounter = global%warnCounter + 1           
           
            WRITE(stdout,'(A,5X,A)') solver_name, & 
                                     '*** WARNING *** Invalid input.'
            cycle
          END IF ! errorFlag 

          IF ( faceindx > 0 .AND. faceindx <= ppatch%nBFacesTot ) THEN
            IF ( ifacesspecial == nfaces_special_max ) THEN 
              CALL errorstop(global,err_nfaces_special_max,__line__)
            END IF ! iFacesSpecial         
           
            ifacesspecial = ifacesspecial + 1          
            pgrid%facesSpecial(1,ifacesspecial) = patchindx
            pgrid%facesSpecial(2,ifacesspecial) = faceindx            
  
            WRITE(stdout,'(A,5X,A,1X,I8)') solver_name,'Added face:',faceindx        
          ELSE 
            global%warnCounter = global%warnCounter + 1           
          
            WRITE(stdout,'(A,5X,A)') solver_name, & 
                                     '*** WARNING *** Invalid input.' 
            cycle 
          END IF ! faceIndx        
        ELSE 
          global%warnCounter = global%warnCounter + 1         
        
          WRITE(stdout,'(A,5X,A)') solver_name,'*** WARNING *** Invalid input.' 
          cycle 
        END IF ! patchIndx
   
! ------------------------------------------------------------------------------
!     Interior face     
! ------------------------------------------------------------------------------

      CASE ( 'i' ) 
        WRITE(stdout,'(A,5X,A)') solver_name,'Enter interior face index:'
        READ(stdin,*,iostat=errorflag) faceindx
 
        IF ( errorflag /= err_none ) THEN
          global%warnCounter = global%warnCounter + 1         
         
          WRITE(stdout,'(A,5X,A)') solver_name,'*** WARNING *** Invalid input.'
          cycle
        END IF ! errorFlag         
        
        IF ( faceindx > 0 .AND. faceindx <= pgrid%nFacesTot ) THEN
          IF ( ifacesspecial == nfaces_special_max ) THEN ! NOTE
            CALL errorstop(global,err_nfaces_special_max,__line__)
          END IF ! iFacesSpecial       
         
          ifacesspecial = ifacesspecial + 1          
          pgrid%facesSpecial(1,ifacesspecial) = 0
          pgrid%facesSpecial(2,ifacesspecial) = faceindx
                                        
          WRITE(stdout,'(A,5X,A,1X,I8)') solver_name,'Added face:',faceindx   
        ELSE 
          global%warnCounter = global%warnCounter + 1         
        
          WRITE(stdout,'(A,5X,A)') solver_name,'*** WARNING *** Invalid input.' 
          cycle 
        END IF ! faceIndx        
            
! ------------------------------------------------------------------------------
!     Quit       
! ------------------------------------------------------------------------------
      
      CASE ( 'q' )
        EXIT
        
! ------------------------------------------------------------------------------
!     Default        
! ------------------------------------------------------------------------------
        
      CASE default 
        global%warnCounter = global%warnCounter + 1 
      
        WRITE(stdout,'(A,5X,A)') solver_name,'*** WARNING *** Invalid input.' 
        cycle 
    END SELECT  
  END DO ! <empty> 

! ******************************************************************************
! Set number of special faces
! ******************************************************************************

  pgrid%nFacesSpecial = ifacesspecial

! ******************************************************************************
! End
! ******************************************************************************

  IF ( global%verbLevel > verbose_none ) THEN 
    WRITE(stdout,'(A,1X,A)') solver_name,'Picking special faces done.'
  END IF ! global%verbLevel

  CALL deregisterfunction(global)

END SUBROUTINE rflu_pickspecialfaces

! ******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLU_PickSpecialFaces.F90,v $
! Revision 1.3  2008/12/06 08:45:04  mtcampbe
! Updated license.
!
! Revision 1.2  2008/11/19 22:18:15  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.1  2004/09/27 02:02:23  haselbac
! Initial revision
!
! ******************************************************************************