RFLU_ModRocstarAdmin.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
! ******************************************************************************
!
! Purpose: Collection of routines related to GENX interaction.
!
! Description: None
!
! Notes: None.
!
! ******************************************************************************
!
! $Id: RFLU_ModGENXAdmin.F90,v 1.26 2009/05/12 20:20:56 mtcampbe Exp $
!
! Copyright: (c) 2004-2005 by the University of Illinois
!
! ******************************************************************************

MODULE rflu_modrocstaradmin

  USE moddatatypes
  USE modparameters
  USE moderror
  USE modglobal, ONLY: t_global
  USE modbndpatch, ONLY: t_patch
  USE moddatastruct, ONLY: t_region
  USE modgrid, ONLY: t_grid 
  USE modborder, ONLY: t_border
  USE modmpi 

  USE rflu_modrocstarutils
  USE rflu_modrocstartools, ONLY: rflu_genx_initbflag

  IMPLICIT NONE

  include 'roccomf90.h'

  PRIVATE
  PUBLIC :: rflu_genx_buildgridsurf, &
            rflu_genx_buildpconn, & 
            rflu_genx_closerocinctrlfiles, &
            rflu_genx_createattrdisp, & 
            rflu_genx_createattrflow, & 
            rflu_genx_createattrgridsurf, &
            rflu_genx_createattrgspeeds, &
            rflu_genx_createattrinterf, & 
            rflu_genx_createattrstats, & 
            rflu_genx_createattrturb, & 
            rflu_genx_createattrwrapper, & 
            rflu_genx_createdatainterf, &
            rflu_genx_creategridsurf, & 
            rflu_genx_createpconn, & 
            rflu_genx_createwindows, &
            rflu_genx_createwindowsdone, & 
            rflu_genx_destroydatainterf, &            
            rflu_genx_destroygridsurf, &
            rflu_genx_destroypconn, & 
            rflu_genx_hardcodewindowname, &
            rflu_genx_initrocman, & 
            rflu_genx_readctrlfile, &
            rflu_genx_registerdataflow, & 
            rflu_genx_registerdatagspeeds, & 
            rflu_genx_registerdatainterf, & 
            rflu_genx_registerdatastats, & 
            rflu_genx_registerdataturb, & 
            rflu_genx_registerdatawrapper, & 
            rflu_genx_registerdisp, & 
            rflu_genx_registergrid, &
            rflu_genx_registergridsurf, & 
            rflu_genx_registergridvol, & 
            rflu_genx_setconnsize, & 
            rflu_genx_storecommunicator, &
            rflu_genx_storenameshandles

! ******************************************************************************
! Declarations and definitions
! ******************************************************************************

! ==============================================================================  
! Private
! ==============================================================================  

  CHARACTER(CHRLEN) :: & 
    RCSIdentString = '$RCSfile: RFLU_ModGENXAdmin.F90,v $ $Revision: 1.26 $'       
  
! ==============================================================================  
! Public
! ==============================================================================  
  

! ******************************************************************************
! Contained routines
! ******************************************************************************

  CONTAINS 
  
  
  


! ******************************************************************************
!
! Purpose: Build surface grid.
!
! Description: None.
!
! Input:
!   pRegion             Pointer to region
!
! Output: None.
!
! Notes: 
!   1. Roccom requires locally-numbered boundary-face lists.
!
! ******************************************************************************

  SUBROUTINE rflu_genx_buildgridsurf(pRegion)
  
    USE rflu_modboundlists, ONLY: rflu_buildbfaceloclists
  
    IMPLICIT NONE

! ******************************************************************************
!   Declarations and definitions
! ******************************************************************************

! ==============================================================================  
!   Arguments 
! ==============================================================================  

    TYPE(t_region), POINTER :: pregion

! ==============================================================================  
!   Locals 
! ==============================================================================  
    
    INTEGER :: errorflag,ipatch,ivg,ivl
    TYPE(t_global), POINTER :: global
    TYPE(t_grid), POINTER :: pgrid
    TYPE(t_patch), POINTER :: ppatch
    
! ******************************************************************************
!   Start, set pointers
! ******************************************************************************
    
    global => pregion%global
    
    pgrid => pregion%grid
    
    CALL registerfunction(global,'RFLU_GENX_BuildGridSurf',&
  'RFLU_ModRocstarAdmin.F90')
    
! ******************************************************************************
!   Create locally-numbered boundary face lists
! ******************************************************************************

    CALL rflu_buildbfaceloclists(pregion)
  
! ******************************************************************************
!   Copy coordinates. NOTE no longer setting coordinates of virtual vertices to 
!   CRAZY_VALUE_INT because this makes testing of service modules difficult. 
! ******************************************************************************  

    DO ipatch=1,pgrid%nPatches
      ppatch => pregion%patches(ipatch)
                
      DO ivl = 1,ppatch%nBVertTot
        ivg = ppatch%bv(ivl)
      
        ppatch%xyz(xcoord,ivl) = pgrid%xyz(xcoord,ivg)
        ppatch%xyz(ycoord,ivl) = pgrid%xyz(ycoord,ivg)
        ppatch%xyz(zcoord,ivl) = pgrid%xyz(zcoord,ivg)                
      END DO ! ivl
    END DO ! iPatch
  
! ******************************************************************************
!   End
! ******************************************************************************
  
    CALL deregisterfunction(global)  
  
  END SUBROUTINE rflu_genx_buildgridsurf

  
  
  



! ******************************************************************************
!
! Purpose: Build pconn attribute. 
!
! Description: None.
!
! Input:
!   pRegion             Pointer to region
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

  SUBROUTINE rflu_genx_buildpconn(pRegion)
    
    IMPLICIT NONE

! ******************************************************************************
!   Declarations and definitions
! ******************************************************************************

! ==============================================================================  
!   Arguments 
! ==============================================================================  

    TYPE(t_region), POINTER :: pregion

! ==============================================================================  
!   Locals 
! ==============================================================================  
    
    INTEGER :: errorflag,iborder,icl,ipc,ivl,paneid
    TYPE(t_global), POINTER :: global
    TYPE(t_grid), POINTER :: pgrid
    TYPE(t_border), POINTER :: pborder
    
! ******************************************************************************
!   Start, set pointers
! ******************************************************************************
    
    global => pregion%global
    
    pgrid => pregion%grid

    CALL registerfunction(global,'RFLU_GENX_BuildPConn',&
  'RFLU_ModRocstarAdmin.F90')

    IF ( global%myProcid == masterproc .AND. & 
         global%verbLevel >= verbose_high ) THEN 
      WRITE(stdout,'(A,1X,A)') solver_name,'Building pconn...'
    END IF ! global%verbLevel

! ******************************************************************************
!   Fill pconn array
! ******************************************************************************  

    ipc = 0 

! ==============================================================================
!   Block 1: Shared vertices
! ==============================================================================

    ipc = ipc + 1
    pgrid%pconn(ipc) = pgrid%nBorders

    DO iborder = 1,pgrid%nBorders
      pborder => pgrid%borders(iborder)

! ------------------------------------------------------------------------------
!     Pane id
! ------------------------------------------------------------------------------

      CALL rflu_genx_buildpaneid(pborder%iRegionGlobal,0,paneid)

      ipc = ipc + 1
      pgrid%pconn(ipc) = paneid

! ------------------------------------------------------------------------------
!     Dimension
! ------------------------------------------------------------------------------

      ipc = ipc + 1
      pgrid%pconn(ipc) = pborder%nVertShared

! ------------------------------------------------------------------------------
!     Data
! ------------------------------------------------------------------------------

      DO ivl = 1,pborder%nVertShared
        ipc = ipc + 1
        pgrid%pconn(ipc) = pborder%ivgShared(ivl)
      END DO ! ivl
    END DO ! iBorder      

! ==============================================================================
!   Block 2: Vertices to send
! ==============================================================================

    ipc = ipc + 1
    pgrid%pconn(ipc) = pgrid%nBorders

    DO iborder = 1,pgrid%nBorders
      pborder => pgrid%borders(iborder)

! ------------------------------------------------------------------------------
!     Pane id
! ------------------------------------------------------------------------------

      CALL rflu_genx_buildpaneid(pborder%iRegionGlobal,0,paneid)

      ipc = ipc + 1
      pgrid%pconn(ipc) = paneid

! ------------------------------------------------------------------------------
!     Dimension
! ------------------------------------------------------------------------------

      ipc = ipc + 1
      pgrid%pconn(ipc) = pborder%nVertSend

! ------------------------------------------------------------------------------
!     Data
! ------------------------------------------------------------------------------

      DO ivl = 1,pborder%nVertSend
        ipc = ipc + 1
        pgrid%pconn(ipc) = pborder%ivgSend(ivl)
      END DO ! ivl
    END DO ! iBorder      

! ==============================================================================
!   Block 3: Vertices to recv
! ==============================================================================

    ipc = ipc + 1
    pgrid%pconn(ipc) = pgrid%nBorders

    DO iborder = 1,pgrid%nBorders
      pborder => pgrid%borders(iborder)

! ------------------------------------------------------------------------------
!     Pane id
! ------------------------------------------------------------------------------

      CALL rflu_genx_buildpaneid(pborder%iRegionGlobal,0,paneid)

      ipc = ipc + 1
      pgrid%pconn(ipc) = paneid

! ------------------------------------------------------------------------------
!     Dimension
! ------------------------------------------------------------------------------

      ipc = ipc + 1
      pgrid%pconn(ipc) = pborder%nVertRecv

! ------------------------------------------------------------------------------
!     Data
! ------------------------------------------------------------------------------

      DO ivl = 1,pborder%nVertRecv
        ipc = ipc + 1
        pgrid%pconn(ipc) = pborder%ivgRecv(ivl)
      END DO ! ivl
    END DO ! iBorder      

! ==============================================================================
!   Block 4: Cells to send
! ==============================================================================

    ipc = ipc + 1
    pgrid%pconn(ipc) = pgrid%nBorders

    DO iborder = 1,pgrid%nBorders
      pborder => pgrid%borders(iborder)

! ------------------------------------------------------------------------------
!     Pane id
! ------------------------------------------------------------------------------


      CALL rflu_genx_buildpaneid(pborder%iRegionGlobal,0,paneid)

      ipc = ipc + 1
      pgrid%pconn(ipc) = paneid

! ------------------------------------------------------------------------------
!     Dimension
! ------------------------------------------------------------------------------

      ipc = ipc + 1
      pgrid%pconn(ipc) = pborder%nCellsSend

! ------------------------------------------------------------------------------
!     Data
! ------------------------------------------------------------------------------

      DO icl = 1,pborder%nCellsSend
        ipc = ipc + 1
        pgrid%pconn(ipc) = pborder%icgSend(icl)
      END DO ! ivl
    END DO ! iBorder      

! ==============================================================================
!   Block 5: Cells to recv
! ==============================================================================

    ipc = ipc + 1
    pgrid%pconn(ipc) = pgrid%nBorders

    DO iborder = 1,pgrid%nBorders
      pborder => pgrid%borders(iborder)

! ------------------------------------------------------------------------------
!     Pane id
! ------------------------------------------------------------------------------

      CALL rflu_genx_buildpaneid(pborder%iRegionGlobal,0,paneid)

      ipc = ipc + 1
      pgrid%pconn(ipc) = paneid

! ------------------------------------------------------------------------------
!     Dimension
! ------------------------------------------------------------------------------

      ipc = ipc + 1
      pgrid%pconn(ipc) = pborder%nCellsRecv

! ------------------------------------------------------------------------------
!     Data
! ------------------------------------------------------------------------------

      DO icl = 1,pborder%nCellsRecv
        ipc = ipc + 1
        pgrid%pconn(ipc) = pborder%icgRecv(icl)
      END DO ! ivl
    END DO ! iBorder   

! ******************************************************************************
!   End
! ******************************************************************************

    IF ( global%myProcid == masterproc .AND. & 
         global%verbLevel >= verbose_high ) THEN 
      WRITE(stdout,'(A,1X,A)') solver_name,'Building pconn done.'
    END IF ! global%verbLevel

    CALL deregisterfunction(global)
  
  END SUBROUTINE rflu_genx_buildpconn



  
  

! ******************************************************************************
!
! Purpose: Close control files for Rocin.
!
! Description: None.
!
! Input:
!   global              Pointer to global data
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

  SUBROUTINE rflu_genx_closerocinctrlfiles(global)

    IMPLICIT NONE

! ******************************************************************************
!   Declarations and definitions
! ******************************************************************************

! ==============================================================================  
!   Arguments 
! ==============================================================================  

    TYPE(t_global), POINTER :: global

! ==============================================================================  
!   Locals 
! ==============================================================================  

    CHARACTER(CHRLEN) :: ifilename
    CHARACTER(GENX_TIME_STRING_LEN) :: timestring
    INTEGER :: errorflag    
        
! ******************************************************************************
!   Start
! ******************************************************************************

    CALL registerfunction(global,'RFLU_GENX_CloseRocinCtrlFiles', & 
                          'RFLU_ModRocstarAdmin.F90')

    IF ( global%myProcid == masterproc .AND. & 
         global%verbLevel >= verbose_high ) THEN 
      WRITE(stdout,'(A,1X,A)') solver_name,'Closing Rocin control files...'
    END IF ! global%verbLevel
     
! ******************************************************************************
!   Close files
! ******************************************************************************

! ==============================================================================  
!   Volume file 
! ==============================================================================  
 
    CALL rflu_genx_buildtimestring(global%currentTime,timestring)
    ifilename = './Rocflu/Rocin/fluid_in_'//trim(timestring)//'.txt'

    CLOSE(if_ctrl_vol,iostat=errorflag)
    global%error = errorflag
    IF ( global%error /= err_none ) THEN 
      CALL errorstop(global,err_file_close,__line__,ifilename) 
    END IF ! global%error

