RFLU_ModENSIGHT.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
! ******************************************************************************
!
! Purpose: Collection of routines to write ENSIGHT files.
!
! Description: None.
!
! Input: None.
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************
!
! $Id: RFLU_ModENSIGHT.F90,v 1.6 2008/12/06 08:45:06 mtcampbe Exp $
!
! Copyright: (c) 2005 by the University of Illinois
!
! ******************************************************************************

MODULE rflu_modensight

  USE moddatatypes
  USE modparameters
  USE moderror
  USE modglobal, ONLY: t_global
  USE modgrid, ONLY: t_grid
  USE modbndpatch, ONLY: t_patch
  USE moddatastruct, ONLY: t_region

  USE rflu_modensightutils
  USE rflu_modplottingvars, ONLY: rflu_countplottingvars

  IMPLICIT NONE

! ******************************************************************************
! Definitions and declarations
! ******************************************************************************

! ==============================================================================
! Private data
! ==============================================================================

  CHARACTER(CHRLEN), PARAMETER, PRIVATE :: &
    RCSIdentString = '$RCSfile: RFLU_ModENSIGHT.F90,v $ $Revision: 1.6 $'

  INTEGER, PRIVATE :: nScalars,nScalars1,nVectors,partNumber,partNumberSave

  TYPE t_var_info
    PRIVATE
    CHARACTER(CHRLEN) :: iFileName,varName,varNameShort
    INTEGER :: iFile
  END TYPE t_var_info
  
  TYPE(t_var_info) :: geoInfo  
  TYPE(t_var_info), DIMENSION(:), ALLOCATABLE :: scalarInfo
  TYPE(t_var_info), DIMENSION(:), ALLOCATABLE :: vectorInfo   

! ==============================================================================
! Public functions
! ==============================================================================

  PUBLIC :: rflu_ens_builddatainfo, & 
            rflu_ens_closefilegeometry, & 
            rflu_ens_destroydatainfo, & 
            rflu_ens_initpartnumber, &
            rflu_ens_mapregion2server, &   
            rflu_ens_openfilegeometry, & 
            rflu_ens_writeflowwrapper, &  
            rflu_ens_writegridwrapper

! ******************************************************************************
! Subroutines and functions
! ******************************************************************************

  CONTAINS






! ******************************************************************************
!
! Purpose: Build scalar information.
!
! Description: None.
!
! Input:
!   pRegion             Pointer to region type
!   iServer             Server index
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

SUBROUTINE rflu_ens_builddatainfo(pRegion,iServer)

  USE modbuildfilenames, ONLY: buildfilenamesteady, & 
                               buildfilenameunsteady

! ******************************************************************************
! Declarations and definitions
! ******************************************************************************

! ==============================================================================
! Arguments
! ==============================================================================

  INTEGER, INTENT(IN) :: iserver
  TYPE(t_region), POINTER :: pregion

! ==============================================================================
! Locals
! ==============================================================================

  CHARACTER(CHRLEN) :: dummystring
  INTEGER :: errorflag,ifileoffs,ipv,ipv2,iscalar,iscalaroffs,ivector
  TYPE(t_global), POINTER :: global

! ******************************************************************************
! Start
! ******************************************************************************

  global => pregion%global

  CALL registerfunction(global,'RFLU_ENS_BuildDataInfo', &
                        'RFLU_ModENSIGHT.F90')

  IF ( global%verbLevel > verbose_low ) THEN
    WRITE(stdout,'(A,1X,A)') solver_name,'Building ENSIGHT data info...'
  END IF ! global%verbLevel

! ******************************************************************************
! Count number of scalars
! ******************************************************************************

! ==============================================================================
! Mixture
! ==============================================================================

  nscalars = 5
  nvectors = 1
  
! ==============================================================================
! Plotting variables
! ==============================================================================

  IF ( pregion%plot%nPv > 0 ) THEN
    nscalars = nscalars + pregion%plot%nPv
  END IF ! nPv 

! ==============================================================================
! Physical modules
! ==============================================================================
  
#ifdef SPEC
! ------------------------------------------------------------------------------
! Species
! ------------------------------------------------------------------------------

  IF ( global%specUsed .EQV. .true. ) THEN
    nscalars = nscalars + global%nSpecies
  END IF ! global%specUsed
#endif
  
! ******************************************************************************
! Allocate memory
! ******************************************************************************

  ALLOCATE(scalarinfo(nscalars),stat=errorflag)
  global%error = errorflag
  IF ( global%error /= err_none ) THEN 
    CALL errorstop(global,err_allocate,__line__,'scalarInfo')
  END IF ! global%error

  ALLOCATE(vectorinfo(nvectors),stat=errorflag)
  global%error = errorflag
  IF ( global%error /= err_none ) THEN 
    CALL errorstop(global,err_allocate,__line__,'vectorInfo')
  END IF ! global%error

! ******************************************************************************
! Set names and file indices
! ******************************************************************************

! ==============================================================================
! Mixture
! ==============================================================================

  nscalars = 5
  nvectors = 1

