RFLU_ModReadWriteBcDataFile.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
! ******************************************************************************
!
! Purpose: Collection of routines to read boundary condition data file.
!
! Description: None.
!
! Notes: None.
!
! ******************************************************************************
!
! $Id: RFLU_ModReadWriteBcDataFile.F90,v 1.6 2008/12/06 08:44:23 mtcampbe Exp $
!
! Copyright: (c) 2004 by the University of Illinois
!
! ******************************************************************************

MODULE rflu_modreadwritebcdatafile

  USE modparameters
  USE moddatatypes
  USE moderror
  USE modglobal, ONLY: t_global 
  USE modbndpatch, ONLY: t_patch
  USE moddatastruct, ONLY: t_region  
  USE modgrid, ONLY: t_grid
  USE modmpi
  
  IMPLICIT NONE

  PRIVATE
  PUBLIC :: rflu_decidereadwritebcdatafile, & 
            rflu_readbcdatafile, & 
            rflu_writebcdatafile
        
! ******************************************************************************
! Declarations and definitions
! ******************************************************************************  
   
  CHARACTER(CHRLEN) :: RCSIdentString = & 
    '$RCSfile: RFLU_ModReadWriteBcDataFile.F90,v $ $Revision: 1.6 $'        
             
! ******************************************************************************
! Routines
! ******************************************************************************

  CONTAINS







! ******************************************************************************
!
! Purpose: Decide whether need to read and/or write boundary-condition data 
!   file.
!
! Description: None.
!
! Input: 
!   pRegion     Pointer to region data
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

  LOGICAL FUNCTION rflu_decidereadwritebcdatafile(pRegion)

    IMPLICIT NONE

! ******************************************************************************
!   Declarations and definitions
! ******************************************************************************  

! ==============================================================================
!   Arguments
! ==============================================================================

    TYPE(t_region), POINTER :: pregion

! ==============================================================================
!   Local variables
! ==============================================================================

    CHARACTER(CHRLEN) :: rcsidentstring
    INTEGER :: ipatch
    TYPE(t_global), POINTER :: global
    TYPE(t_grid), POINTER :: pgrid
    TYPE(t_patch), POINTER :: ppatch

! ******************************************************************************
!   Start
! ******************************************************************************

    global => pregion%global

    CALL registerfunction(global,'RFLU_DecideReadWriteBcDataFile',&
  'RFLU_ModReadWriteBcDataFile.F90')
    
! ******************************************************************************
!   Set pointers and initialize
! ******************************************************************************    
    
    pgrid => pregion%grid  
    
    rflu_decidereadwritebcdatafile = .false.  
    
! ******************************************************************************
!   Loop over patches
! ******************************************************************************

    DO ipatch = 1,pgrid%nPatches
      ppatch => pregion%patches(ipatch)
  
! ==============================================================================
!     If not coupled and have distribution, write data
! ==============================================================================    
  
      IF ( (ppatch%bcCoupled == bc_not_coupled) .AND. & 
           (ppatch%mixt%distrib == bcdat_distrib) ) THEN
! TEMPORARY
!        RFLU_DecideReadWriteBcDataFile = .TRUE.
        rflu_decidereadwritebcdatafile = .false.
! END TEMPORARY

        EXIT
      END IF ! pPatch%bcCoupled
    END DO ! iPatch 

! ******************************************************************************
!   End
! ******************************************************************************
  
    CALL deregisterfunction(global)

  END FUNCTION rflu_decidereadwritebcdatafile








! ******************************************************************************
!
! Purpose: Read boundary-condition data file.
!
! Description: None.
!
! Input: 
!   pRegion     Pointer to region data
!
! Output: None.
!
! Notes: 
!   1. At present restricted to mixture. Best way to extend to MP not clear.
!
! ******************************************************************************

  SUBROUTINE rflu_readbcdatafile(pRegion)

    USE modbuildfilenames, ONLY: buildfilenamebasic

    IMPLICIT NONE

! ******************************************************************************
!   Declarations and definitions
! ******************************************************************************  

! ==============================================================================
!   Arguments
! ==============================================================================

    TYPE(t_region), POINTER :: pregion

! ==============================================================================
!   Local variables
! ==============================================================================

    CHARACTER(CHRLEN) :: errorstring,ifilename,sectionstring
    INTEGER :: dummyinteger,errorflag,idata,ifile,ifl,ipatch,ipatchglobal, & 
               loopcounter,nbfaces,ndata
    TYPE(t_global), POINTER :: global
    TYPE(t_grid), POINTER :: pgrid
    TYPE(t_patch), POINTER :: ppatch

! ******************************************************************************
! Start
! ******************************************************************************

    global => pregion%global

    CALL registerfunction(global,'RFLU_ReadBcDataFile',&
  'RFLU_ModReadWriteBcDataFile.F90')

    IF ( global%myProcid == masterproc .AND. &
         global%verbLevel > verbose_none ) THEN  
      WRITE(stdout,'(A,1X,A)') solver_name,'Reading boundary-condition data...'
    END IF ! global%verbLevel

! ******************************************************************************
!   Set pointers
! ******************************************************************************

    pgrid => pregion%grid
    