! ==============================================================================  
!   Surface file 
! ==============================================================================  

    CALL rflu_genx_buildtimestring(global%currentTime,timestring)
    ifilename = './Rocflu/Rocin/ifluid_in_'//trim(timestring)//'.txt'

    CLOSE(if_ctrl_surf,iostat=errorflag)
    global%error = errorflag
    IF ( global%error /= err_none ) THEN 
      CALL errorstop(global,err_file_close,__line__,ifilename) 
    END IF ! global%error
 
! ******************************************************************************
!   End
! ******************************************************************************

    IF ( global%myProcid == masterproc .AND. & 
         global%verbLevel >= verbose_high ) THEN 
      WRITE(stdout,'(A,1X,A)') solver_name,'Closing Rocin control files done.'
    END IF ! global%verbLevel
      
    CALL deregisterfunction(global)  
  
  END SUBROUTINE rflu_genx_closerocinctrlfiles
  
  
  
  
  

! ******************************************************************************
!
! Purpose: Create new attributes for displacements.
!
! Description: None.
!
! Input:
!   pRegion             Pointer to region
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

  SUBROUTINE rflu_genx_createattrdisp(pRegion)
  
    IMPLICIT NONE

! ******************************************************************************
!   Declarations and definitions
! ******************************************************************************

! ==============================================================================  
!   Arguments 
! ==============================================================================  

    TYPE(t_region), POINTER :: pregion

! ==============================================================================  
!   Locals 
! ==============================================================================  
    
    CHARACTER(CHRLEN) :: winname
    TYPE(t_global), POINTER :: global
    
! ******************************************************************************
!   Start, set pointers and variables
! ******************************************************************************
    
    global => pregion%global
    