! ==============================================================================
! Plotting variables
! ==============================================================================

  IF ( pregion%plot%nPv > 0 ) THEN
    nscalars = nscalars + pregion%plot%nPv
  END IF ! nPv 

! ------------------------------------------------------------------------------
! Scalars
! ------------------------------------------------------------------------------

  scalarinfo(1)%varName = 'Density'
  scalarinfo(2)%varName = 'Energy'
  scalarinfo(3)%varName = 'Pressure'
  scalarinfo(4)%varName = 'Temperature'
  scalarinfo(5)%varName = 'Soundspeed'
  
  scalarinfo(1)%varNameShort = 'r'
  scalarinfo(2)%varNameShort = 'rE'
  scalarinfo(3)%varNameShort = 'p'
  scalarinfo(4)%varNameShort = 'T'
  scalarinfo(5)%varNameShort = 'a'

  nscalars1 = 5
  iscalar   = 0

  IF ( pregion%plot%nPv > 0 ) THEN
    DO ipv = 1,pregion%plot%nPv
      ipv2 = pregion%plot%pvi2pv(ipv)
      
      iscalar = iscalar+1
      
      scalarinfo(nscalars1+iscalar)%varName      = pregion%plot%pvNameLong(ipv2)
      scalarinfo(nscalars1+iscalar)%varNameShort = pregion%plot%pvNameShort(ipv2)      
    END DO ! iPv
  END IF ! nPv 

  scalarinfo(1)%iFile = if_ens_scalar
  scalarinfo(2)%iFile = if_ens_scalar + 1
  scalarinfo(3)%iFile = if_ens_scalar + 2
  scalarinfo(4)%iFile = if_ens_scalar + 3
  scalarinfo(5)%iFile = if_ens_scalar + 4 

  nscalars1 = 5

  IF ( pregion%plot%nPv > 0 ) THEN
    DO iscalar=1,pregion%plot%nPv
      scalarinfo(5+iscalar)%iFile = if_ens_scalar + nscalars1 + iscalar - 1 
    END DO ! iScalar  
  END IF ! nPv 

  iscalaroffs = 5

  IF ( pregion%plot%nPv > 0 ) THEN
    iscalaroffs = iscalaroffs + pregion%plot%nPv
  END IF ! nPv 

! ------------------------------------------------------------------------------
! Vectors
! ------------------------------------------------------------------------------

  vectorinfo(1)%varName = 'Momentum'
  
  vectorinfo(1)%varNameShort = 'rv'       

  vectorinfo(1)%iFile = if_ens_vector
    
! ==============================================================================
! Physical modules
! ==============================================================================

  ifileoffs = scalarinfo(iscalaroffs)%iFile 

#ifdef SPEC
! ------------------------------------------------------------------------------
! Species
! ------------------------------------------------------------------------------

  IF ( global%specUsed .EQV. .true. ) THEN
    DO iscalar = 1,global%nSpecies
      WRITE(dummystring,'(A,I2.2)') 'Density',iscalar  
      scalarinfo(iscalar+iscalaroffs)%varName = trim(dummystring)

      WRITE(dummystring,'(A,I2.2)') 'rY',iscalar 
      scalarinfo(iscalar+iscalaroffs)%varNameShort = trim(dummystring)

      scalarinfo(iscalar+iscalaroffs)%iFile = iscalar + ifileoffs
    END DO ! iScalar
  
    iscalaroffs = iscalaroffs + global%nSpecies
    nscalars    = nscalars    + global%nSpecies
  END IF ! global%specUsed
#endif

! ******************************************************************************
! Write info
! ******************************************************************************

  IF ( global%verbLevel > verbose_low ) THEN 
    WRITE(stdout,'(A,3X,A,1X,I2)') solver_name,'Server:',iserver
    WRITE(stdout,'(A,3X,A)') solver_name,'Scalar variables:'   
    WRITE(stdout,'(A,5X,A,2X,A,2X,A,26X,A)') solver_name,'#','Index', &
                                             'Long name','Short name'

    DO iscalar = 1,nscalars
      WRITE(stdout,'(A,4X,I2,3X,I3,3X,A32,3X,A5)') & 
            solver_name,iscalar,scalarinfo(iscalar)%iFile, & 
            adjustl(scalarinfo(iscalar)%varName), & 
            adjustl(scalarinfo(iscalar)%varNameShort)
    END DO ! iScalar

    WRITE(stdout,'(A,3X,A)') solver_name,'Vector variables:'   
    WRITE(stdout,'(A,5X,A,2X,A,2X,A,26X,A)') solver_name,'#','Index', &
                                             'Long name','Short name'

    DO ivector = 1,nvectors
      WRITE(stdout,'(A,4X,I2,3X,I3,3X,A32,3X,A5)') &
            solver_name,ivector,vectorinfo(ivector)%iFile, &      
            adjustl(vectorinfo(ivector)%varName), & 
            adjustl(vectorinfo(ivector)%varNameShort)
    END DO ! iVector
  END IF ! global%verbLevel

! ******************************************************************************
! Set file names
! ******************************************************************************