! ******************************************************************************
!   Open file
! ******************************************************************************

    ifile = if_distr

    CALL buildfilenamebasic(global,filedest_indir,'.bcd', & 
                            pregion%iRegionGlobal,ifilename) 

    OPEN(ifile,file=ifilename,form='FORMATTED',status='OLD',iostat=errorflag)
    global%error = errorflag
    IF ( global%error /= err_none ) THEN 
      CALL errorstop(global,err_file_open,__line__,'File: '//trim(ifilename))
    END IF ! global%error  

! ******************************************************************************
!   Read header
! ******************************************************************************

    READ(ifile,'(A)') sectionstring
    IF ( trim(sectionstring) /= '# ROCFLU boundary-condition data file' ) THEN 
      CALL errorstop(global,err_invalid_marker,__line__,sectionstring) 
    END IF ! TRIM

! ******************************************************************************
!   Read data
! ******************************************************************************

    loopcounter = 0

    DO ! set up infinite loop
      loopcounter = loopcounter + 1

      READ(ifile,'(A)') sectionstring

      SELECT CASE ( trim(sectionstring) ) 

! ==============================================================================
!       Patch data
! ==============================================================================
        
        CASE ( '# Patch data' )
          IF ( global%myProcid == masterproc .AND. &
               global%verbLevel > verbose_low ) THEN  
            WRITE(stdout,'(A,3X,A)') solver_name,'Patch data...'
          END IF ! global%verbLevel       

          READ(ifile,*) ipatch,ipatchglobal,nbfaces,ndata  
            
! ------------------------------------------------------------------------------
!         Check that input correct
! ------------------------------------------------------------------------------            
                    
          IF ( ipatch > pgrid%nPatches ) THEN
            WRITE(errorstring,'(A,1X,I3)') 'Patch index invalid:',ipatch 
            CALL errorstop(global,err_bcdata_value_invalid,__line__, & 
                           trim(errorstring))
          END IF ! iPatch                                                  

          ppatch => pregion%patches(ipatch)

          IF ( nbfaces /= ppatch%nBFaces ) THEN 
            WRITE(errorstring,'(A,1X,I6)') 'Number of faces invalid:',nbfaces
            CALL errorstop(global,err_bcdata_value_invalid,__line__, & 
                           trim(errorstring))
          END IF ! nBFaces          

          IF ( ipatchglobal /= ppatch%iPatchGlobal ) THEN 
            WRITE(errorstring,'(A,1X,I3)') 'Global patch index invalid:', & 
                                           ipatchglobal
            CALL errorstop(global,err_bcdata_value_invalid,__line__, & 
                           trim(errorstring))
          END IF ! iPatchGlobal           

          IF ( ndata /= ppatch%mixt%nData ) THEN 
            WRITE(errorstring,'(A,1X,I3)') & 
              'Number of pieces of data invalid:',ndata
            CALL errorstop(global,err_bcdata_value_invalid,__line__, & 
                           trim(errorstring))
          END IF ! iPatchGlobal    
    
! ------------------------------------------------------------------------------
!         Read data
! ------------------------------------------------------------------------------    
    
          DO ifl = 1,ppatch%nBFaces
            DO idata = 1,ppatch%mixt%nData
              READ(ifile,'(1X,I6,1X,I2,1X,E23.16)') & 
                dummyinteger,dummyinteger,ppatch%mixt%vals(idata,ifl)
            END DO ! iData  
          END DO ! ifl

! ==============================================================================
!       End marker
! ==============================================================================
      
        CASE ( '# End' ) 
          IF ( global%myProcid == masterproc .AND. & 
               global%verbLevel > verbose_low ) THEN  
            WRITE(stdout,'(A,3X,A)') solver_name,'End marker...'
          END IF ! global%verbLevel           

          EXIT

! ==============================================================================
!       Invalid section string
! ==============================================================================

        CASE default
          IF ( global%verbLevel > verbose_low ) THEN  
            WRITE(stdout,'(A,3X,A)') solver_name,sectionstring
          END IF ! verbosityLevel           

          CALL errorstop(global,err_invalid_marker,__line__,sectionstring)      

      END SELECT ! TRIM

! ==============================================================================
!     Guard against infinite loop - might be unnecessary because of read errors?
! ==============================================================================
  
      IF ( loopcounter >= limit_infinite_loop ) THEN 
        CALL errorstop(global,err_infinite_loop,__line__)
      END IF ! loopCounter

    END DO ! <empty> 

! ******************************************************************************
!   Close file
! ******************************************************************************
    
    CLOSE(ifile,iostat=errorflag)
    global%error = errorflag
    IF ( global%error /= err_none ) THEN 
      CALL errorstop(global,err_file_close,__line__,'File: '//trim(ifilename))
    END IF ! global%error  

! ******************************************************************************
!   End
! ******************************************************************************

    IF ( global%myProcid == masterproc .AND. &
         global%verbLevel > verbose_none ) THEN  
      WRITE(stdout,'(A,1X,A)') solver_name,'Reading boundary-condition data done.'
    END IF ! global%verbLevel

    CALL deregisterfunction(global)

  END SUBROUTINE rflu_readbcdatafile








! ******************************************************************************
!
! Purpose: Write boundary-condition data file.
!
! Description: None.
!
! Input: 
!   pRegion     Pointer to region data
!
! Output: None.
!
! Notes: 
!   1. At present restricted to mixture. Best way to extend to MP not clear.
!
! ******************************************************************************

  SUBROUTINE rflu_writebcdatafile(pRegion)

    USE modbuildfilenames, ONLY: buildfilenamebasic

    IMPLICIT NONE

! ******************************************************************************
!   Declarations and definitions
! ******************************************************************************  

! ==============================================================================
!   Arguments
! ==============================================================================

    TYPE(t_region), POINTER :: pregion

! ==============================================================================
!   Local variables
! ==============================================================================

    CHARACTER(CHRLEN) :: ifilename,sectionstring
    INTEGER :: dummyinteger,errorflag,idata,ifile,ifl,ipatch
    TYPE(t_global), POINTER :: global
    TYPE(t_grid), POINTER :: pgrid
    TYPE(t_patch), POINTER :: ppatch

! ******************************************************************************
!   Start
! ******************************************************************************

    global => pregion%global

    CALL registerfunction(global,'RFLU_WriteBcDataFile',&
  'RFLU_ModReadWriteBcDataFile.F90')

    IF ( global%myProcid == masterproc .AND. &
         global%verbLevel > verbose_none ) THEN  
      WRITE(stdout,'(A,1X,A)') solver_name,'Writing boundary-condition data...'
    END IF ! global%verbLevel
  
! ******************************************************************************
!   Set pointers
! ******************************************************************************

    pgrid => pregion%grid
  
! ******************************************************************************
!   Open file
! ******************************************************************************

    ifile = if_distr

    CALL buildfilenamebasic(global,filedest_indir,'.bcd', & 
                            pregion%iRegionGlobal,ifilename) 

    OPEN(ifile,file=ifilename,form='FORMATTED',status='UNKNOWN', & 
         iostat=errorflag)
    global%error = errorflag
    IF ( global%error /= err_none ) THEN 
      CALL errorstop(global,err_file_open,__line__,'File: '//trim(ifilename))
    END IF ! global%error  

! ******************************************************************************
!   Write header
! ******************************************************************************
 
    sectionstring = '# ROCFLU boundary-condition data file'   
    WRITE(ifile,'(A)') sectionstring

! ******************************************************************************
!   Loop over patches
! ******************************************************************************

    DO ipatch = 1,pgrid%nPatches
      ppatch => pregion%patches(ipatch)
  
! ==============================================================================
!     If not coupled and have distribution, write data
! ==============================================================================    
  
      IF ( (ppatch%bcCoupled == bc_not_coupled) .AND. & 
           (ppatch%mixt%distrib == bcdat_distrib) ) THEN
        WRITE(ifile,'(A)') '# Patch data' 
        WRITE(ifile,'(2(1X,I3),1X,I6,1X,I2)') ipatch,ppatch%iPatchGlobal, & 
                                              ppatch%nBFaces, & 
                                              ppatch%mixt%nData

        DO ifl = 1,ppatch%nBFaces
          DO idata = 1,ppatch%mixt%nData
            WRITE(ifile,'(1X,I6,1X,I2,1X,E23.16)') ifl,idata, &
              ppatch%mixt%vals(idata,ifl)
          END DO ! iData  
        END DO ! ifl
      END IF ! pPatch%bcCoupled
    END DO ! iPatch

! ******************************************************************************
!   Write footer
! ******************************************************************************
 
    sectionstring = '# End'   
    WRITE(ifile,'(A)') sectionstring

! ******************************************************************************
!   Close file
! ******************************************************************************

    CLOSE(ifile,iostat=errorflag)
    global%error = errorflag
    IF ( global%error /= err_none ) THEN 
      CALL errorstop(global,err_file_close,__line__,'File: '//trim(ifilename))
    END IF ! global%error  

! ******************************************************************************
!   End
! ******************************************************************************

    IF ( global%myProcid == masterproc .AND. &
         global%verbLevel > verbose_none ) THEN  
      WRITE(stdout,'(A,1X,A)') solver_name, & 
        'Writing boundary-condition data done.'
    END IF ! global%verbLevel

    CALL deregisterfunction(global)

  END SUBROUTINE rflu_writebcdatafile









! ******************************************************************************
! End
! ******************************************************************************
  
END MODULE rflu_modreadwritebcdatafile


! ******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLU_ModReadWriteBcDataFile.F90,v $
! Revision 1.6  2008/12/06 08:44:23  mtcampbe
! Updated license.
!
! Revision 1.5  2008/11/19 22:17:34  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.4  2006/08/19 15:39:14  mparmar
! Renamed patch variables
!
! Revision 1.3  2006/04/07 15:19:20  haselbac
! Removed tabs
!
! Revision 1.2  2005/12/23 13:47:01  haselbac
! Temporarily disable bc data files to avoid hardcoding for runs with tbc
!
! Revision 1.1  2004/07/06 15:14:30  haselbac
! Initial revision
!
! ******************************************************************************