! ******************************************************************************
!   Create new attributes
! ******************************************************************************
    
    winname = global%volWinName
    
    CALL com_new_attribute(trim(winname)//'.disp','n',com_double_precision,3,'')

! ******************************************************************************
!   End
! ******************************************************************************
  
  END SUBROUTINE rflu_genx_createattrdisp
  
  
  
  
  
  
! ******************************************************************************
!
! Purpose: Create new attributes for mixture solution.
!
! Description: None.
!
! Input:
!   pRegion             Pointer to region
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

  SUBROUTINE rflu_genx_createattrflow(pRegion)
  
    IMPLICIT NONE

! ******************************************************************************
!   Declarations and definitions
! ******************************************************************************

! ==============================================================================  
!   Arguments 
! ==============================================================================  

    TYPE(t_region), POINTER :: pregion

! ==============================================================================  
!   Locals 
! ==============================================================================  
    
    CHARACTER(CHRLEN) :: winname
    TYPE(t_global), POINTER :: global
    
! ******************************************************************************
!   Start, set pointers
! ******************************************************************************
    
    global => pregion%global
    
! ******************************************************************************
!   Create new attributes
! ******************************************************************************

! ==============================================================================  
!   Volume
! ==============================================================================  

    winname = global%volWinName
    
    CALL com_new_attribute(trim(winname)//'.rhof' ,'e',com_double_precision, &
                           1,'kg/(m^3)')
    CALL com_new_attribute(trim(winname)//'.rhovf','e',com_double_precision, &
                           3,'kg/(m^2 s)')
    CALL com_new_attribute(trim(winname)//'.rhoEf','e',com_double_precision, &
                           1,'(J/(m^3))')  
    CALL com_new_attribute(trim(winname)//'.pf','e',com_double_precision,1, & 
                           'N/(m^2)')  
    CALL com_new_attribute(trim(winname)//'.Tf','e',com_double_precision,1, &
                           'K')
    CALL com_new_attribute(trim(winname)//'.af','e',com_double_precision,1, &
                           'm/s')
  
! ******************************************************************************
!   End
! ******************************************************************************
  
  END SUBROUTINE rflu_genx_createattrflow  
  
  
  
  
  


! ******************************************************************************
!
! Purpose: Create new attributes for surface grid.
!
! Description: None.
!
! Input:
!   pRegion             Pointer to region
!
! Output: None.
!
! Notes: 
!   1. Must not access dimensions of grid, because not necessarily known.
!
! ******************************************************************************

  SUBROUTINE rflu_genx_createattrgridsurf(pRegion)
  
    IMPLICIT NONE

! ******************************************************************************
!   Declarations and definitions
! ******************************************************************************

! ==============================================================================  
!   Arguments 
! ==============================================================================  

    TYPE(t_region), POINTER :: pregion

! ==============================================================================  
!   Locals 
! ==============================================================================  
    
    CHARACTER(CHRLEN) :: winname
    TYPE(t_global), POINTER :: global
    
! ******************************************************************************
!   Start, set pointers and variables
! ******************************************************************************
    
    global => pregion%global
    
! ******************************************************************************
!   Create new attributes
! ******************************************************************************

    winname = global%surfWinName

    CALL com_new_attribute(trim(winname)//'.bcflag'     ,'p',com_integer,1,'')
    CALL com_new_attribute(trim(winname)//'.patchNo'    ,'p',com_integer,1,'')    
    CALL com_new_attribute(trim(winname)//'.cnstr_type' ,'p',com_integer,1,'')
  
    CALL com_new_attribute(trim(winname)//'.t3g:real'   ,'p',com_integer,3,'')
    CALL com_new_attribute(trim(winname)//'.t3g:virtual','p',com_integer,3,'')    

    CALL com_new_attribute(trim(winname)//'.q4g:real'   ,'p',com_integer,4,'')
    CALL com_new_attribute(trim(winname)//'.q4g:virtual','p',com_integer,4,'')    

! ******************************************************************************
!   End
! ******************************************************************************
  
  END SUBROUTINE rflu_genx_createattrgridsurf
  
  

 




! ******************************************************************************
!
! Purpose: Create new attributes for grid speeds.
!
! Description: None.
!
! Input:
!   pRegion             Pointer to region
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

  SUBROUTINE rflu_genx_createattrgspeeds(pRegion)
  
    IMPLICIT NONE

! ******************************************************************************
!   Declarations and definitions
! ******************************************************************************

! ==============================================================================  
!   Arguments 
! ==============================================================================  

    TYPE(t_region), POINTER :: pregion

! ==============================================================================  
!   Locals 
! ==============================================================================  
    
    CHARACTER(CHRLEN) :: winname
    TYPE(t_global), POINTER :: global
    
! ******************************************************************************
!   Start, set pointers
! ******************************************************************************
    
    global => pregion%global
    
! ******************************************************************************
!   Create new attributes
! ******************************************************************************

! ==============================================================================  
!   Volume
! ==============================================================================  

    winname = global%volWinName
    
    CALL com_new_attribute(trim(winname)//'.gs','p',com_double_precision, & 
                           1,'m/s') 

! ==============================================================================  
!   Surface
! ==============================================================================  

    winname = global%surfWinName
  
    CALL com_new_attribute(trim(winname)//'.gs','e',com_double_precision, & 
                           1,'m/s')
  
! ******************************************************************************
!   End
! ******************************************************************************
  
  END SUBROUTINE rflu_genx_createattrgspeeds







! ******************************************************************************
!
! Purpose: Create new attributes for interface data.
!
! Description: None.
!
! Input:
!   pRegion             Pointer to region
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

  SUBROUTINE rflu_genx_createattrinterf(pRegion)
  
    IMPLICIT NONE

! ******************************************************************************
!   Declarations and definitions
! ******************************************************************************

! ==============================================================================  
!   Arguments 
! ==============================================================================  

    TYPE(t_region), POINTER :: pregion

! ==============================================================================  
!   Locals 
! ==============================================================================  
    
    CHARACTER(CHRLEN) :: winname
    INTEGER :: comd,comi
    TYPE(t_global), POINTER :: global
    
! ******************************************************************************
!   Start, set pointers and variables
! ******************************************************************************
    
    global => pregion%global

    winname = global%surfWinName
    
    comd = com_double_precision 
    comi = com_integer 
    
! ******************************************************************************
!   Create new attributes
! ******************************************************************************

! ==============================================================================  
!   Incoming data
! ==============================================================================  
    
    CALL com_new_attribute(trim(winname)//'.du_alp'    ,'n',comd,3,'m'        )
    CALL com_new_attribute(trim(winname)//'.mdot_alp'  ,'e',comd,1,'kg/(m^2s)')
    CALL com_new_attribute(trim(winname)//'.rhofvf_alp','e',comd,3,'kg/(m^2s)')
    CALL com_new_attribute(trim(winname)//'.Tflm_alp'  ,'e',comd,1,'K'        )
    CALL com_new_attribute( trim(winname)//'.zoomFact' ,'w',comd,1,'none' )
    CALL com_new_attribute(trim(winname)//'.Tb_alp'    ,'e',comd,1,'K'        )

! ==============================================================================  
!   Outgoing data
! ==============================================================================  

    CALL com_new_attribute(trim(winname)//'.nf_alp'  ,'e',comd,3,''          )
    CALL com_new_attribute(trim(winname)//'.pf'      ,'e',comd,1,'Pa'        )
    CALL com_new_attribute(trim(winname)//'.tf'      ,'e',comd,3,'Pa'        )  
    CALL com_new_attribute(trim(winname)//'.qc'      ,'e',comd,1,'kgK/(m^2s)')
    CALL com_new_attribute(trim(winname)//'.qr'      ,'e',comd,1,'kgK/(m^2s)')
    CALL com_new_attribute(trim(winname)//'.rhof_alp','e',comd,1,'kg/m^3'    )
    CALL com_new_attribute(trim(winname)//'.Tf'      ,'e',comd,1,'K'         )
!    CALL COM_new_attribute(TRIM(winName)//'.Tv'      ,'e',comd,1,'K'         )
!    CALL COM_new_attribute(TRIM(winName)//'.dn'      ,'e',comd,1,'m'         )

! ==============================================================================  
!   Interface data (utility data used in the interface)
! ==============================================================================  

    CALL com_new_attribute(trim(winname)//'.bflag'   ,'e',comi,1,''          )
      
! ******************************************************************************
!   End
! ******************************************************************************
  
  END SUBROUTINE rflu_genx_createattrinterf






  
! ******************************************************************************
!
! Purpose: Create new attributes for statistics data.
!
! Description: None.
!
! Input:
!   pRegion             Pointer to region
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

  SUBROUTINE rflu_genx_createattrstats(pRegion)
#ifdef STATS  
    USE stat_rflu_modrocstaradmin, ONLY: stat_rflu_genxcreateattr
#endif
    IMPLICIT NONE

! ******************************************************************************
!   Declarations and definitions
! ******************************************************************************

! ==============================================================================  
!   Arguments 
! ==============================================================================  

    TYPE(t_region), POINTER :: pregion
    
! ******************************************************************************
!   Create new attributes
! ******************************************************************************
#ifdef STATS
    CALL stat_rflu_genxcreateattr(pregion)
#endif  
! ******************************************************************************
!   End
! ******************************************************************************
  
  END SUBROUTINE rflu_genx_createattrstats






  
! ******************************************************************************
!
! Purpose: Create new attributes for turbulence.
!
! Description: None.
!
! Input:
!   pRegion             Pointer to region
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

  SUBROUTINE rflu_genx_createattrturb(pRegion)
#ifdef TURB  
    USE turb_rflu_modrocstaradmin, ONLY: turb_rflu_genxcreateattr
#endif
    IMPLICIT NONE

! ******************************************************************************
!   Declarations and definitions
! ******************************************************************************

! ==============================================================================  
!   Arguments 
! ==============================================================================  

    TYPE(t_region), POINTER :: pregion
    
! ******************************************************************************
!   Create new attributes
! ******************************************************************************
#ifdef TURB
    CALL turb_rflu_genxcreateattr(pregion)
#endif  
! ******************************************************************************
!   End
! ******************************************************************************
  
  END SUBROUTINE rflu_genx_createattrturb






  
! ******************************************************************************
!
! Purpose: Wrapper for new attributes routines.
!
! Description: None.
!
! Input:
!   pRegion             Pointer to region
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

  SUBROUTINE rflu_genx_createattrwrapper(pRegion)
  
    IMPLICIT NONE

! ******************************************************************************
!   Declarations and definitions
! ******************************************************************************

! ==============================================================================  
!   Arguments 
! ==============================================================================  

    TYPE(t_region), POINTER :: pregion
    
! ******************************************************************************
!   Create new attributes
! ******************************************************************************

! ==============================================================================  
!   Mixture
! ==============================================================================  

    CALL rflu_genx_createattrflow(pregion)
    CALL rflu_genx_createattrgridsurf(pregion)
    CALL rflu_genx_createattrgspeeds(pregion)     
    CALL rflu_genx_createattrinterf(pregion)
    CALL rflu_genx_createattrdisp(pregion)

! ==============================================================================  
!   Statistics
! ==============================================================================  

    CALL rflu_genx_createattrstats(pregion)

! ==============================================================================  
!   Turbulence
! ==============================================================================  

    CALL rflu_genx_createattrturb(pregion)
  
! ******************************************************************************
!   End
! ******************************************************************************
  
  END SUBROUTINE rflu_genx_createattrwrapper







! ******************************************************************************
!
! Purpose: Create interface data arrays.
!
! Description: None.
!
! Input:
!   pRegion             Pointer to region
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

  SUBROUTINE rflu_genx_createdatainterf(pRegion)
  
    IMPLICIT NONE

! ******************************************************************************
!   Declarations and definitions
! ******************************************************************************

! ==============================================================================  
!   Arguments 
! ==============================================================================  

    TYPE(t_region), POINTER :: pregion
    
! ==============================================================================  
!   Locals 
! ==============================================================================  
    
    INTEGER :: errorflag,ifl,ipatch,ivl    
    TYPE(t_global), POINTER :: global
    TYPE(t_grid), POINTER :: pgrid
    TYPE(t_patch), POINTER :: ppatch
      
! ******************************************************************************
!   Start, set pointers
! ******************************************************************************
    
    global => pregion%global

    pgrid => pregion%grid 

    CALL registerfunction(global,'RFLU_GENX_CreateDataInterf',&
  'RFLU_ModRocstarAdmin.F90')

! ******************************************************************************
!   Allocate memory 
! ******************************************************************************  
  
    DO ipatch = 1,pgrid%nPatches
      ppatch => pregion%patches(ipatch)
    
! ==============================================================================
!     Surface grid deformation
! ==============================================================================

      ALLOCATE(ppatch%dXyz(xcoord:zcoord,ppatch%nBVertTot),stat=errorflag)
      global%error = errorflag
      IF ( global%error /= err_none ) THEN 
        CALL errorstop(global,err_allocate,__line__,'pPatch%dXyz')
      END IF ! global%error      

      DO ivl = 1,ppatch%nBVertTot   
        ppatch%dXyz(xcoord,ivl) = 0.0_rfreal
        ppatch%dXyz(ycoord,ivl) = 0.0_rfreal
        ppatch%dXyz(zcoord,ivl) = 0.0_rfreal            
      END DO ! ivl

! ==============================================================================
!     Input data
! ==============================================================================      
      
! ------------------------------------------------------------------------------
!     All patches      
! ------------------------------------------------------------------------------
      
      ALLOCATE(ppatch%duAlp(xcoord:zcoord,ppatch%nBVertTot),stat=errorflag)
      global%error = errorflag
      IF ( global%error /= err_none ) THEN 
        CALL errorstop(global,err_allocate,__line__,'pPatch%duAlp')
      END IF ! global

      DO ivl = 1,ppatch%nBVertTot 
        ppatch%duAlp(xcoord,ivl) = 0.0_rfreal
        ppatch%duAlp(ycoord,ivl) = 0.0_rfreal
        ppatch%duAlp(zcoord,ivl) = 0.0_rfreal      
      END DO ! ivl

! ------------------------------------------------------------------------------
!     Interacting patches (burning or non-burning)       
! ------------------------------------------------------------------------------

      IF ( ppatch%bcCoupled /= bc_not_coupled ) THEN 
        ALLOCATE(ppatch%rhofvfAlp(xcoord:zcoord,ppatch%nBFacesTot), & 
                 stat=errorflag)
        global%error = errorflag         
        IF ( global%error /= err_none ) THEN 
          CALL errorstop(global,err_allocate,__line__,'pPatch%rhofvfAlp')
        END IF ! global

        DO ifl = 1,ppatch%nBFacesTot 
          ppatch%rhofvfAlp(xcoord,ifl) = 0.0_rfreal
          ppatch%rhofvfAlp(ycoord,ifl) = 0.0_rfreal
          ppatch%rhofvfAlp(zcoord,ifl) = 0.0_rfreal        
        END DO ! ifl
        
        ALLOCATE(ppatch%tbAlp(ppatch%nBFacesTot),stat=errorflag)
        global%error = errorflag
        IF ( global%error /= err_none ) THEN 
          CALL errorstop(global,err_allocate,__line__,'pPatch%tbAlp')
        END IF ! global

        DO ifl = 1,ppatch%nBFacesTot 
          ppatch%tbAlp(ifl) = 0.0_rfreal
        END DO ! ifl           
      END IF ! pPatch

! ------------------------------------------------------------------------------
!     Burning patches 
! ------------------------------------------------------------------------------

      IF ( ppatch%bcCoupled == bc_burning ) THEN 
        ALLOCATE(ppatch%mdotAlp(ppatch%nBFacesTot),stat=errorflag)
        global%error = errorflag
        IF ( global%error /= err_none ) THEN 
          CALL errorstop(global,err_allocate,__line__,'pPatch%mdotAlp')
        END IF ! global

        DO ifl = 1,ppatch%nBFacesTot 
          ppatch%mdotAlp(ifl) = 0.0_rfreal
        END DO ! ifl

        ALLOCATE(ppatch%tflmAlp(ppatch%nBFacesTot),stat=errorflag)
        global%error = errorflag
        IF ( global%error /= err_none ) THEN 
          CALL errorstop(global,err_allocate,__line__,'pPatch%tflmAlp')
        END IF ! global

        DO ifl = 1,ppatch%nBFacesTot 
          ppatch%tflmAlp(ifl) = 0.0_rfreal
        END DO ! ifl      
      END IF ! pPatch  
      
! ==============================================================================
!     Output data
! ==============================================================================      

! ------------------------------------------------------------------------------
!     Interacting patches (burning or non-burning)       
! ------------------------------------------------------------------------------

      IF ( ppatch%bcCoupled /= bc_not_coupled ) THEN 
        ALLOCATE(ppatch%nfAlp(xcoord:zcoord,ppatch%nBFacesTot),stat=errorflag)
        global%error = errorflag
        IF ( global%error /= err_none ) THEN 
          CALL errorstop(global,err_allocate,__line__,'pPatch%nfAlp')
        END IF ! global             

        DO ifl = 1,ppatch%nBFacesTot 
          ppatch%nfAlp(xcoord,ifl) = 0.0_rfreal
          ppatch%nfAlp(ycoord,ifl) = 0.0_rfreal
          ppatch%nfAlp(zcoord,ifl) = 0.0_rfreal                
        END DO ! ifl

        ALLOCATE(ppatch%rhofAlp(ppatch%nBFacesTot),stat=errorflag)
        global%error = errorflag
        IF ( global%error /= err_none ) THEN 
          CALL errorstop(global,err_allocate,__line__,'pPatch%rhofAlp')
        END IF ! global                    

        DO ifl = 1,ppatch%nBFacesTot 
          ppatch%rhofAlp(ifl) = 0.0_rfreal
        END DO ! ifl

        ALLOCATE(ppatch%pf(ppatch%nBFacesTot),stat=errorflag)
        global%error = errorflag
        IF ( global%error /= err_none ) THEN 
          CALL errorstop(global,err_allocate,__line__,'pPatch%pf')
        END IF ! global            

        DO ifl = 1,ppatch%nBFacesTot 
          ppatch%pf(ifl) = 0.0_rfreal
        END DO ! ifl

        ALLOCATE(ppatch%tracf(xcoord:zcoord,ppatch%nBFacesTot),stat=errorflag)
        global%error = errorflag
        IF ( global%error /= err_none ) THEN 
          CALL errorstop(global,err_allocate,__line__,'pPatch%tracf')
        END IF ! global

        DO ifl = 1,ppatch%nBFacesTot 
          ppatch%tracf(xcoord,ifl) = 0.0_rfreal
          ppatch%tracf(ycoord,ifl) = 0.0_rfreal
          ppatch%tracf(zcoord,ifl) = 0.0_rfreal                             
        END DO ! ifl      
        
        ALLOCATE(ppatch%qc(ppatch%nBFacesTot),stat=errorflag)
        global%error = errorflag
        IF ( global%error /= err_none ) THEN 
          CALL errorstop(global,err_allocate,__line__,'pPatch%qc')
        END IF ! global             

        DO ifl = 1,ppatch%nBFacesTot 
          ppatch%qc(ifl) = 0.0_rfreal
        END DO ! ifl

        ALLOCATE(ppatch%qr(ppatch%nBFacesTot),stat=errorflag)
        global%error = errorflag
        IF ( global%error /= err_none ) THEN 
          CALL errorstop(global,err_allocate,__line__,'pPatch%qr')
        END IF ! global             

        DO ifl = 1,ppatch%nBFacesTot 
          ppatch%qr(ifl) = 0.0_rfreal
        END DO ! ifl        
      END IF ! pPatch%bcCoupled

! ------------------------------------------------------------------------------
!     Burning patches
! ------------------------------------------------------------------------------

      IF ( ppatch%bcCoupled == bc_burning ) THEN     
        ALLOCATE(ppatch%tempf(ppatch%nBFacesTot),stat=errorflag)
        global%error = errorflag
        IF ( global%error /= err_none ) THEN 
          CALL errorstop(global,err_allocate,__line__,'pPatch%tempf')
        END IF ! global  

        DO ifl = 1,ppatch%nBFacesTot 
          ppatch%tempf(ifl) = 0.0_rfreal
        END DO ! ifl

! TEMPORARY
!       bFlag will need to be removed from Rocflu eventually. For the 
!       moment, leave in, but always set bFlag to 1. This means that igniting 
!       computations cannot be run.
    
        ALLOCATE(ppatch%bFlag(ppatch%nBFacesTot),stat=errorflag)
        global%error = errorflag
        IF ( global%error /= err_none ) THEN 
          CALL errorstop(global,err_allocate,__line__,'pPatch%bFlag')
        END IF ! global  

        DO ifl = 1,ppatch%nBFaces 
          ppatch%bFlag(ifl) = 1
        END DO ! ifl   

        DO ifl = ppatch%nBFaces+1,ppatch%nBFacesTot 
          ppatch%bFlag(ifl) = crazy_value_int
        END DO ! ifl        
! END TEMPORARY 
      END IF ! pPatch%bcType
    END DO ! iPatch  
  
! ******************************************************************************
!   End
! ******************************************************************************

    CALL rflu_genx_initbflag(pregion)

    CALL deregisterfunction(global)
  
  END SUBROUTINE rflu_genx_createdatainterf










! ******************************************************************************
!
! Purpose: Create surface grid.
!
! Description: None.
!
! Input:
!   pRegion             Pointer to region
!
! Output: None.
!
! Notes: 
!   1. Roccom requires locally-numbered boundary-face lists.
!
! ******************************************************************************

  SUBROUTINE rflu_genx_creategridsurf(pRegion)
  
    USE rflu_modboundlists, ONLY: rflu_createbfaceloclists
  
    IMPLICIT NONE

! ******************************************************************************
!   Declarations and definitions
! ******************************************************************************

! ==============================================================================  
!   Arguments 
! ==============================================================================  

    TYPE(t_region), POINTER :: pregion

! ==============================================================================  
!   Locals 
! ==============================================================================  
    
    INTEGER :: errorflag,ipatch
    TYPE(t_global), POINTER :: global
    TYPE(t_grid), POINTER :: pgrid
    TYPE(t_patch), POINTER :: ppatch
    
! ******************************************************************************
!   Start, set pointers
! ******************************************************************************
    
    global => pregion%global
    
    pgrid => pregion%grid

    CALL registerfunction(global,'RFLU_GENX_CreateGridSurf',&
  'RFLU_ModRocstarAdmin.F90')
    
! ******************************************************************************
!   Create locally-numbered boundary face lists
! ******************************************************************************

    CALL rflu_createbfaceloclists(pregion)
  
! ******************************************************************************
!   Allocate memory and initialize 
! ******************************************************************************  

    DO ipatch=1,pgrid%nPatches
      ppatch => pregion%patches(ipatch)

      ALLOCATE(ppatch%bcFlag(1),stat=errorflag)
      global%error = errorflag
      IF ( global%error /= err_none ) THEN 
        CALL errorstop(global,err_allocate,__line__,'pPatch%bcFlag')
      END IF ! global            
                
      ppatch%bcFlag(1) = ppatch%bcCoupled
                
      ALLOCATE(ppatch%patchNo(1),stat=errorflag)
      global%error = errorflag
      IF ( global%error /= err_none ) THEN 
        CALL errorstop(global,err_allocate,__line__,'pPatch%patchNo')
      END IF ! global                 

      ppatch%patchNo(1) = ppatch%iPatchGlobal          
                
      ALLOCATE(ppatch%cnstrType(1),stat=errorflag)
      global%error = errorflag
      IF ( global%error /= err_none ) THEN 
        CALL errorstop(global,err_allocate,__line__,'pPatch%cnstrType')
      END IF ! global                 

      ppatch%cnstrType(1) = rflu_genx_setcnstrtype(ppatch%movePatchDir)         
                
      ALLOCATE(ppatch%xyz(xcoord:zcoord,ppatch%nBVertTot),stat=errorflag)
      global%error = errorflag
      IF ( global%error /= err_none ) THEN 
        CALL errorstop(global,err_allocate,__line__,'pPatch%xyz')
      END IF ! global%error  
    END DO ! iPatch

! ******************************************************************************
!   End
! ******************************************************************************

    CALL deregisterfunction(global)
  
  END SUBROUTINE rflu_genx_creategridsurf







! ******************************************************************************
!
! Purpose: Create pconn attribute.
!
! Description: None.
!
! Input:
!   pRegion             Pointer to region
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

  SUBROUTINE rflu_genx_createpconn(pRegion)
    
    IMPLICIT NONE

! ******************************************************************************
!   Declarations and definitions
! ******************************************************************************

! ==============================================================================  
!   Arguments 
! ==============================================================================  

    TYPE(t_region), POINTER :: pregion

! ==============================================================================  
!   Locals 
! ==============================================================================  
    
    INTEGER :: errorflag,iborder
    TYPE(t_global), POINTER :: global
    TYPE(t_grid), POINTER :: pgrid
    TYPE(t_border), POINTER :: pborder
    
! ******************************************************************************
!   Start, set pointers
! ******************************************************************************
    
    global => pregion%global
    
    pgrid => pregion%grid

    CALL registerfunction(global,'RFLU_GENX_CreatePConn',&
  'RFLU_ModRocstarAdmin.F90')

    IF ( global%myProcid == masterproc .AND. & 
         global%verbLevel >= verbose_high ) THEN 
      WRITE(stdout,'(A,1X,A)') solver_name,'Creating pconn...'
    END IF ! global%verbLevel

! ******************************************************************************
!   Determine size of pconn attribute
! ******************************************************************************  

    pgrid%pconnSizeTot   = 0
    pgrid%pconnSizeGhost = 0 

! ==============================================================================
!   Block 1: Shared vertices
! ==============================================================================

    pgrid%pconnSizeTot = pgrid%pconnSizeTot + 1

    DO iborder = 1,pgrid%nBorders
      pborder => pgrid%borders(iborder)

      pgrid%pconnSizeTot = pgrid%pconnSizeTot + pborder%nVertShared + 2  
    END DO ! iBorder      

! ==============================================================================
!   Block 2: Vertices to send
! ==============================================================================

    pgrid%pconnSizeTot   = pgrid%pconnSizeTot   + 1
    pgrid%pconnSizeGhost = pgrid%pconnSizeGhost + 1

    DO iborder = 1,pgrid%nBorders
      pborder => pgrid%borders(iborder)

      pgrid%pconnSizeTot   = pgrid%pconnSizeTot   + pborder%nVertSend + 2 
      pgrid%pconnSizeGhost = pgrid%pconnSizeGhost + pborder%nVertSend + 2 
    END DO ! iBorder   

! ==============================================================================
!   Block 3: Vertices to recv
! ==============================================================================

    pgrid%pconnSizeTot   = pgrid%pconnSizeTot   + 1
    pgrid%pconnSizeGhost = pgrid%pconnSizeGhost + 1

    DO iborder = 1,pgrid%nBorders
      pborder => pgrid%borders(iborder)

      pgrid%pconnSizeTot   = pgrid%pconnSizeTot   + pborder%nVertRecv  + 2 
      pgrid%pconnSizeGhost = pgrid%pconnSizeGhost + pborder%nVertRecv  + 2 
    END DO ! iBorder 

! ==============================================================================
!   Block 4: Cells to send
! ==============================================================================

    pgrid%pconnSizeTot   = pgrid%pconnSizeTot   + 1
    pgrid%pconnSizeGhost = pgrid%pconnSizeGhost + 1

    DO iborder = 1,pgrid%nBorders
      pborder => pgrid%borders(iborder)

      pgrid%pconnSizeTot   = pgrid%pconnSizeTot   + pborder%nCellsSend + 2 
      pgrid%pconnSizeGhost = pgrid%pconnSizeGhost + pborder%nCellsSend + 2 
    END DO ! iBorder   

! ==============================================================================
!   Block 5: Cells to recv
! ==============================================================================

    pgrid%pconnSizeTot   = pgrid%pconnSizeTot   + 1
    pgrid%pconnSizeGhost = pgrid%pconnSizeGhost + 1

    DO iborder = 1,pgrid%nBorders
      pborder => pgrid%borders(iborder)

      pgrid%pconnSizeTot   = pgrid%pconnSizeTot   + pborder%nCellsRecv + 2 
      pgrid%pconnSizeGhost = pgrid%pconnSizeGhost + pborder%nCellsRecv + 2 
    END DO ! iBorder 

! ******************************************************************************
!   Allocate memory 
! ******************************************************************************  

    ALLOCATE(pgrid%pconn(pgrid%pconnSizeTot),stat=errorflag)
    global%error = errorflag
    IF ( global%error /= err_none ) THEN 
      CALL errorstop(global,err_allocate,__line__,'pGrid%pconn')
    END IF ! global%error

! ******************************************************************************
!   End
! ******************************************************************************

    IF ( global%myProcid == masterproc .AND. & 
         global%verbLevel >= verbose_high ) THEN 
      WRITE(stdout,'(A,1X,A)') solver_name,'Creating pconn done.'
    END IF ! global%verbLevel

    CALL deregisterfunction(global)
  
  END SUBROUTINE rflu_genx_createpconn








! ******************************************************************************
!
! Purpose: Create windows.
!
! Description: None.
!
! Input:
!   pRegion             Pointer to region
!   communicator        Communicator
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

  SUBROUTINE rflu_genx_createwindows(pRegion,communicator)
  
    IMPLICIT NONE

! ******************************************************************************
!   Declarations and definitions
! ******************************************************************************

! ==============================================================================  
!   Arguments 
! ==============================================================================  

    INTEGER, INTENT(IN), OPTIONAL :: communicator
    TYPE(t_region), POINTER :: pregion

! ==============================================================================  
!   Locals 
! ==============================================================================  
    
    TYPE(t_global), POINTER :: global
    
! ******************************************************************************
!   Start, set pointers
! ******************************************************************************
    
    global => pregion%global
    
    IF ( global%myProcid == masterproc .AND. & 
         global%verbLevel >= verbose_high ) THEN 
      WRITE(stdout,'(A,1X,A)') solver_name,'Creating windows...'
    END IF ! global%myProcid
    
! ******************************************************************************
!   Set names and create windows
! ******************************************************************************

    global%surfWinName = trim(global%winName)//'_surf'
    global%volWinName = trim(global%winName)//'_vol'

    IF ( global%myProcid == masterproc .AND. & 
         global%verbLevel >= verbose_high ) THEN 
      WRITE(stdout,'(A,3X,A,1X,A)') solver_name,'Surface window name:', & 
                                    trim(global%surfWinName)
      WRITE(stdout,'(A,3X,A,1X,A)') solver_name,'Volume window name:', & 
                                    trim(global%volWinName)                                    
    END IF ! global%myProcid
    
    IF ( present(communicator) ) THEN 
      CALL com_new_window(trim(global%surfWinName),communicator)
      CALL com_new_window(trim(global%volWinName),communicator)
    ELSE 
      CALL com_new_window(trim(global%surfWinName))
      CALL com_new_window(trim(global%volWinName))      
    END IF ! PRESENT

! ******************************************************************************
!   End
! ******************************************************************************
  
    IF ( global%myProcid == masterproc .AND. & 
         global%verbLevel >= verbose_high ) THEN 
      WRITE(stdout,'(A,1X,A)') solver_name,'Creating windows done.'
    END IF ! global%myProcid  
  
  END SUBROUTINE rflu_genx_createwindows  







! ******************************************************************************
!
! Purpose: Inform Roccom that window creation is done.
!
! Description: None.
!
! Input:
!   pRegion             Pointer to region
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

  SUBROUTINE rflu_genx_createwindowsdone(pRegion)
  
    IMPLICIT NONE

! ******************************************************************************
!   Declarations and definitions
! ******************************************************************************

! ==============================================================================  
!   Arguments 
! ==============================================================================  

    TYPE(t_region), POINTER :: pregion

! ==============================================================================  
!   Locals 
! ==============================================================================  
    
    TYPE(t_global), POINTER :: global
    
! ******************************************************************************
!   Start, set pointers
! ******************************************************************************
    
    global => pregion%global
    
! ******************************************************************************
!   Inform Roccom that window creation done
! ******************************************************************************

    global%surfWinName = trim(global%winName)//'_surf'
    CALL com_window_init_done(trim(global%surfWinName))

    global%volWinName = trim(global%winName)//'_vol'
    CALL com_window_init_done(trim(global%volWinName))

! ******************************************************************************
!   End
! ******************************************************************************
  
  END SUBROUTINE rflu_genx_createwindowsdone








! ******************************************************************************
!
! Purpose: Destroy interface data arrays.
!
! Description: None.
!
! Input:
!   pRegion             Pointer to region
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

  SUBROUTINE rflu_genx_destroydatainterf(pRegion)
  
    IMPLICIT NONE

! ******************************************************************************
!   Declarations and definitions
! ******************************************************************************

! ==============================================================================  
!   Arguments 
! ==============================================================================  

    TYPE(t_region), POINTER :: pregion
    
! ==============================================================================  
!   Locals 
! ==============================================================================  
    
    INTEGER :: errorflag,ipatch   
    TYPE(t_global), POINTER :: global
    TYPE(t_grid), POINTER :: pgrid
    TYPE(t_patch), POINTER :: ppatch
      
! ******************************************************************************
!   Start, set pointers
! ******************************************************************************
    
    global => pregion%global

    pgrid => pregion%grid 

    CALL registerfunction(global,'RFLU_GENX_DestroyDataInterf',&
  'RFLU_ModRocstarAdmin.F90')

! ******************************************************************************
!   Allocate memory 
! ******************************************************************************  
  
    DO ipatch = 1,pgrid%nPatches
      ppatch => pregion%patches(ipatch)
    
! ==============================================================================
!     Surface grid deformation
! ==============================================================================

      DEALLOCATE(ppatch%dXyz,stat=errorflag)
      global%error = errorflag
      IF ( global%error /= err_none ) THEN 
        CALL errorstop(global,err_deallocate,__line__,'pPatch%dXyz')
      END IF ! global%error      

! ==============================================================================
!     Input data
! ==============================================================================      
      
! ------------------------------------------------------------------------------
!     All patches       
! ------------------------------------------------------------------------------
      
      DEALLOCATE(ppatch%duAlp,stat=errorflag)
      global%error = errorflag
      IF ( global%error /= err_none ) THEN 
        CALL errorstop(global,err_deallocate,__line__,'pPatch%duAlp')
      END IF ! global

! ------------------------------------------------------------------------------
!     Interacting patches (burning or non-burning)       
! ------------------------------------------------------------------------------

      IF ( ppatch%bcCoupled /= bc_not_coupled ) THEN 
        DEALLOCATE(ppatch%rhofvfAlp,stat=errorflag)
        global%error = errorflag         
        IF ( global%error /= err_none ) THEN 
          CALL errorstop(global,err_deallocate,__line__,'pPatch%rhofvfAlp')
        END IF ! global
        
        DEALLOCATE(ppatch%tbAlp,stat=errorflag)
        global%error = errorflag         
        IF ( global%error /= err_none ) THEN 
          CALL errorstop(global,err_deallocate,__line__,'pPatch%tbfAlp')
        END IF ! global        
      END IF ! pPatch

! ------------------------------------------------------------------------------
!     Burning patches
! ------------------------------------------------------------------------------

      IF ( ppatch%bcCoupled == bc_burning ) THEN 
        DEALLOCATE(ppatch%mdotAlp,stat=errorflag)
        global%error = errorflag
        IF ( global%error /= err_none ) THEN 
          CALL errorstop(global,err_deallocate,__line__,'pPatch%mdotAlp')
        END IF ! global

        DEALLOCATE(ppatch%tflmAlp,stat=errorflag)
        global%error = errorflag
        IF ( global%error /= err_none ) THEN 
          CALL errorstop(global,err_deallocate,__line__,'pPatch%tflmAlp')
        END IF ! global
      END IF ! pPatch  
      
! ==============================================================================
!     Output data
! ==============================================================================      

! ------------------------------------------------------------------------------
!     Interacting patches (burning or non-burning)       
! ------------------------------------------------------------------------------

      IF ( ppatch%bcCoupled /= bc_not_coupled ) THEN 
        DEALLOCATE(ppatch%nfAlp,stat=errorflag)
        global%error = errorflag
        IF ( global%error /= err_none ) THEN 
          CALL errorstop(global,err_deallocate,__line__,'pPatch%nfAlp')
        END IF ! global             

        DEALLOCATE(ppatch%rhofAlp,stat=errorflag)
        global%error = errorflag
        IF ( global%error /= err_none ) THEN 
          CALL errorstop(global,err_deallocate,__line__,'pPatch%rhofAlp')
        END IF ! global                    

        DEALLOCATE(ppatch%pf,stat=errorflag)
        global%error = errorflag
        IF ( global%error /= err_none ) THEN 
          CALL errorstop(global,err_deallocate,__line__,'pPatch%pf')
        END IF ! global            

        DEALLOCATE(ppatch%tracf,stat=errorflag)
        global%error = errorflag
        IF ( global%error /= err_none ) THEN 
          CALL errorstop(global,err_deallocate,__line__,'pPatch%tracf')
        END IF ! global
        
        DEALLOCATE(ppatch%qc,stat=errorflag)
        global%error = errorflag
        IF ( global%error /= err_none ) THEN 
          CALL errorstop(global,err_deallocate,__line__,'pPatch%qc')
        END IF ! global             

        DEALLOCATE(ppatch%qr,stat=errorflag)
        global%error = errorflag
        IF ( global%error /= err_none ) THEN 
          CALL errorstop(global,err_deallocate,__line__,'pPatch%qr')
        END IF ! global             
      END IF ! pPatch%bcCoupled

! ------------------------------------------------------------------------------
!     Burning patches 
! ------------------------------------------------------------------------------

      IF ( ppatch%bcCoupled == bc_burning ) THEN     
        DEALLOCATE(ppatch%tempf,stat=errorflag)
        global%error = errorflag
        IF ( global%error /= err_none ) THEN 
          CALL errorstop(global,err_deallocate,__line__,'pPatch%tempf')
        END IF ! global
        
! TO BE REMOVED - Needs discussion    
        DEALLOCATE(ppatch%bFlag,stat=errorflag)
        global%error = errorflag
        IF ( global%error /= err_none ) THEN 
          CALL errorstop(global,err_deallocate,__line__,'pPatch%bFlag')
        END IF ! global          
! END TO BE REMOVED
      END IF ! pPatch%bcType
    END DO ! iPatch  
  
! ******************************************************************************
!   End
! ******************************************************************************

    CALL deregisterfunction(global)
  
  END SUBROUTINE rflu_genx_destroydatainterf








! ******************************************************************************
!
! Purpose: Destroy surface grid.
!
! Description: None.
!
! Input:
!   pRegion             Pointer to region
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

  SUBROUTINE rflu_genx_destroygridsurf(pRegion)
  
    USE rflu_modboundlists, ONLY: rflu_destroybfaceloclists  
  
    IMPLICIT NONE

! ******************************************************************************
!   Declarations and definitions
! ******************************************************************************

! ==============================================================================  
!   Arguments 
! ==============================================================================  

    TYPE(t_region), POINTER :: pregion

! ==============================================================================  
!   Locals 
! ==============================================================================  
    
    INTEGER :: errorflag,ipatch
    TYPE(t_global), POINTER :: global
    TYPE(t_grid), POINTER :: pgrid
    TYPE(t_patch), POINTER :: ppatch
    
! ******************************************************************************
!   Start, set pointers
! ******************************************************************************
    
    global => pregion%global
    
    pgrid => pregion%grid

    CALL registerfunction(global,'RFLU_GENX_DestroyGridSurf',&
  'RFLU_ModRocstarAdmin.F90')
    
! ******************************************************************************
!   Create locally-numbered boundary face lists
! ******************************************************************************

    CALL rflu_destroybfaceloclists(pregion)
  
! ******************************************************************************
!   Allocate memory 
! ******************************************************************************  

    DO ipatch=1,pgrid%nPatches
      ppatch => pregion%patches(ipatch)
     
      DEALLOCATE(ppatch%bcFlag,stat=errorflag)
      global%error = errorflag
      IF ( global%error /= err_none ) THEN 
        CALL errorstop(global,err_deallocate,__line__,'pPatch%bcFlag')
      END IF ! global
      
      DEALLOCATE(ppatch%patchNo,stat=errorflag)
      global%error = errorflag
      IF ( global%error /= err_none ) THEN 
        CALL errorstop(global,err_deallocate,__line__,'pPatch%patchNo')
      END IF ! global          
             
      DEALLOCATE(ppatch%cnstrType,stat=errorflag)
      global%error = errorflag
      IF ( global%error /= err_none ) THEN 
        CALL errorstop(global,err_deallocate,__line__,'pPatch%cnstrType')
      END IF ! global        
             
      DEALLOCATE(ppatch%xyz,stat=errorflag)
      global%error = errorflag
      IF ( global%error /= err_none ) THEN 
        CALL errorstop(global,err_deallocate,__line__,'pPatch%xyz')
      END IF ! global%error  
    END DO ! iPatch
  
! ******************************************************************************
!   End
! ******************************************************************************

    CALL deregisterfunction(global)
  
  END SUBROUTINE rflu_genx_destroygridsurf










! ******************************************************************************
!
! Purpose: Destroy pconn attribute.
!
! Description: None.
!
! Input:
!   pRegion             Pointer to region
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

  SUBROUTINE rflu_genx_destroypconn(pRegion)
    
    IMPLICIT NONE

! ******************************************************************************
!   Declarations and definitions
! ******************************************************************************

! ==============================================================================  
!   Arguments 
! ==============================================================================  

    TYPE(t_region), POINTER :: pregion

! ==============================================================================  
!   Locals 
! ==============================================================================  
    
    INTEGER :: errorflag
    TYPE(t_global), POINTER :: global
    TYPE(t_grid), POINTER :: pgrid
    
! ******************************************************************************
!   Start, set pointers
! ******************************************************************************
    
    global => pregion%global
    
    pgrid => pregion%grid

    CALL registerfunction(global,'RFLU_GENX_DestroyPConn',&
  'RFLU_ModRocstarAdmin.F90')     

    IF ( global%myProcid == masterproc .AND. & 
         global%verbLevel >= verbose_high ) THEN 
      WRITE(stdout,'(A,1X,A)') solver_name,'Destroying pconn...'
    END IF ! global%verbLevel

! ******************************************************************************
!   Deallocate memory 
! ******************************************************************************  

    DEALLOCATE(pgrid%pconn,stat=errorflag)
    global%error = errorflag
    IF ( global%error /= err_none ) THEN 
      CALL errorstop(global,err_deallocate,__line__,'pGrid%pconn')
    END IF ! global%error

! ******************************************************************************
!   End
! ******************************************************************************

    IF ( global%myProcid == masterproc .AND. & 
         global%verbLevel >= verbose_high ) THEN 
      WRITE(stdout,'(A,1X,A)') solver_name,'Destroying pconn done.'
    END IF ! global%verbLevel

    CALL deregisterfunction(global)
  
  END SUBROUTINE rflu_genx_destroypconn











! ******************************************************************************
!
! Purpose: Hard-code window name.
!
! Description: None.
!
! Input:
!   global              Pointer to global data
!
! Output: None.
!
! Notes: 
!   1. Routine is needed because some utilities are not called through Roccom.
!      This means that rocflu_load_module is not called in which the window name
!      is set. This window name must be set before the windows are created.
!   2. This routine MUST ONLY BE CALLED IF the parent code is not called through
!      Roccom. 
!
! ******************************************************************************

  SUBROUTINE rflu_genx_hardcodewindowname(global)
  
    IMPLICIT NONE

! ******************************************************************************
!   Declarations and definitions
! ******************************************************************************

! ==============================================================================  
!   Arguments 
! ==============================================================================  

    TYPE(t_global), POINTER :: global
        
! ******************************************************************************
!   Set names and register windows
! ******************************************************************************

    global%winName = 'ROCFLU'

! ******************************************************************************
!   End
! ******************************************************************************
  
  END SUBROUTINE rflu_genx_hardcodewindowname








! ******************************************************************************
!
! Purpose: Initialize Rocman.
!
! Description: None.
!
! Input:
!   pRegion             Pointer to region
!   handle              Handle
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

  SUBROUTINE rflu_genx_initrocman(pRegion,handle)
  
    IMPLICIT NONE

! ******************************************************************************
!   Declarations and definitions
! ******************************************************************************

! ==============================================================================  
!   Arguments 
! ==============================================================================  

    INTEGER, INTENT(IN) :: handle
    TYPE(t_region), POINTER :: pregion

! ==============================================================================  
!   Locals 
! ==============================================================================  
    
    INTEGER :: solvertype
    TYPE(t_global), POINTER :: global
    
! ******************************************************************************
!   Start, set pointers
! ******************************************************************************
    
    global => pregion%global

    IF ( global%myProcid == masterproc .AND. &
         global%verbLevel >= verbose_high ) THEN 
      WRITE(stdout,'(A,1X,A)') solver_name,'Initializing Rocman...'
    END IF ! global%verbLevel
    
! ******************************************************************************
!   Initialize Rocman
! ******************************************************************************

    IF ( pregion%mixtInput%flowModel == flow_navst ) THEN 
      solvertype = 1
    ELSE  
      solvertype = 0
    END IF ! pRegion       

    CALL com_call_function(handle,3,trim(global%surfWinName), & 
                           trim(global%volWinName),solvertype)
   
! ******************************************************************************
!   End
! ******************************************************************************

    IF ( global%myProcid == masterproc .AND. &
         global%verbLevel >= verbose_high ) THEN 
      WRITE(stdout,'(A,1X,A)') solver_name,'Initializing Rocman done.'
    END IF ! global%verbLevel 
  
  END SUBROUTINE rflu_genx_initrocman








! ******************************************************************************
!
! Purpose: Read Rocflu control file for GENX runs.
!
! Description: None.
!
! Input:
!   global      global type
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

  SUBROUTINE rflu_genx_readctrlfile(global)

    IMPLICIT NONE

! ******************************************************************************
!   Definitions and declarations
! ******************************************************************************

! ==============================================================================
!   Arguments
! ==============================================================================

    TYPE(t_global), POINTER :: global

! ==============================================================================
!   Locals
! ==============================================================================

    CHARACTER(CHRLEN) :: ifilename
    INTEGER :: errorflag,verblevelcom

! ******************************************************************************
!   Start
! ******************************************************************************

    CALL registerfunction(global,'RFLU_GENX_ReadCtrlFile',&
  'RFLU_ModRocstarAdmin.F90')

! ==============================================================================
!   Open file
! ==============================================================================

    ifilename = './Rocflu/RocfluControl.txt'

    OPEN(if_control,file=ifilename,form='FORMATTED',status='OLD', & 
         iostat=errorflag)
    global%error = errorflag
    IF ( global%error /= err_none ) THEN
      CALL errorstop(global,err_file_open,__line__,'File: '//trim(ifilename))
    END IF ! global%error

! ==============================================================================
!   Read file
! ==============================================================================

! ------------------------------------------------------------------------------
!   Case name
! ------------------------------------------------------------------------------

    READ(if_control,'(A)',iostat=errorflag) global%casename
    global%error = errorflag
    IF ( global%error /= err_none ) THEN
      CALL errorstop( global,err_file_read,__line__,'File: '//trim(ifilename) )
    END IF ! global%error

! ------------------------------------------------------------------------------
!   Input and output directories
! ------------------------------------------------------------------------------

    READ(if_control,'(A)',iostat=errorflag) global%inDir
    global%error = errorflag
    IF ( global%error /= err_none ) THEN
      global%inDir = './'
    ELSE
      IF ( global%inDir(len_trim(global%inDir): & 
                        len_trim(global%inDir)) /= '/' ) THEN
        global%inDir = trim(global%inDir)//'/'
      END IF ! global%inDir
    END IF ! global%error

    READ(if_control,'(A)',iostat=errorflag) global%outDir
    global%error = errorflag
    IF ( global%error /= err_none ) THEN
      global%outDir = './'
    ELSE
      IF ( global%outDir(len_trim(global%outDir): & 
                         len_trim(global%outDir)) /=  '/' ) THEN
        global%outDir = trim(global%outDir)//'/'
      END IF ! global%outDir
    END IF ! global%error

    READ(if_control,'(A)',iostat=errorflag) global%outDirHDF
    global%error = errorflag
    IF ( global%error /= err_none ) THEN
      global%outDirHDF = './'
    ELSE
      IF ( global%outDirHDF(len_trim(global%outDirHDF): & 
                            len_trim(global%outDirHDF)) /=  '/' ) THEN
        global%outDirHDF = trim(global%outDirHDF)//'/'
      END IF ! global%outDirHDF
    END IF ! global%error

! ------------------------------------------------------------------------------
!   Verbosity and checking levels. NOTE do not report error if Roccom verbosity
!   level does not exist for backward compatibility. NOTE cannot write warning
!   if Roccom verbosity level does not exit because global%myProcid is not set 
!   yet.
! ------------------------------------------------------------------------------

    READ(if_control,*,iostat=errorflag) global%verbLevel
    global%error = errorflag
    IF ( global%error /= err_none ) THEN
      global%verbLevel = verbose_high
    ELSE
      global%verbLevel = max(global%verbLevel,verbose_none)
      global%verbLevel = min(global%verbLevel,verbose_high)
    END IF ! global%error

    READ(if_control,*,iostat=errorflag) global%checkLevel
    global%error = errorflag
    IF ( global%error /= err_none ) THEN
      global%checkLevel = check_high
    ELSE
      global%checkLevel = max(global%checkLevel,check_none)
      global%checkLevel = min(global%checkLevel,check_high)
    END IF ! global%error

    READ(if_control,*,iostat=errorflag) verblevelcom
    IF ( errorflag == err_none ) THEN
      global%verbLevelCOM = verblevelcom
    END IF ! global%error

! ==============================================================================
!   Close file
! ==============================================================================

    CLOSE(if_control,iostat=errorflag)
    global%error = errorflag
    IF ( global%error /= err_none ) THEN
      CALL errorstop(global,err_file_close,__line__,'File: '//trim(ifilename))
    END IF ! global%error

! ******************************************************************************
!   End
! ******************************************************************************

    CALL deregisterfunction(global)

  END SUBROUTINE rflu_genx_readctrlfile
 






! ******************************************************************************
!
! Purpose: Register flow data.
!
! Description: None.
!
! Input:
!   pRegion             Pointer to region
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

  SUBROUTINE rflu_genx_registerdataflow(pRegion)
  
    USE modmixture, ONLY: t_mixt_input
  
    IMPLICIT NONE

! ******************************************************************************
!   Declarations and definitions
! ******************************************************************************

! ==============================================================================  
!   Arguments 
! ==============================================================================  

    TYPE(t_region), POINTER :: pregion

! ==============================================================================  
!   Locals 
! ==============================================================================  
    
    CHARACTER(CHRLEN) :: winname
    INTEGER :: paneid,sz,ng
    REAL(RFREAL), POINTER :: preal    
    TYPE(t_global), POINTER :: global
    TYPE(t_grid), POINTER :: pgrid
    TYPE(t_mixt_input), POINTER :: pmixtinput
    
! ******************************************************************************
!   Start, set pointers
! ******************************************************************************
    
    global => pregion%global

    pgrid      => pregion%grid
    pmixtinput => pregion%mixtInput    

    IF ( global%myProcid == masterproc .AND. &
         global%verbLevel >= verbose_high ) THEN 
      WRITE(stdout,'(A,1X,A)') solver_name,'Registering flow data...'
    END IF ! global%verbLevel
    
! ******************************************************************************
!   Register data
! ******************************************************************************

! ==============================================================================  
!   Volume
! ==============================================================================  

    winname = global%volWinName       

    CALL rflu_genx_buildpaneid(pregion%iRegionGlobal,0,paneid) 

    IF ( global%myProcid == masterproc .AND. &
         global%verbLevel >= verbose_high ) THEN 
      WRITE(stdout,'(A,3X,A,1X,A)') solver_name,'Window name:',trim(winname)
      WRITE(stdout,'(A,3X,A,1X,I5.5)') solver_name,'Pane id:', paneid           
    END IF ! global%verbLevel
   
! ------------------------------------------------------------------------------
!   Conserved variables
! ------------------------------------------------------------------------------   
   
    preal => pregion%mixt%cv(cv_mixt_dens,1)
  
    CALL com_set_array(trim(winname)//'.rhof',paneid,preal,pmixtinput%nCv, &
                       pgrid%nCellsTot)

 
    preal => pregion%mixt%cv(cv_mixt_xmom,1)
   
    CALL com_set_array(trim(winname)//'.rhovf',paneid,preal,pmixtinput%nCv, &
                       pgrid%nCellsTot)
 
    preal => pregion%mixt%cv(cv_mixt_ener,1)
   
    CALL com_set_array(trim(winname)//'.rhoEf',paneid,preal,pmixtinput%nCv, &
                       pgrid%nCellsTot)                       

! ------------------------------------------------------------------------------
!   Dependent variables
! ------------------------------------------------------------------------------   
   
    preal => pregion%mixt%dv(dv_mixt_pres,1)
   
    CALL com_set_array(trim(winname)//'.pf',paneid,preal,pmixtinput%nDv, &
                       pgrid%nCellsTot)
 
    preal => pregion%mixt%dv(dv_mixt_temp,1)
   
    CALL com_set_array(trim(winname)//'.Tf',paneid,preal,pmixtinput%nDv, &
                       pgrid%nCellsTot)

    preal => pregion%mixt%dv(dv_mixt_soun,1)
   
    CALL com_set_array(trim(winname)//'.af',paneid,preal,pmixtinput%nDv, &
                       pgrid%nCellsTot)
   
! ******************************************************************************
!   End
! ******************************************************************************

    IF ( global%myProcid == masterproc .AND. &
         global%verbLevel >= verbose_high ) THEN 
      WRITE(stdout,'(A,1X,A)') solver_name,'Registering flow data done.'
    END IF ! global%verbLevel 
    
    CALL com_get_size(trim(winname)//'.rhof',paneid,sz,ng)
  
  END SUBROUTINE rflu_genx_registerdataflow







! ******************************************************************************
!
! Purpose: Register grid speeds.
!
! Description: None.
!
! Input:
!   pRegion             Pointer to region
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

  SUBROUTINE rflu_genx_registerdatagspeeds(pRegion)
  
    IMPLICIT NONE

! ******************************************************************************
!   Declarations and definitions
! ******************************************************************************

! ==============================================================================  
!   Arguments 
! ==============================================================================  

    TYPE(t_region), POINTER :: pregion

! ==============================================================================  
!   Locals 
! ==============================================================================  
    
    CHARACTER(CHRLEN) :: winname
    INTEGER :: ipatch,paneid
    REAL(RFREAL), POINTER :: preal    
    TYPE(t_global), POINTER :: global
    TYPE(t_grid), POINTER :: pgrid
    TYPE(t_patch), POINTER :: ppatch
    
! ******************************************************************************
!   Start, set pointers
! ******************************************************************************
    
    global => pregion%global

    pgrid => pregion%grid

    IF ( global%myProcid == masterproc .AND. &
         global%verbLevel >= verbose_high ) THEN 
      WRITE(stdout,'(A,1X,A)') solver_name,'Registering grid speeds...'
    END IF ! global%verbLevel
        
! ******************************************************************************
!   Register data
! ******************************************************************************

! ==============================================================================  
!   Volume
! ==============================================================================  

    winname = global%volWinName       

    CALL rflu_genx_buildpaneid(pregion%iRegionGlobal,0,paneid) 

    IF ( global%myProcid == masterproc .AND. &
         global%verbLevel >= verbose_high ) THEN 
      WRITE(stdout,'(A,3X,A)') solver_name,'Volume data...'
      WRITE(stdout,'(A,5X,A,1X,A)') solver_name,'Window name:',trim(winname)
      WRITE(stdout,'(A,5X,A,1X,I5.5)') solver_name,'Pane id:', paneid           
    END IF ! global%verbLevel
   
    preal => pgrid%gs(1)

    CALL com_set_size(trim(winname)//'.gs',paneid,pgrid%nFacesTot,0)
    CALL com_set_array(trim(winname)//'.gs',paneid,preal,1,pgrid%nFacesTot)

! ==============================================================================  
!   Surface
! ==============================================================================  

    winname = global%surfWinName

    IF ( global%myProcid == masterproc .AND. &
         global%verbLevel >= verbose_high ) THEN 
      WRITE(stdout,'(A,3X,A)') solver_name,'Surface data...'
      WRITE(stdout,'(A,5X,A,1X,A)') solver_name,'Window name:',trim(winname)   
    END IF ! global%verbLevel
        
    DO ipatch = 1,pgrid%nPatches
      ppatch => pregion%patches(ipatch)
      
      CALL rflu_genx_buildpaneid(pregion%iRegionGlobal,ipatch,paneid) 

      IF ( global%myProcid == masterproc .AND. &
           global%verbLevel >= verbose_high ) THEN 
        WRITE(stdout,'(A,5X,A,1X,I2)')   solver_name,'Patch:',ipatch
        WRITE(stdout,'(A,7X,A,1X,I5.5)') solver_name,'Pane id:', paneid      
      END IF ! global%verbLevel
      
      preal => ppatch%gs(1)
            
      CALL com_set_array(trim(winname)//'.gs',paneid,preal,1,ppatch%nBFacesTot)
    END DO ! iPatch    
   
! ******************************************************************************
!   End
! ******************************************************************************
 
    IF ( global%myProcid == masterproc .AND. &
         global%verbLevel >= verbose_high ) THEN 
      WRITE(stdout,'(A,1X,A)') solver_name,'Registering grid speeds done.'
    END IF ! global%verbLevel 
  
  END SUBROUTINE rflu_genx_registerdatagspeeds







! ******************************************************************************
!
! Purpose: Register interface data.
!
! Description: None.
!
! Input:
!   pRegion             Pointer to region
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

  SUBROUTINE rflu_genx_registerdatainterf(pRegion)
  
    IMPLICIT NONE

! ******************************************************************************
!   Declarations and definitions
! ******************************************************************************

! ==============================================================================  
!   Arguments 
! ==============================================================================  

    TYPE(t_region), POINTER :: pregion

! ==============================================================================  
!   Locals 
! ==============================================================================  
    
    CHARACTER(CHRLEN) :: winname
    INTEGER :: ipatch,paneid
    REAL(RFREAL), POINTER :: preal    
    TYPE(t_global), POINTER :: global
    TYPE(t_grid), POINTER :: pgrid
    TYPE(t_patch), POINTER :: ppatch
    
! ******************************************************************************
!   Start, set pointers
! ******************************************************************************
    
    global => pregion%global

    pgrid => pregion%grid

    IF ( global%myProcid == masterproc .AND. &
         global%verbLevel >= verbose_high ) THEN 
      WRITE(stdout,'(A,1X,A)') solver_name,'Registering interface data...'
    END IF ! global%verbLevel
    
! ******************************************************************************
!   Register interface data
! ******************************************************************************

    winname = global%surfWinName

    IF ( global%myProcid == masterproc .AND. &
         global%verbLevel >= verbose_high) THEN 
      WRITE(stdout,'(A,3X,A,1X,A)') solver_name,'Window name:',trim(winname)   
    END IF ! global%verbLevel
        
    DO ipatch = 1,pgrid%nPatches
      ppatch => pregion%patches(ipatch)
      
      CALL rflu_genx_buildpaneid(pregion%iRegionGlobal,ipatch,paneid) 

      IF ( global%myProcid == masterproc .AND. &
           global%verbLevel >= verbose_high ) THEN 
        WRITE(stdout,'(A,3X,A,1X,I2)')   solver_name,'Patch:',ipatch
        WRITE(stdout,'(A,5X,A,1X,I5.5)') solver_name,'Pane id:',paneid      
      END IF ! global%verbLevel
      
! ==============================================================================  
!     Input data
! ==============================================================================  

! ------------------------------------------------------------------------------
!     All patches
! ------------------------------------------------------------------------------
      
      CALL com_set_array(trim(winname)//'.du_alp',paneid,ppatch%duAlp)

! ------------------------------------------------------------------------------
!     Interacting patches (burning or non-burning)      
! ------------------------------------------------------------------------------

      IF ( ppatch%bcCoupled /= bc_not_coupled ) THEN 
        CALL com_set_array(trim(winname)//'.rhofvf_alp',paneid,ppatch%rhofvfAlp)
        CALL com_set_array(trim(winname)//'.Tb_alp',paneid,ppatch%tbAlp)
      END IF ! pPatch%bcCoupled

! ------------------------------------------------------------------------------
!     Burning patches 
! ------------------------------------------------------------------------------

      IF ( ppatch%bcCoupled == bc_burning ) THEN  
        CALL com_set_array(trim(winname)//'.mdot_alp',paneid,ppatch%mdotAlp)        
        CALL com_set_array(trim(winname)//'.Tflm_alp',paneid,ppatch%tflmAlp)
      END IF ! pPatch%bcCoupled

! ==============================================================================  
!     Output data
! ==============================================================================  

! ------------------------------------------------------------------------------
!     Interacting patches (burning or non-burning)      
! ------------------------------------------------------------------------------

      IF ( ppatch%bcCoupled /= bc_not_coupled ) THEN         
        CALL com_set_array(trim(winname)//'.nf_alp',paneid,ppatch%nfAlp)        
        CALL com_set_array(trim(winname)//'.rhof_alp',paneid,ppatch%rhofAlp)        
        CALL com_set_array(trim(winname)//'.pf',paneid,ppatch%pf)
        CALL com_set_array(trim(winname)//'.tf',paneid,ppatch%tracf)
        CALL com_set_array(trim(winname)//'.qc',paneid,ppatch%qc)
        CALL com_set_array(trim(winname)//'.qr',paneid,ppatch%qr)        
      END IF ! pPatch%bcCoupled

! ------------------------------------------------------------------------------
!     Burning patches 
! ------------------------------------------------------------------------------

      IF ( ppatch%bcCoupled == bc_burning ) THEN         
        CALL com_set_array(trim(winname)//'.Tf',paneid,ppatch%tempf)    
        CALL com_set_array(trim(winname)//'.bflag',paneid,ppatch%bFlag)        
      END IF ! pPatch%bcCoupled                  
    END DO ! iPatch    
   
! ******************************************************************************
!   End
! ******************************************************************************

    IF ( global%myProcid == masterproc .AND. &
         global%verbLevel >= verbose_high ) THEN 
      WRITE(stdout,'(A,1X,A)') solver_name,'Registering interface data done.'
    END IF ! global%verbLevel
  
  END SUBROUTINE rflu_genx_registerdatainterf






  
! ******************************************************************************
!
! Purpose: Statistics data registration.
!
! Description: None.
!
! Input:
!   pRegion             Pointer to region
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

  SUBROUTINE rflu_genx_registerdatastats(pRegion)
#ifdef STATS  
    USE stat_rflu_modrocstaradmin, ONLY: stat_rflu_genxregisterdata
#endif
    IMPLICIT NONE

! ******************************************************************************
!   Declarations and definitions
! ******************************************************************************

! ==============================================================================  
!   Arguments 
! ==============================================================================  

    TYPE(t_region), POINTER :: pregion
    
! ******************************************************************************
!   Register data
! ******************************************************************************
#ifdef STATS
    CALL stat_rflu_genxregisterdata(pregion)
#endif  
! ******************************************************************************
!   End
! ******************************************************************************
  
  END SUBROUTINE rflu_genx_registerdatastats






  
! ******************************************************************************
!
! Purpose: Turbulence data registration.
!
! Description: None.
!
! Input:
!   pRegion             Pointer to region
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

  SUBROUTINE rflu_genx_registerdataturb(pRegion)
#ifdef TURB  
    USE turb_rflu_modrocstaradmin, ONLY: turb_rflu_genxregisterdata
#endif
    IMPLICIT NONE

! ******************************************************************************
!   Declarations and definitions
! ******************************************************************************

! ==============================================================================  
!   Arguments 
! ==============================================================================  

    TYPE(t_region), POINTER :: pregion
    
! ******************************************************************************
!   Register data
! ******************************************************************************
#ifdef TURB
    IF (pregion%global%turbActive) CALL turb_rflu_genxregisterdata(pregion)
#endif
! ******************************************************************************
!   End
! ******************************************************************************
  
  END SUBROUTINE rflu_genx_registerdataturb






  
! ******************************************************************************
!
! Purpose: Wrapper for data registration routines.
!
! Description: None.
!
! Input:
!   pRegion             Pointer to region
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

  SUBROUTINE rflu_genx_registerdatawrapper(pRegion)
  
    IMPLICIT NONE

! ******************************************************************************
!   Declarations and definitions
! ******************************************************************************

! ==============================================================================  
!   Arguments 
! ==============================================================================  

    TYPE(t_region), POINTER :: pregion
    
! ******************************************************************************
!   Register data
! ******************************************************************************

! ==============================================================================  
!   Mixture
! ==============================================================================  

    CALL rflu_genx_registerdataflow(pregion)
    CALL rflu_genx_registerdatagspeeds(pregion) 
    CALL rflu_genx_registerdatainterf(pregion)
    CALL rflu_genx_registerdisp(pregion)  

! ==============================================================================  
!   Statistics
! ==============================================================================  

    CALL rflu_genx_registerdatastats(pregion)

! ==============================================================================  
!   Turbulence
! ==============================================================================  

    CALL rflu_genx_registerdataturb(pregion)
  
! ******************************************************************************
!   End
! ******************************************************************************
  
  END SUBROUTINE rflu_genx_registerdatawrapper






! ******************************************************************************
!
! Purpose: Register volume grid.
!
! Description: None.
!
! Input:
!   pRegion             Pointer to region
!
! Output: None.
!
! Notes: 
!    1. Must be called after new attributes were created.
!
! ******************************************************************************

  SUBROUTINE rflu_genx_registerdisp(pRegion)
  
    IMPLICIT NONE

! ******************************************************************************
!   Declarations and definitions
! ******************************************************************************

! ==============================================================================  
!   Arguments 
! ==============================================================================  

    TYPE(t_region), POINTER :: pregion

! ==============================================================================  
!   Locals 
! ==============================================================================  
    
    CHARACTER(CHRLEN) :: winname
    INTEGER :: paneid  
    TYPE(t_global), POINTER :: global
    TYPE(t_grid), POINTER :: pgrid
    
! ******************************************************************************
!   Start, set pointers
! ******************************************************************************
    
    global => pregion%global

    pgrid => pregion%grid

    IF ( global%myProcid == masterproc .AND. &
         global%verbLevel >= verbose_high) THEN 
      WRITE(stdout,'(A,1X,A)') solver_name,'Registering displacements...'
    END IF ! global%verbLevel
    
! ******************************************************************************
!   Register displacements
! ******************************************************************************

    winname = global%volWinName
    
    CALL rflu_genx_buildpaneid(pregion%iRegionGlobal,0,paneid) 

    IF ( global%myProcid == masterproc .AND. &
         global%verbLevel >= verbose_high ) THEN         
      WRITE(stdout,'(A,3X,A,1X,A)') solver_name,'Window name:',trim(winname)
      WRITE(stdout,'(A,3X,A,1X,I5.5)') solver_name,'Pane id:',paneid   
    END IF ! global%verbLevel

    CALL com_set_array(trim(winname)//'.disp',paneid,pgrid%disp)
   
! ******************************************************************************
!   End
! ******************************************************************************

    IF ( global%myProcid == masterproc .AND. &
         global%verbLevel >= verbose_high ) THEN 
      WRITE(stdout,'(A,1X,A)') solver_name,'Registering displacements done.'
    END IF ! global%verbLevel
  
  END SUBROUTINE rflu_genx_registerdisp








! ******************************************************************************
!
! Purpose: Register grid.
!
! Description: None.
!
! Input:
!   pRegion             Pointer to region
!
! Output: None.
!
! Notes: 
!    1. Must be called after new attributes were created.
!
! ******************************************************************************

  SUBROUTINE rflu_genx_registergrid(pRegion)
  
    IMPLICIT NONE

! ******************************************************************************
!   Declarations and definitions
! ******************************************************************************

! ==============================================================================  
!   Arguments 
! ==============================================================================  

    TYPE(t_region), POINTER :: pregion

! ==============================================================================  
!   Locals 
! ==============================================================================  
     
    TYPE(t_global), POINTER :: global
    TYPE(t_grid), POINTER :: pgrid
    
! ******************************************************************************
!   Start, set pointers
! ******************************************************************************
    
    global => pregion%global

    pgrid => pregion%grid

    IF ( global%myProcid == masterproc .AND. &
         global%verbLevel >= verbose_high ) THEN 
      WRITE(stdout,'(A,1X,A)') solver_name,'Registering grid...'
    END IF ! global%verbLevel
    
! ******************************************************************************
!   Register grid
! ******************************************************************************

! ==============================================================================  
!   Volume
! ==============================================================================  

    CALL rflu_genx_registergridvol(pregion)
   
! ==============================================================================  
!   Surface 
! ==============================================================================  
    
    IF ( pgrid%nPatches > 0 ) THEN 
      CALL rflu_genx_registergridsurf(pregion)
    END IF ! pGrid%nPatches

! ******************************************************************************
!   End
! ******************************************************************************

    IF ( global%myProcid == masterproc .AND. &
         global%verbLevel >= verbose_high ) THEN 
      WRITE(stdout,'(A,1X,A)') solver_name,'Registering grid done.'
    END IF ! global%verbLevel
  
  END SUBROUTINE rflu_genx_registergrid  








! ******************************************************************************
!
! Purpose: Register surface grid.
!
! Description: None.
!
! Input:
!   pRegion             Pointer to region
!
! Output: None.
!
! Notes: 
!    1. Must be called after new attributes were created.
!
! ******************************************************************************

  SUBROUTINE rflu_genx_registergridsurf(pRegion)
  
    IMPLICIT NONE

! ******************************************************************************
!   Declarations and definitions
! ******************************************************************************

! ==============================================================================  
!   Arguments 
! ==============================================================================  

    TYPE(t_region), POINTER :: pregion

! ==============================================================================  
!   Locals 
! ==============================================================================  
    
    CHARACTER(CHRLEN) :: winname
    INTEGER :: ipatch,paneid
    INTEGER, POINTER :: pint    
    TYPE(t_global), POINTER :: global
    TYPE(t_grid), POINTER :: pgrid
    TYPE(t_patch), POINTER :: ppatch
    
! ******************************************************************************
!   Start, set pointers
! ******************************************************************************
    
    global => pregion%global

    pgrid => pregion%grid

    IF ( global%myProcid == masterproc .AND. &
         global%verbLevel >= verbose_high ) THEN 
      WRITE(stdout,'(A,1X,A)') solver_name,'Registering surface grid...'
    END IF ! global%verbLevel
    
! ******************************************************************************
!   Register surface grid
! ******************************************************************************
       
    winname = global%surfWinName

    IF ( global%myProcid == masterproc .AND. &
         global%verbLevel >= verbose_high ) THEN 
      WRITE(stdout,'(A,3X,A,1X,A)') solver_name,'Window name:',trim(winname)   
    END IF ! global%verbLevel
   
! ==============================================================================  
!   Loop over patches 
! ==============================================================================  
 
    DO ipatch = 1,pgrid%nPatches
      ppatch => pregion%patches(ipatch)
      
      CALL rflu_genx_buildpaneid(pregion%iRegionGlobal,ipatch,paneid) 

      IF ( global%myProcid == masterproc .AND. &
           global%verbLevel >= verbose_high ) THEN 
        WRITE(stdout,'(A,3X,A,1X,I2)')   solver_name,'Patch:',ipatch
        WRITE(stdout,'(A,5X,A,1X,I2)')   solver_name,'Global patch id:', & 
                                         ppatch%iPatchGlobal
        WRITE(stdout,'(A,5X,A,1X,I5.5)') solver_name,'Pane id:', paneid      
        WRITE(stdout,'(A,5X,A,1X,2X,I3)') solver_name,'bcFlag:   ', & 
                                          ppatch%bcFlag(1)
        WRITE(stdout,'(A,5X,A,1X,2X,I4)') solver_name,'cnstrType:', & 
                                          ppatch%cnstrType(1)   
      END IF ! global%verbLevel

! ------------------------------------------------------------------------------
!     Patch quantities
! ------------------------------------------------------------------------------  

      CALL com_set_size(trim(winname)//'.bcflag',paneid,1)
      CALL com_set_array(trim(winname)//'.bcflag',paneid,ppatch%bcFlag)

      CALL com_set_size(trim(winname)//'.patchNo',paneid,1)
      CALL com_set_array(trim(winname)//'.patchNo',paneid,ppatch%patchNo)

      CALL com_set_size(trim(winname)//'.cnstr_type',paneid,1)
      CALL com_set_array(trim(winname)//'.cnstr_type',paneid,ppatch%cnstrType)

! ------------------------------------------------------------------------------
!     Coordinates
! ------------------------------------------------------------------------------  

      CALL com_set_size(trim(winname)//'.nc',paneid,ppatch%nBVertTot, &
                        ppatch%nBVertTot-ppatch%nBVert)
      CALL com_set_array(trim(winname)//'.nc',paneid,ppatch%xyz)
      
! ------------------------------------------------------------------------------
!     Connectivity. IMPORTANT: Note that locally-numbered boundary-face lists 
!     are registered as connectivity. Globally-numbered boundary-face lists are
!     registered as additional data because they are needed for the basic 
!     grid description. 
! ------------------------------------------------------------------------------  

! --- Actual faces -------------------------------------------------------------

      IF ( ppatch%nBTris > 0 ) THEN 
        pint => ppatch%bTri2vLoc(1,1)

        CALL com_set_size(trim(winname)//'.:t3:real',paneid,ppatch%nBTris,0)
        CALL com_set_array(trim(winname)//'.:t3:real',paneid,pint) 
        
        pint => ppatch%bTri2v(1,1)

        CALL com_set_size(trim(winname)//'.t3g:real',paneid,ppatch%nBTris,0)
        CALL com_set_array(trim(winname)//'.t3g:real',paneid,pint)                                    
      END IF ! pPatch%nBTris

      IF ( ppatch%nBQuads > 0 ) THEN 
        pint => ppatch%bQuad2vLoc(1,1)

        CALL com_set_size(trim(winname)//'.:q4:real',paneid,ppatch%nBQuads,0)
        CALL com_set_array(trim(winname)//'.:q4:real',paneid,pint)                             

        pint => ppatch%bQuad2v(1,1)

        CALL com_set_size(trim(winname)//'.q4g:real',paneid,ppatch%nBQuads,0)
        CALL com_set_array(trim(winname)//'.q4g:real',paneid,pint)                             
      END IF ! pPatch%nBTris      
      
! --- Virtual faces ------------------------------------------------------------

      IF ( ppatch%nBTrisTot > ppatch%nBTris ) THEN 
        pint => ppatch%bTri2vLoc(1,ppatch%nBTris+1)

        CALL com_set_size(trim(winname)//'.:t3:virtual',paneid, & 
                          ppatch%nBTrisTot-ppatch%nBTris, &
                          ppatch%nBTrisTot-ppatch%nBTris)
        CALL com_set_array(trim(winname)//'.:t3:virtual',paneid,pint)
        
        pint => ppatch%bTri2v(1,ppatch%nBTris+1)

        CALL com_set_size(trim(winname)//'.t3g:virtual',paneid, & 
                          ppatch%nBTrisTot-ppatch%nBTris, &
                          ppatch%nBTrisTot-ppatch%nBTris)
        CALL com_set_array(trim(winname)//'.t3g:virtual',paneid,pint)                                     
      END IF ! pPatch%nBTris

      IF ( ppatch%nBQuadsTot > ppatch%nBQuads ) THEN 
        pint => ppatch%bQuad2vLoc(1,ppatch%nBQuads+1)

        CALL com_set_size(trim(winname)//'.:q4:virtual',paneid, &
                          ppatch%nBQuadsTot-ppatch%nBQuads, &
                          ppatch%nBQuadsTot-ppatch%nBQuads)
        CALL com_set_array(trim(winname)//'.:q4:virtual',paneid,pint) 
        
        pint => ppatch%bQuad2v(1,ppatch%nBQuads+1)

        CALL com_set_size(trim(winname)//'.q4g:virtual',paneid, &
                          ppatch%nBQuadsTot-ppatch%nBQuads, &
                          ppatch%nBQuadsTot-ppatch%nBQuads)
        CALL com_set_array(trim(winname)//'.q4g:virtual',paneid,pint)                                    
      END IF ! pPatch%nBQuads      
    END DO ! iPatch

! ******************************************************************************
!   End
! ******************************************************************************

    IF ( global%myProcid == masterproc .AND. &
         global%verbLevel >= verbose_high ) THEN 
      WRITE(stdout,'(A,1X,A)') solver_name,'Registering surface grid done.'
    END IF ! global%verbLevel
  
  END SUBROUTINE rflu_genx_registergridsurf
  
  
  
  



! ******************************************************************************
!
! Purpose: Register volume grid.
!
! Description: None.
!
! Input:
!   pRegion             Pointer to region
!
! Output: None.
!
! Notes: 
!    1. Must be called after new attributes were created.
!
! ******************************************************************************

  SUBROUTINE rflu_genx_registergridvol(pRegion)
  
    IMPLICIT NONE

! ******************************************************************************
!   Declarations and definitions
! ******************************************************************************

! ==============================================================================  
!   Arguments 
! ==============================================================================  

    TYPE(t_region), POINTER :: pregion

! ==============================================================================  
!   Locals 
! ==============================================================================  
    
    CHARACTER(CHRLEN) :: winname
    INTEGER :: paneid
    INTEGER, POINTER :: pint    
    TYPE(t_global), POINTER :: global
    TYPE(t_grid), POINTER :: pgrid
    
! ******************************************************************************
!   Start, set pointers
! ******************************************************************************
    
    global => pregion%global

    pgrid => pregion%grid

    IF ( global%myProcid == masterproc .AND. &
         global%verbLevel >= verbose_high ) THEN 
      WRITE(stdout,'(A,1X,A)') solver_name,'Registering volume grid...'
    END IF ! global%verbLevel
    
! ******************************************************************************
!   Register grid
! ******************************************************************************

    winname = global%volWinName
    
    CALL rflu_genx_buildpaneid(pregion%iRegionGlobal,0,paneid) 

    IF ( global%myProcid == masterproc .AND. &
         global%verbLevel >= verbose_high ) THEN         
      WRITE(stdout,'(A,3X,A,1X,A)') solver_name,'Window name:',trim(winname)
      WRITE(stdout,'(A,3X,A,1X,I5.5)') solver_name,'Pane id:',paneid   
    END IF ! global%verbLevel

! ==============================================================================  
!   Coordinates
! ==============================================================================  

    CALL com_set_size(trim(winname)//'.nc',paneid,pgrid%nVertTot, &
                      pgrid%nVertTot-pgrid%nVert)
    CALL com_set_array(trim(winname)//'.nc',paneid,pgrid%xyz)

! ==============================================================================  
!   Connectivity
! ==============================================================================  

! ------------------------------------------------------------------------------
!   pconn attribute
! ------------------------------------------------------------------------------

    CALL com_set_size(trim(winname)//'.pconn',paneid,pgrid%pconnSizeTot, &
                      pgrid%pconnSizeGhost)
    CALL com_set_array(trim(winname)//'.pconn',paneid,pgrid%pconn)    

! ------------------------------------------------------------------------------
!   Actual cells
! ------------------------------------------------------------------------------

    IF ( pgrid%nTets > 0 ) THEN 
      pint => pgrid%tet2v(1,1)

      CALL com_set_size(trim(winname)//'.:T4:real',paneid,pgrid%nTets,0)
      CALL com_set_array(trim(winname)//'.:T4:real',paneid,pint)  
    END IF ! pGrid%nTets 

    IF ( pgrid%nHexs > 0 ) THEN 
      pint => pgrid%hex2v(1,1)

      CALL com_set_size(trim(winname)//'.:H8:real',paneid,pgrid%nHexs,0)
      CALL com_set_array(trim(winname)//'.:H8:real',paneid,pint)  
    END IF ! pGrid%nHexs 

    IF ( pgrid%nPris > 0 ) THEN 
      pint => pgrid%pri2v(1,1)

      CALL com_set_size(trim(winname)//'.:W6:real',paneid,pgrid%nPris,0)
      CALL com_set_array(trim(winname)//'.:W6:real',paneid,pint)  
    END IF ! pGrid%nPris 

    IF ( pgrid%nPyrs > 0 ) THEN 
      pint => pgrid%pyr2v(1,1)

      CALL com_set_size(trim(winname)//'.:P5:real',paneid,pgrid%nPyrs,0)
      CALL com_set_array(trim(winname)//'.:P5:real',paneid,pint)  
    END IF ! pGrid%nPyrs     

! ------------------------------------------------------------------------------
!   Virtual cells
! ------------------------------------------------------------------------------

    IF ( pgrid%nTetsTot > pgrid%nTets ) THEN 
      pint => pgrid%tet2v(1,pgrid%nTets+1)

      CALL com_set_size(trim(winname)//'.:T4:virtual',paneid, &
                        pgrid%nTetsTot-pgrid%nTets,pgrid%nTetsTot-pgrid%nTets)
      CALL com_set_array(trim(winname)//'.:T4:virtual',paneid,pint) 
    END IF ! pGrid%nTetsTot

    IF ( pgrid%nHexsTot > pgrid%nHexs ) THEN 
      pint => pgrid%hex2v(1,pgrid%nHexs+1)

      CALL com_set_size(trim(winname)//'.:H8:virtual',paneid, &
                        pgrid%nHexsTot-pgrid%nHexs,pgrid%nHexsTot-pgrid%nHexs)
      CALL com_set_array(trim(winname)//'.:H8:virtual',paneid,pint)  
    END IF ! pGrid%nHexsTot

    IF ( pgrid%nPrisTot > pgrid%nPris ) THEN 
      pint => pgrid%pri2v(1,pgrid%nPris+1)

      CALL com_set_size(trim(winname)//'.:W6:virtual',paneid, &
                        pgrid%nPrisTot-pgrid%nPris,pgrid%nPrisTot-pgrid%nPris)
      CALL com_set_array(trim(winname)//'.:W6:virtual',paneid,pint)  
    END IF ! pGrid%nPrisTot

    IF ( pgrid%nPyrsTot > pgrid%nPyrs ) THEN 
      pint => pgrid%pyr2v(1,pgrid%nPyrs+1)

      CALL com_set_size(trim(winname)//'.:P5:virtual',paneid, &
                        pgrid%nPyrsTot-pgrid%nPyrs,pgrid%nPyrsTot-pgrid%nPyrs)
      CALL com_set_array(trim(winname)//'.:P5:virtual',paneid,pint)  
    END IF ! pGrid%nPrisTot

! ******************************************************************************
!   End
! ******************************************************************************

    IF ( global%myProcid == masterproc .AND. &
         global%verbLevel >= verbose_high ) THEN 
      WRITE(stdout,'(A,1X,A)') solver_name,'Registering volume grid done.'
    END IF ! global%verbLevel
  
  END SUBROUTINE rflu_genx_registergridvol

  








! ******************************************************************************
!
! Purpose: Register size of connectivity tables.
!
! Description: None.
!
! Input:
!   pRegion             Pointer to region
!
! Output: None.
!
! Notes: 
!    1. Must be called in initializor if have not registered grid so Roccom
!       knows how many cells exist in grid.
!
! ******************************************************************************

  SUBROUTINE rflu_genx_setconnsize(pRegion)
  
    IMPLICIT NONE

! ******************************************************************************
!   Declarations and definitions
! ******************************************************************************

! ==============================================================================  
!   Arguments 
! ==============================================================================  

    TYPE(t_region), POINTER :: pregion

! ==============================================================================  
!   Locals 
! ==============================================================================  
    
    CHARACTER(CHRLEN) :: winname
    INTEGER :: paneid   
    TYPE(t_global), POINTER :: global
    TYPE(t_grid), POINTER :: pgrid
    
! ******************************************************************************
!   Start, set pointers
! ******************************************************************************
    
    global => pregion%global

    pgrid => pregion%grid

    IF ( global%myProcid == masterproc .AND. &
         global%verbLevel >= verbose_high ) THEN 
      WRITE(stdout,'(A,1X,A)') solver_name,'Setting conn size...'
    END IF ! global%verbLevel
    
! ******************************************************************************
!   Register conn size
! ******************************************************************************

    winname = global%volWinName
    
    CALL rflu_genx_buildpaneid(pregion%iRegionGlobal,0,paneid) 

    IF ( global%myProcid == masterproc .AND. &
         global%verbLevel >= verbose_high ) THEN         
      WRITE(stdout,'(A,3X,A,1X,A)') solver_name,'Window name:',trim(winname)
      WRITE(stdout,'(A,3X,A,1X,I5.5)') solver_name,'Pane id:',paneid   
    END IF ! global%verbLevel

    CALL com_set_size(trim(winname)//'.conn',paneid,pgrid%nCellsTot, &
                      pgrid%nCellsTot-pgrid%nCells)   

! ******************************************************************************
!   End
! ******************************************************************************

    IF ( global%myProcid == masterproc .AND. &
         global%verbLevel >= verbose_high ) THEN 
      WRITE(stdout,'(A,1X,A)') solver_name,'Setting conn size done.'
    END IF ! global%verbLevel
  
  END SUBROUTINE rflu_genx_setconnsize













! ******************************************************************************
!
! Purpose: Store communicator.
!
! Description: None.
!
! Input:
!   global              Pointer to global data
!   communicator        Communicator
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

  SUBROUTINE rflu_genx_storecommunicator(global,communicator)

    IMPLICIT NONE

! ******************************************************************************
!   Declarations and definitions
! ******************************************************************************

! ==============================================================================  
!   Arguments 
! ==============================================================================  

    INTEGER, INTENT(IN) :: communicator
    TYPE(t_global), POINTER :: global
        
! ******************************************************************************
!   Store communicator
! ******************************************************************************

    global%communicator = communicator
 
! ******************************************************************************
!   End
! ******************************************************************************
  
  END SUBROUTINE rflu_genx_storecommunicator










! ******************************************************************************
!
! Purpose: Set input window names.
!
! Description: None.
!
! Input:
!   pRegion             Pointer to region
!
! Output: None.
!
! Notes: 
!   1. Input volume window name is assumed to be subdivided into separate 
!      strings for the mixture and multi-physics modules by empty spaces. 
!
! ******************************************************************************

  SUBROUTINE rflu_genx_storenameshandles(global,surfWinNameInput, & 
                                         volwinnameinput,handleobtain)

    IMPLICIT NONE

! ******************************************************************************
!   Declarations and definitions
! ******************************************************************************

! ==============================================================================  
!   Arguments 
! ==============================================================================  

    CHARACTER(*), INTENT(IN) :: surfwinnameinput,volwinnameinput
    INTEGER, INTENT(IN) :: handleobtain
    TYPE(t_global), POINTER :: global

! ==============================================================================  
!   Locals 
! ==============================================================================  
        
    CHARACTER(CHRLEN) :: tempstring1,tempstring2
    INTEGER :: errorflag
        
! ******************************************************************************
!   Set names 
! ******************************************************************************

    IF ( global%myProcid == masterproc .AND. & 
         global%verbLevel >= verbose_high ) THEN 
      WRITE(stdout,'(A,1X,A)') solver_name,'Storing names and handles...'
    END IF ! global%myProcid

! ==============================================================================  
!   Surface
! ==============================================================================  

    global%surfWinNameInput = surfwinnameinput

    IF ( global%myProcid == masterproc .AND. & 
         global%verbLevel >= verbose_high ) THEN 
      WRITE(stdout,'(A,3X,A,1X,A)') solver_name,'Input surface window name:', & 
                                    trim(global%surfWinNameInput)
    END IF ! global%myProcid
    
! ==============================================================================  
!   Volume. NOTE separate input volume window into substrings.
! ==============================================================================  
  
    READ(volwinnameinput,*,iostat=errorflag) tempstring1,tempstring2
    global%error = errorflag
    IF ( global%error /= err_none ) THEN 
      CALL errorstop(global,err_string_read,__line__)
    END IF ! global%error

! ------------------------------------------------------------------------------
!   Mixture
! ------------------------------------------------------------------------------
  
    global%volWinNameInput = trim(tempstring1)

    IF ( global%myProcid == masterproc .AND. & 
         global%verbLevel >= verbose_high ) THEN 
      WRITE(stdout,'(A,3X,A,1X,A)') solver_name,'Input volume window name:', & 
                                    trim(global%volWinNameInput)
    END IF ! global%myProcid
    
! TO DO 
! When PLAG is being integrated, a new window name will need to be defined and
! it will need to be set to tempString2
! END TO DO 
      
! ******************************************************************************
!   Set handles
! ******************************************************************************

    global%handleObtain = handleobtain   

! ******************************************************************************
!   End
! ******************************************************************************

    IF ( global%myProcid == masterproc .AND. & 
         global%verbLevel >= verbose_high ) THEN 
      WRITE(stdout,'(A,1X,A)') solver_name,'Storing names and handles done.'
    END IF ! global%myProcid
      
  END SUBROUTINE rflu_genx_storenameshandles









END MODULE rflu_modrocstaradmin

! ******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLU_ModGENXAdmin.F90,v $
! Revision 1.26  2009/05/12 20:20:56  mtcampbe
! Rocon integration changes
!
! Revision 1.25  2008/12/06 08:44:21  mtcampbe
! Updated license.
!
! Revision 1.24  2008/11/19 22:17:32  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.23  2007/07/08 21:45:03  gzheng
! changed the PRESENT is used for PGI compiler
!
! Revision 1.22  2007/04/20 16:07:48  mtcampbe
! Updating for burnout support function RFLU_GENX_InitBFLAG
!
! Revision 1.21  2007/04/14 14:12:53  mtcampbe
! Mods for TZ
!
! Revision 1.20  2006/04/07 15:19:19  haselbac
! Removed tabs
!
! Revision 1.19  2006/01/04 20:11:18  wasistho
! added turbActive condition
!
! Revision 1.18  2006/01/03 06:29:53  wasistho
! added CreateAttrWrapper and RegisterDataWrapper
!
! Revision 1.17  2005/10/14 14:06:53  haselbac
! Added alloc/dealloc and setting of tbAlp array
!
! Revision 1.16  2005/10/14 13:07:36  haselbac
! Removed tbAlp - added erroneously when checking in other changes
!
! Revision 1.15  2005/10/13 17:27:32  haselbac
! Fixed bug in format statement, lead to *** output
!
! Revision 1.14  2005/07/01 15:14:36  haselbac
! Added reading of verbLevelCOM
!
! Revision 1.13  2005/06/09 20:19:52  haselbac
! Added cnstr_type to various routines
!
! Revision 1.12  2005/05/04 03:34:10  haselbac
! Added writing of more info when registering surface grid
!
! Revision 1.11  2005/04/15 15:06:55  haselbac
! Added routines to create, build, and destroy pconn attribute
!
! Revision 1.10  2005/03/09 15:07:41  haselbac
! Erroneous check-in, removed debug code
!
! Revision 1.9  2005/03/09 15:06:03  haselbac
! Added 2d option
!
! Revision 1.8  2004/11/03 17:02:16  haselbac
! Removal of vertex and cell flag arrays, removed RFLU_GENX_CreateAttrGridVol (no longer necessary)
!
! Revision 1.7  2004/11/02 14:03:34  haselbac
! Bug fix: Added missing declaration of t_mixt_input
!
! Revision 1.6  2004/11/02 02:31:33  haselbac
! Replaced CV_MIXT_NEQS and DV_MIXT_NVAR
!
! Revision 1.5  2004/10/27 12:26:52  jiao
! Fixed definition of bcflag, which used to be defined three times.
!
! Revision 1.4  2004/10/27 05:46:45  jiao
! Added COM_set_size back for .gs for volume window.
!
! Revision 1.3  2004/10/27 05:24:55  jiao
! Removed COM_set_size on du_alp and gs.
!
! Revision 1.2  2004/10/22 14:00:57  haselbac
! Bug fix: False type used when creating attr for disp
!
! Revision 1.1  2004/10/19 19:27:25  haselbac
! Initial revision
!
! ******************************************************************************