! ==============================================================================
! Geometry
! ==============================================================================

  CALL buildfilenamesteady(global,filedest_indir,'.geo',iserver, &
                           global%currentIter,geoinfo%iFileName)

! ==============================================================================
! Scalars
! ==============================================================================

  IF ( global%flowType == flow_unsteady ) THEN
    DO iscalar = 1,nscalars
      CALL buildfilenameunsteady(global,filedest_indir, & 
                                 '.'//trim(scalarinfo(iscalar)%varNameShort), & 
                                 iserver,global%currentTime, &
                                 scalarinfo(iscalar)%iFileName)
    END DO ! iScalar
  ELSE IF ( global%flowType == flow_steady ) THEN
    DO iscalar = 1,nscalars
      CALL buildfilenamesteady(global,filedest_indir, & 
                               '.'//trim(scalarinfo(iscalar)%varNameShort), &
                               iserver,global%currentIter, &
                               scalarinfo(iscalar)%iFileName)
    END DO ! iScalar
  ELSE ! defensive coding
    CALL errorstop(global,err_reached_default,__line__)
  END IF ! global%flowType 
  
! ==============================================================================
! Vectors
! ==============================================================================
  
  IF ( global%flowType == flow_unsteady ) THEN
    DO ivector = 1,nvectors
      CALL buildfilenameunsteady(global,filedest_indir, & 
                                 '.'//trim(vectorinfo(ivector)%varNameShort), & 
                                 iserver,global%currentTime, &
                                 vectorinfo(ivector)%iFileName)
    END DO ! iScalar
  ELSE IF ( global%flowType == flow_steady ) THEN
    DO ivector = 1,nvectors
      CALL buildfilenamesteady(global,filedest_indir, & 
                               '.'//trim(vectorinfo(ivector)%varNameShort), &
                               iserver,global%currentIter, &
                               vectorinfo(ivector)%iFileName)
    END DO ! iVector
  ELSE ! defensive coding
    CALL errorstop(global,err_reached_default,__line__)
  END IF ! global%flowType      
         
! ******************************************************************************
! End
! ******************************************************************************

  IF ( global%verbLevel > verbose_low ) THEN
    WRITE(stdout,'(A,1X,A)') solver_name,'Building ENSIGHT data info done.'
  END IF ! global%verbLevel

  CALL deregisterfunction(global)

END SUBROUTINE rflu_ens_builddatainfo








! ******************************************************************************
!
! Purpose: Open ENSIGHT scalar file.
!
! Description: None.
!
! Input:
!   global                Pointer to global type
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

SUBROUTINE rflu_ens_closefileflowwrapper(global)

! ******************************************************************************
! Declarations and definitions
! ******************************************************************************

! ==============================================================================
! Arguments
! ==============================================================================

  TYPE(t_global), POINTER :: global

! ==============================================================================
! Locals
! ==============================================================================

  CHARACTER(80) :: dummystring
  CHARACTER(CHRLEN) :: ifilename 
  INTEGER :: errorflag,iscalar,ivector

! ******************************************************************************
! Start
! ******************************************************************************

  CALL registerfunction(global,'RFLU_ENS_CloseFileFlowWrapper', &
                        'RFLU_ModENSIGHT.F90')

  IF ( global%verbLevel > verbose_low ) THEN
    WRITE(stdout,'(A,1X,A)') solver_name,'Closing ENSIGHT flow files...'
  END IF ! global%verbLevel

! ******************************************************************************
! Close files
! ******************************************************************************

  DO iscalar = 1,nscalars
    CALL rflu_ens_closefilescalarvector(global,scalarinfo(iscalar)%iFile)
  END DO ! iScalar
  
  DO ivector = 1,nvectors
    CALL rflu_ens_closefilescalarvector(global,vectorinfo(ivector)%iFile)
  END DO ! iVector
         
! ******************************************************************************
! End
! ******************************************************************************

  IF ( global%verbLevel > verbose_low ) THEN
    WRITE(stdout,'(A,1X,A)') solver_name,'Closing ENSIGHT flow files done.'
  END IF ! global%verbLevel

  CALL deregisterfunction(global)

END SUBROUTINE rflu_ens_closefileflowwrapper








! ******************************************************************************
!
! Purpose: Close ENSIGHT geometry file.
!
! Description: None.
!
! Input:
!   global                Pointer to global type
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

SUBROUTINE rflu_ens_closefilegeometry(global)

! ******************************************************************************
! Declarations and definitions
! ******************************************************************************

! ==============================================================================
! Arguments
! ==============================================================================

  TYPE(t_global), POINTER :: global

! ==============================================================================
! Locals
! ==============================================================================

  INTEGER :: errorflag

! ******************************************************************************
! Start
! ******************************************************************************

  CALL registerfunction(global,'RFLU_ENS_CloseFileGeometry', &
                        'RFLU_ModENSIGHT.F90')

  IF ( global%verbLevel > verbose_low ) THEN
    WRITE(stdout,'(A,1X,A)') solver_name,'Closing ENSIGHT geometry file...'
  END IF ! global%verbLevel

! ******************************************************************************
! Close file
! ******************************************************************************

  CLOSE(if_ens_geometry,iostat=errorflag)
  global%error = errorflag
  IF ( global%error /= err_none ) THEN 
    CALL errorstop(global,err_file_close,__line__)
  END IF ! global%error    

! ******************************************************************************
! End
! ******************************************************************************

  IF ( global%verbLevel > verbose_low ) THEN
    WRITE(stdout,'(A,1X,A)') solver_name,'Closing ENSIGHT geometry file done.'
  END IF ! global%verbLevel

  CALL deregisterfunction(global)

END SUBROUTINE rflu_ens_closefilegeometry






! ******************************************************************************
!
! Purpose: Close ENSIGHT scalar/vector file.
!
! Description: None.
!
! Input:
!   global                Pointer to global type
!   iFile                 File index
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

SUBROUTINE rflu_ens_closefilescalarvector(global,iFile)

! ******************************************************************************
! Declarations and definitions
! ******************************************************************************

! ==============================================================================
! Arguments
! ==============================================================================

  INTEGER, INTENT(IN) :: ifile
  TYPE(t_global), POINTER :: global

! ==============================================================================
! Locals
! ==============================================================================

  INTEGER :: errorflag

! ******************************************************************************
! Start
! ******************************************************************************

  CALL registerfunction(global,'RFLU_ENS_CloseFileScalarVector', &
                        'RFLU_ModENSIGHT.F90')

! ******************************************************************************
! Close file
! ******************************************************************************

  CLOSE(ifile,iostat=errorflag)
  global%error = errorflag
  IF ( global%error /= err_none ) THEN 
    CALL errorstop(global,err_file_close,__line__)
  END IF ! global%error    

! ******************************************************************************
! End
! ******************************************************************************

  CALL deregisterfunction(global)

END SUBROUTINE rflu_ens_closefilescalarvector







! ******************************************************************************
!
! Purpose: Destroy data information.
!
! Description: None.
!
! Input:
!   global                Pointer to global type
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

SUBROUTINE rflu_ens_destroydatainfo(global)

! ******************************************************************************
! Declarations and definitions
! ******************************************************************************

! ==============================================================================
! Arguments
! ==============================================================================

  TYPE(t_global), POINTER :: global

! ==============================================================================
! Locals
! ==============================================================================

  INTEGER :: errorflag

! ******************************************************************************
! Start
! ******************************************************************************

  CALL registerfunction(global,'RFLU_ENS_DestroyDataInfo', &
                        'RFLU_ModENSIGHT.F90')

  IF ( global%verbLevel > verbose_low ) THEN
    WRITE(stdout,'(A,1X,A)') solver_name,'Destroying ENSIGHT data info...'
  END IF ! global%verbLevel

! ******************************************************************************
! Deallocate memory
! ******************************************************************************

  DEALLOCATE(scalarinfo,stat=errorflag)
  global%error = errorflag
  IF ( global%error /= err_none ) THEN 
    CALL errorstop(global,err_deallocate,__line__,'scalarInfo')
  END IF ! global%error
  
  DEALLOCATE(vectorinfo,stat=errorflag)
  global%error = errorflag
  IF ( global%error /= err_none ) THEN 
    CALL errorstop(global,err_deallocate,__line__,'vectorInfo')
  END IF ! global%error  

! ******************************************************************************
! Reset number of data items
! ******************************************************************************

  nscalars = 0
  nvectors = 0

! ******************************************************************************
! End
! ******************************************************************************

  IF ( global%verbLevel > verbose_low ) THEN
    WRITE(stdout,'(A,1X,A)') solver_name,'Destroying ENSIGHT data info done.'
  END IF ! global%verbLevel

  CALL deregisterfunction(global)

END SUBROUTINE rflu_ens_destroydatainfo







! ******************************************************************************
!
! Purpose: Initialize part number.
!
! Description: None.
!
! Input:
!   global                Pointer to global type
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

SUBROUTINE rflu_ens_initpartnumber(global)

! ******************************************************************************
! Declarations and definitions
! ******************************************************************************

! ==============================================================================
! Arguments
! ==============================================================================

  TYPE(t_global), POINTER :: global

! ******************************************************************************
! Start
! ******************************************************************************

  global%postPartNumber = 0
         
! ******************************************************************************
! End
! ******************************************************************************

END SUBROUTINE rflu_ens_initpartnumber







! ******************************************************************************
!
! Purpose: Map regions to servers.
!
! Description: None.
!
! Input:
!   iReg        Region index
!   nRegions    Number of regions
!   nServers    Number of servers
!
! Output: None.
!
! Notes: 
!   1. Note use of integer division.
!
! ******************************************************************************

INTEGER FUNCTION rflu_ens_mapregion2server(iReg,nRegions,nServers)

! ******************************************************************************
! Declarations and definitions
! ******************************************************************************

! ==============================================================================
! Arguments
! ==============================================================================

  INTEGER, INTENT(IN) :: ireg,nregions,nservers

! ******************************************************************************
! Start
! ******************************************************************************

  rflu_ens_mapregion2server = min((ireg-1)/nservers + 1,nservers)
         
! ******************************************************************************
! End
! ******************************************************************************

END FUNCTION rflu_ens_mapregion2server






! ******************************************************************************
!
! Purpose: Open ENSIGHT scalar file.
!
! Description: None.
!
! Input:
!   global              Pointer to global type
!   iServer             Index of server
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

SUBROUTINE rflu_ens_openfileflowwrapper(global,iServer)

! ******************************************************************************
! Declarations and definitions
! ******************************************************************************

! ==============================================================================
! Arguments
! ==============================================================================

  INTEGER, INTENT(IN) :: iserver
  TYPE(t_global), POINTER :: global

! ==============================================================================
! Locals
! ==============================================================================

  CHARACTER(80) :: dummystring
  CHARACTER(CHRLEN) :: ifilename 
  INTEGER :: errorflag,iscalar,ivector

! ******************************************************************************
! Start
! ******************************************************************************

  CALL registerfunction(global,'RFLU_ENS_OpenFileFlowWrapper', &
                        'RFLU_ModENSIGHT.F90')

  IF ( global%verbLevel > verbose_low ) THEN
    WRITE(stdout,'(A,1X,A)') solver_name,'Opening ENSIGHT flow files...'
  END IF ! global%verbLevel

! ******************************************************************************
! Open files
! ******************************************************************************

  DO iscalar = 1,nscalars
    CALL rflu_ens_openfilescalarvector(global,scalarinfo(iscalar)%iFile, & 
                                       scalarinfo(iscalar)%iFileName)
  END DO ! iScalar                                                                              
                  
  DO ivector = 1,nvectors                                                                          
    CALL rflu_ens_openfilescalarvector(global,vectorinfo(ivector)%iFile, &
                                       vectorinfo(ivector)%iFileName)
  END DO ! iVector       
         
! ******************************************************************************
! End
! ******************************************************************************

  IF ( global%verbLevel > verbose_low ) THEN
    WRITE(stdout,'(A,1X,A)') solver_name,'Opening ENSIGHT flow files done.'
  END IF ! global%verbLevel

  CALL deregisterfunction(global)

END SUBROUTINE rflu_ens_openfileflowwrapper






! ******************************************************************************
!
! Purpose: Open ENSIGHT geometry file.
!
! Description: None.
!
! Input:
!   global              Pointer to global type
!   iServer             Index of server
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

SUBROUTINE rflu_ens_openfilegeometry(global,iServer)

! ******************************************************************************
! Declarations and definitions
! ******************************************************************************

! ==============================================================================
! Arguments
! ==============================================================================

  INTEGER, INTENT(IN) :: iserver
  TYPE(t_global), POINTER :: global

! ==============================================================================
! Locals
! ==============================================================================

  CHARACTER(80) :: dummystring
  CHARACTER(CHRLEN) :: ifilename 
  INTEGER :: errorflag

! ******************************************************************************
! Start
! ******************************************************************************

  CALL registerfunction(global,'RFLU_ENS_OpenFileGeometry', &
                        'RFLU_ModENSIGHT.F90')

  IF ( global%verbLevel > verbose_low ) THEN
    WRITE(stdout,'(A,1X,A)') solver_name,'Opening ENSIGHT geometry file...'
  END IF ! global%verbLevel

! ******************************************************************************
! Open file
! ******************************************************************************

  OPEN(if_ens_geometry,file=trim(geoinfo%iFileName),form="UNFORMATTED", &
       status="UNKNOWN",iostat=errorflag)
  global%error = errorflag
  IF ( global%error /= err_none ) THEN 
    CALL errorstop(global,err_file_open,__line__,ifilename)
  END IF ! global%error  

! ******************************************************************************
! Write header
! ******************************************************************************

  dummystring = 'Fortran Binary'
  WRITE(if_ens_geometry) dummystring
  
  dummystring = trim(global%casename)
  WRITE(if_ens_geometry) dummystring
  
  dummystring = trim(global%casename)
  WRITE(if_ens_geometry) dummystring
  
  dummystring = 'node id assign'
  WRITE(if_ens_geometry) dummystring
  
  dummystring = 'element id assign'
  WRITE(if_ens_geometry) dummystring        

! ******************************************************************************
! End
! ******************************************************************************

  IF ( global%verbLevel > verbose_low ) THEN
    WRITE(stdout,'(A,1X,A)') solver_name,'Opening ENSIGHT geometry file done.'
  END IF ! global%verbLevel

  CALL deregisterfunction(global)

END SUBROUTINE rflu_ens_openfilegeometry








! ******************************************************************************
!
! Purpose: Open ENSIGHT scalar/vector file.
!
! Description: None.
!
! Input:
!   global              Pointer to global data
!   iFile               File index 
!   iFileName           File name
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

SUBROUTINE rflu_ens_openfilescalarvector(global,iFile,iFileName)

! ******************************************************************************
! Declarations and definitions
! ******************************************************************************

! ==============================================================================
! Arguments
! ==============================================================================

  CHARACTER(CHRLEN) :: ifilename
  INTEGER, INTENT(IN) :: ifile
  TYPE(t_global), POINTER :: global
  
! ==============================================================================
! Locals
! ==============================================================================

  CHARACTER(80) :: dummystring
  INTEGER :: errorflag

! ******************************************************************************
! Start
! ******************************************************************************

  CALL registerfunction(global,'RFLU_ENS_OpenFileScalarVector', &
                        'RFLU_ModENSIGHT.F90')

! ******************************************************************************
! Open file
! ******************************************************************************

  OPEN(ifile,file=trim(ifilename),form="UNFORMATTED",status="UNKNOWN", & 
       iostat=errorflag)
  global%error = errorflag
  IF ( global%error /= err_none ) THEN 
    CALL errorstop(global,err_file_open,__line__,trim(ifilename))
  END IF ! global%error  

! ******************************************************************************
! Write header
! ******************************************************************************
  
  dummystring = trim(global%casename)
  WRITE(ifile) dummystring
         
! ******************************************************************************
! End
! ******************************************************************************

  CALL deregisterfunction(global)

END SUBROUTINE rflu_ens_openfilescalarvector









! ******************************************************************************
!
! Purpose: Restore part number.
!
! Description: None.
!
! Input:
!   global                Pointer to global type
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

SUBROUTINE rflu_ens_restorepartnumber(global)

! ******************************************************************************
! Declarations and definitions
! ******************************************************************************

! ==============================================================================
! Arguments
! ==============================================================================

  TYPE(t_global), POINTER :: global

! ******************************************************************************
! Start
! ******************************************************************************

  global%postPartNumber = global%postPartNumberSave
         
! ******************************************************************************
! End
! ******************************************************************************

END SUBROUTINE rflu_ens_restorepartnumber







! ******************************************************************************
!
! Purpose: Store part number.
!
! Description: None.
!
! Input:
!   global                Pointer to global type
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

SUBROUTINE rflu_ens_storepartnumber(global)

! ******************************************************************************
! Declarations and definitions
! ******************************************************************************

! ==============================================================================
! Arguments
! ==============================================================================

  TYPE(t_global), POINTER :: global

! ******************************************************************************
! Start
! ******************************************************************************

  global%postPartNumberSave = global%postPartNumber 
         
! ******************************************************************************
! End
! ******************************************************************************

END SUBROUTINE rflu_ens_storepartnumber









! ******************************************************************************
!
! Purpose: Write case file.
!
! Description: None.
!
! Input:
!   global              Pointer to global data
!   iServer             Index of server
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

SUBROUTINE rflu_ens_writefilecase(global,iServer)

  USE modbuildfilenames, ONLY: buildfilenamebasic

! ******************************************************************************
! Declarations and definitions
! ******************************************************************************

! ==============================================================================
! Arguments
! ==============================================================================

  INTEGER, INTENT(IN) :: iserver
  TYPE(t_global), POINTER :: global

! ==============================================================================
! Locals
! ==============================================================================

  CHARACTER(80) :: dummystring
  CHARACTER(CHRLEN) :: ifilename
  INTEGER :: errorflag,iscalar,ivector

! ******************************************************************************
! Start
! ******************************************************************************

  CALL registerfunction(global,'RFLU_ENS_WriteFileCase', &
                        'RFLU_ModENSIGHT.F90')

! ******************************************************************************
! Write 
! ******************************************************************************

  CALL buildfilenamebasic(global,filedest_indir,'.case',iserver,ifilename)
  
  OPEN(if_ens_case,file=trim(ifilename),form="FORMATTED",status="UNKNOWN", & 
       iostat=errorflag)
  global%error = errorflag
  IF ( global%error /= err_none ) THEN 
    CALL errorstop(global,err_file_open,__line__,trim(ifilename))
  END IF ! global%error 

  WRITE(if_ens_case,'(A)') 'FORMAT'
  WRITE(if_ens_case,'(A)') 'type: ensight gold' 
  WRITE(if_ens_case,'(A)') 'GEOMETRY'
  WRITE(if_ens_case,'(A,1X,A)') 'model:',trim(geoinfo%iFileName)
  WRITE(if_ens_case,'(A)') 'VARIABLE'
        
  DO iscalar = 1,nscalars
    WRITE(if_ens_case,'(A,2(1X,A))') 'scalar per element:', & 
                                     trim(scalarinfo(iscalar)%varName), & 
                                     trim(scalarinfo(iscalar)%iFileName)    
  END DO ! iScalar
  
  DO ivector = 1,nvectors
    WRITE(if_ens_case,'(A,2(1X,A))') 'vector per element:', & 
                                     trim(vectorinfo(ivector)%varName), & 
                                     trim(vectorinfo(ivector)%iFileName)   
  END DO ! iVector         

  CLOSE(if_ens_case,iostat=errorflag)
  global%error = errorflag
  IF ( global%error /= err_none ) THEN 
    CALL errorstop(global,err_file_close,__line__,trim(ifilename))
  END IF ! global%error

! ******************************************************************************
! End
! ******************************************************************************

  CALL deregisterfunction(global)

END SUBROUTINE rflu_ens_writefilecase







! ******************************************************************************
!
! Purpose: Write solution to ENSIGHT files.
!
! Description: None.
!
! Input:
!   pRegion             Pointer to region
!   emptyPartFlagIn     Flag indicating whether part should be empty
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

SUBROUTINE rflu_ens_writeflowwrapper(pRegion,emptyPartFlagIn)

! ******************************************************************************
! Declarations and definitions
! ******************************************************************************

! ==============================================================================
! Arguments
! ==============================================================================

  LOGICAL, OPTIONAL :: emptypartflagin
  TYPE(t_region), POINTER :: pregion

! ==============================================================================
! Locals
! ==============================================================================

  LOGICAL :: emptypartflag
  CHARACTER(80) :: dummystring
  INTEGER :: errorflag,icg,icl,ifl,ipart,ipatch,ipv,iscalar,iscalaroffs,offs
  REAL(RFREAL), DIMENSION(:), POINTER :: pscalar
  REAL(RFREAL), DIMENSION(:,:), POINTER :: pvector  
  TYPE(t_global), POINTER :: global
  TYPE(t_grid), POINTER :: pgrid
  TYPE(t_patch), POINTER :: ppatch

! ******************************************************************************
! Start
! ******************************************************************************

  global => pregion%global

  CALL registerfunction(global,'RFLU_ENS_WriteFlowWrapper', &
                        'RFLU_ModENSIGHT.F90')

  IF ( global%verbLevel > verbose_none ) THEN
    WRITE(stdout,'(A,1X,A)') solver_name,'Writing solution to ENSIGHT files...'
    WRITE(stdout,'(A,3X,A,1X,I5.5)') solver_name,'Global region:', &
                                     pregion%iRegionGlobal    
  END IF ! global%verbLevel

  pgrid => pregion%grid

! ******************************************************************************
! Set emptyPartFlag if missing
! ******************************************************************************

  IF ( present(emptypartflagin) .EQV. .false. ) THEN 
    emptypartflag = .false.
  ELSE 
    emptypartflag = emptypartflagin 
  END IF ! PRESENT(emptyPartFlagIn)
  
  IF ( global%verbLevel > verbose_none ) THEN
    WRITE(stdout,'(A,3X,A,1X,L1)') solver_name,'Writing empty parts:', &
                                   emptypartflag 
  END IF ! global%verbLevel  
  
! ******************************************************************************
! Write scalars
! ******************************************************************************

! ==============================================================================
! Mixture
! ==============================================================================

! ------------------------------------------------------------------------------
! Scalars
! ------------------------------------------------------------------------------

  IF ( emptypartflag .EQV. .false. ) THEN
    pscalar => pregion%mixt%cv(cv_mixt_dens,:)
  ELSE 
    nullify(pscalar)
  END IF ! pScalar
  
  CALL rflu_ens_restorepartnumber(global)
  CALL rflu_ens_writescalar(pregion,pscalar,scalarinfo(1)%iFile,emptypartflag)
  
  
  IF ( emptypartflag .EQV. .false. ) THEN
    pscalar => pregion%mixt%cv(cv_mixt_ener,:)
  ELSE 
    nullify(pscalar)
  END IF ! pScalar

  CALL rflu_ens_restorepartnumber(global)  
  CALL rflu_ens_writescalar(pregion,pscalar,scalarinfo(2)%iFile,emptypartflag)  
  
  
  IF ( emptypartflag .EQV. .false. ) THEN
    pscalar => pregion%mixt%dv(dv_mixt_pres,:)
  ELSE 
    nullify(pscalar)
  END IF ! pScalar  
  
  CALL rflu_ens_restorepartnumber(global)  
  CALL rflu_ens_writescalar(pregion,pscalar,scalarinfo(3)%iFile,emptypartflag)  

  
  IF ( emptypartflag .EQV. .false. ) THEN
    pscalar => pregion%mixt%dv(dv_mixt_temp,:)
  ELSE 
    nullify(pscalar)
  END IF ! pScalar  
  
  CALL rflu_ens_restorepartnumber(global)  
  CALL rflu_ens_writescalar(pregion,pscalar,scalarinfo(4)%iFile,emptypartflag)  
  
  
  IF ( emptypartflag .EQV. .false. ) THEN
    pscalar => pregion%mixt%dv(dv_mixt_soun,:)
  ELSE 
    nullify(pscalar)
  END IF ! pScalar 
  
  CALL rflu_ens_restorepartnumber(global) 
  CALL rflu_ens_writescalar(pregion,pscalar,scalarinfo(5)%iFile,emptypartflag)  
  
  iscalaroffs = 5
 
! ------------------------------------------------------------------------------
! Plotting variables 
! ------------------------------------------------------------------------------

  IF ( pregion%plot%nPv > 0 ) THEN
    iscalar = 0
    
    DO ipv = 1,pregion%plot%nPv
      iscalar = iscalar+1

      IF ( emptypartflag .EQV. .false. ) THEN
        pscalar => pregion%plot%pv(ipv,:)
      ELSE 
        nullify(pscalar)
      END IF ! pScalar 
    
      CALL rflu_ens_restorepartnumber(global) 
      CALL rflu_ens_writescalar(pregion,pscalar, &
                                scalarinfo(iscalaroffs+iscalar)%iFile, & 
                                emptypartflag)  
    END DO ! iPv

    iscalaroffs = iscalaroffs + pregion%plot%nPv
  END IF ! nPv 
  
! ------------------------------------------------------------------------------
! Vectors
! ------------------------------------------------------------------------------
  
  IF ( emptypartflag .EQV. .false. ) THEN
    pvector => pregion%mixt%cv(cv_mixt_xmom:cv_mixt_zmom,:)
  ELSE 
    nullify(pvector)
  END IF ! pScalar 

  CALL rflu_ens_restorepartnumber(global)
  CALL rflu_ens_writevector(pregion,pvector,vectorinfo(1)%iFile,emptypartflag)          

! ==============================================================================
! Physical modules
! ==============================================================================

#ifdef SPEC
! ------------------------------------------------------------------------------
! Species
! ------------------------------------------------------------------------------

  IF ( global%specUsed .EQV. .true. ) THEN 
    DO iscalar = 1,pregion%specInput%nSpecies
      IF ( emptypartflag .EQV. .false. ) THEN
        pscalar => pregion%spec%cv(iscalar,:)
      ELSE 
        nullify(pscalar)
      END IF ! pScalar
      
      CALL rflu_ens_restorepartnumber(global)  
      CALL rflu_ens_writescalar(pregion,pscalar, &
                                scalarinfo(iscalar+iscalaroffs)%iFile, &
                                emptypartflag)        
    END DO ! iScalar
  END IF ! global%specUsed
#endif

! ******************************************************************************
! End
! ******************************************************************************

  IF ( global%verbLevel > verbose_none ) THEN
    WRITE(stdout,'(A,1X,A)') solver_name, & 
                             'Writing solution to ENSIGHT files done.'
  END IF ! global%verbLevel

  CALL deregisterfunction(global)

END SUBROUTINE rflu_ens_writeflowwrapper







! ******************************************************************************
!
! Purpose: Write grid to ENSIGHT geometry file.
!
! Description: None.
!
! Input:
!   pRegion                Pointer to region
!   emptyPartFlagIn     Flag indicating whether part should be empty 
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

SUBROUTINE rflu_ens_writegridwrapper(pRegion,emptyPartFlagIn)

! ******************************************************************************
! Declarations and definitions
! ******************************************************************************

! ==============================================================================
! Arguments
! ==============================================================================

  LOGICAL, OPTIONAL :: emptypartflagin
  TYPE(t_region), POINTER :: pregion

! ==============================================================================
! Locals
! ==============================================================================

  LOGICAL :: emptypartflag
  INTEGER :: errorflag
  TYPE(t_global), POINTER :: global

! ******************************************************************************
! Start
! ******************************************************************************

  global => pregion%global

  CALL registerfunction(global,'RFLU_ENS_WriteGrid', &
                        'RFLU_ModENSIGHT.F90')

  IF ( global%verbLevel > verbose_none ) THEN
    WRITE(stdout,'(A,1X,A)') solver_name, & 
                             'Writing grid to ENSIGHT geometry file...'
    WRITE(stdout,'(A,3X,A,1X,I5.5)') solver_name,'Global region:', &
                                     pregion%iRegionGlobal  
  END IF ! global%verbLevel

! ******************************************************************************
! Set emptyPartFlag if missing
! ******************************************************************************

  IF ( present(emptypartflagin) .EQV. .false. ) THEN 
    emptypartflag = .false.
  ELSE 
    emptypartflag = emptypartflagin 
  END IF ! PRESENT(emptyPartFlagIn)
  
  IF ( global%verbLevel > verbose_none ) THEN
    WRITE(stdout,'(A,3X,A,1X,L1)') solver_name,'Writing empty parts:', &
                                   emptypartflag 
  END IF ! global%verbLevel   
  
! ******************************************************************************
! Write geometry
! ******************************************************************************

  CALL rflu_ens_writegrid(pregion,emptypartflag)

! ******************************************************************************
! End
! ******************************************************************************

  IF ( global%verbLevel > verbose_none ) THEN
    WRITE(stdout,'(A,1X,A)') solver_name, & 
                             'Writing grid to ENSIGHT geometry file done.'
  END IF ! global%verbLevel

  CALL deregisterfunction(global)

END SUBROUTINE rflu_ens_writegridwrapper







END MODULE rflu_modensight

! ******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLU_ModENSIGHT.F90,v $
! Revision 1.6  2008/12/06 08:45:06  mtcampbe
! Updated license.
!
! Revision 1.5  2008/11/19 22:18:16  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.4  2007/03/19 21:42:36  haselbac
! Adapted to changes related to plotting variables
!
! Revision 1.3  2006/04/07 15:19:26  haselbac
! Removed tabs
!
! Revision 1.2  2006/01/24 21:20:38  mparmar
! Added plotting variables
!
! Revision 1.1  2005/10/05 20:23:34  haselbac
! Initial revision
!
! ******************************************************************************