RFLU_ModColoring.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
! ******************************************************************************
!
! Purpose: Suite of routines for coloring.
!
! Description: None.
!
! Notes: 
!   1. Use of overloading.
!
! ******************************************************************************
!
! $Id: RFLU_ModColoring.F90,v 1.7 2008/12/06 08:44:20 mtcampbe Exp $
!
! Copyright: (c) 2005 by the University of Illinois
!
! ******************************************************************************

MODULE rflu_modcoloring

  USE modglobal, ONLY: t_global 
  USE modparameters
  USE moddatatypes
  USE moderror
  USE moddatastruct, ONLY: t_region
  USE modgrid, ONLY: t_grid  
  USE modbndpatch, ONLY: t_patch
  USE modmpi
  
  IMPLICIT NONE

  PRIVATE
  PUBLIC :: rflu_col_buildcoloring, & 
            rflu_col_createcoloring, &
            rflu_col_destroycoloring, & 
            rflu_col_readcoloring, & 
            rflu_col_writecoloring

! ******************************************************************************
! Interface declaration for overloaded procedures
! ******************************************************************************  
        
  INTERFACE rflu_col_buildcoloring
    MODULE PROCEDURE rflu_col_buildcoloringp,rflu_col_buildcolorings
  END INTERFACE 
        
! ******************************************************************************
! Declarations and definitions
! ******************************************************************************  
   
  CHARACTER(CHRLEN) :: RCSIdentString = & 
    '$RCSfile: RFLU_ModColoring.F90,v $ $Revision: 1.7 $'        
       
! ******************************************************************************
! Routines
! ******************************************************************************

  CONTAINS
  







! ******************************************************************************
!
! Purpose: Build coloring.
!
! Description: None.
!
! Input:
!   pRegion             Pointer to region
!   pRegionSerial       Pointer to serial region
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

SUBROUTINE rflu_col_buildcoloringp(pRegion,pRegionSerial)

  USE rflu_modcopydata, ONLY: rflu_copy_celldatas2p_i1d

  IMPLICIT NONE

! ******************************************************************************
! Declarations and definitions
! ******************************************************************************

! ==============================================================================
! Arguments
! ==============================================================================

  TYPE(t_region), POINTER :: pregion,pregionserial

! ==============================================================================
! Locals
! ==============================================================================

  TYPE(t_global), POINTER :: global
  TYPE(t_grid), POINTER :: pgrid

! ******************************************************************************
! Start
! ******************************************************************************

  global => pregion%global

  CALL registerfunction(global,'RFLU_COL_BuildColoringP', &
                        'RFLU_ModColoring.F90')

  pgrid => pregion%grid

! ******************************************************************************
! Copy coloring
! ******************************************************************************

  CALL rflu_copy_celldatas2p_i1d(global,pgrid,pgrid%col,pregionserial%grid%col)
  
! ******************************************************************************
! End
! ******************************************************************************

  CALL deregisterfunction(global)

END SUBROUTINE rflu_col_buildcoloringp








! ******************************************************************************
!
! Purpose: Build coloring.
!
! Description: None.
!
! Input:
!   pRegion     Pointer to region
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

SUBROUTINE rflu_col_buildcolorings(pRegion)

  USE rflu_modresidual, ONLY: rflu_getresidualsupport1, & 
                              rflu_getresidualsupport2

  USE modsortsearch

  IMPLICIT NONE

! ******************************************************************************
! Declarations and definitions
! ******************************************************************************

! ==============================================================================
! Arguments
! ==============================================================================

  TYPE(t_region), POINTER :: pregion

! ==============================================================================
! Locals
! ==============================================================================

  LOGICAL :: neednewcolor
  INTEGER :: cntr,errorflag,icg,icg2,icl,iloc,isoc,ncellmembsmin,nsocmax, & 
             offs,rssize,rssizemax
  INTEGER, DIMENSION(:), ALLOCATABLE :: cellmembstemp,rs
  TYPE(t_global), POINTER :: global
  TYPE(t_grid), POINTER :: pgrid


! ******************************************************************************
! Start
! ******************************************************************************

  global => pregion%global

  CALL registerfunction(global,'RFLU_COL_BuildColoringS', &
                        'RFLU_ModColoring.F90')

  IF ( global%myProcid == masterproc .AND. & 
       global%verbLevel > verbose_none ) THEN
    WRITE(stdout,'(A,1X,A)') solver_name,'Building coloring...' 
  END IF ! global%myProcid

  pgrid => pregion%grid

! ******************************************************************************
! Initialize
! ******************************************************************************

  rssizemax     = 10000 ! Maximum allowed size of residual support
  nsocmax       =  2048 ! Maximum allowed number of struct orthog columns
  ncellmembsmin =   100 ! Minimum number of cell members

  pgrid%nSoc    = 0
  pgrid%nSocMax = nsocmax
 
! ******************************************************************************
! Allocate temporary memory
! ******************************************************************************

  ALLOCATE(rs(rssizemax),stat=errorflag)
  global%error = errorflag
  IF ( global%error /= err_none ) THEN 
    CALL errorstop(global,err_allocate,__line__,'rs')
  END IF ! global%errorFlag  

  ALLOCATE(pgrid%soc(pgrid%nSocMax),stat=errorflag)
  global%error = errorflag
  IF ( global%error /= err_none ) THEN
    CALL errorstop(global,err_allocate,__line__,'pGrid%soc')
  END IF ! global%error

  DO isoc = 1,nsocmax
    ALLOCATE(pgrid%soc(isoc)%cellMembs(ncellmembsmin),stat=errorflag)
    IF ( global%error /= err_none ) THEN
      CALL errorstop(global,err_allocate,__line__,'pGrid%soc%cellMembs')
    END IF ! global%error
  END DO ! iSoc

! ******************************************************************************
! Loop over cells
! ******************************************************************************

  DO icg = 1,pgrid%nCells

! ==============================================================================
!   Get stencil members and sort
! ==============================================================================

    SELECT CASE ( pregion%mixtInput%spaceOrder )
      CASE ( 1 ) 
        CALL rflu_getresidualsupport1(pregion,icg,rs,rssizemax,rssize)
      CASE ( 2 ) 
! TEMPORARY
!        CALL RFLU_GetResidualSupport2(pRegion,icg,rs,rsSizeMax,rsSize)
        CALL rflu_getresidualsupport1(pregion,icg,rs,rssizemax,rssize)
! END TEMPORARY
      CASE default 
        CALL errorstop(global,err_reached_default,__line__)
    END SELECT ! pRegion%mixtInput%spaceOrder
                 
! ==============================================================================
!   Loop over colors
! ==============================================================================

    neednewcolor = .true.

    colorloop: DO isoc = 1,pgrid%nSoc
      
! ------------------------------------------------------------------------------
!     Determine whether stencil members already in this color
! ------------------------------------------------------------------------------      
      
      cntr = 0
      
      neednewcolor = .false.
      
      rsloop: DO icl = 1,rssize
        icg2 = rs(icl)

        IF ( pgrid%soc(isoc)%nCellMembs > 0 ) THEN
          CALL binarysearchinteger(pgrid%soc(isoc)%cellMembs(1:pgrid%soc(isoc)%nCellMembs), & 
                                   pgrid%soc(isoc)%nCellMembs,icg2,iloc)
        ELSE 
          iloc = element_not_found
        END IF ! pGrid%soc%nCellMembs

        IF ( iloc == element_not_found ) THEN 
          cntr = cntr + 1
        ELSE
          IF ( isoc /= pgrid%nSoc ) THEN
            EXIT rsloop
          ELSE 
            neednewcolor = .true.
            
            EXIT colorloop
          END IF ! iSoc           
        END IF ! iLoc                         
      END DO rsloop
     
! ------------------------------------------------------------------------------
!     Add to this color if none of the stencil members already present
! ------------------------------------------------------------------------------      
           
      IF ( (neednewcolor .EQV. .false.) .AND. (cntr == rssize) ) THEN
        offs = pgrid%soc(isoc)%nCellMembs
       
! ----- Array too small, so reallocate -----------------------------------------       
       
        IF ( (pgrid%soc(isoc)%nCellMembs + rssize) > SIZE(pgrid%soc(isoc)%cellMembs,1) ) THEN  
          ALLOCATE(cellmembstemp(pgrid%soc(isoc)%nCellMembs),stat=errorflag)
          global%error = errorflag
          IF ( global%error /= err_none ) THEN 
            CALL errorstop(global,err_allocate,__line__,'cellMembsTemp')
          END IF !global%error
       
          DO icl = 1,pgrid%soc(isoc)%nCellMembs
            cellmembstemp(icl) = pgrid%soc(isoc)%cellMembs(icl)
          END DO ! icl
       
          DEALLOCATE(pgrid%soc(isoc)%cellMembs,stat=errorflag)
          global%error = errorflag
          IF ( global%error /= err_none ) THEN 
            CALL errorstop(global,err_deallocate,__line__,'pGrid%soc%cellMembs')
          END IF !global%error          
       
          ncellmembsmin = 2*(pgrid%soc(isoc)%nCellMembs + rssize)
       
          ALLOCATE(pgrid%soc(isoc)%cellMembs(ncellmembsmin),stat=errorflag)
          global%error = errorflag
          IF ( global%error /= err_none ) THEN 
            CALL errorstop(global,err_deallocate,__line__,'pGrid%soc%cellMembs')
          END IF !global%error        
       
          DO icl = 1,pgrid%soc(isoc)%nCellMembs
            pgrid%soc(isoc)%cellMembs(icl) = cellmembstemp(icl)
          END DO ! icl       
       
          DEALLOCATE(cellmembstemp,stat=errorflag)
          global%error = errorflag
          IF ( global%error /= err_none ) THEN 
            CALL errorstop(global,err_deallocate,__line__,'cellMembsTemp')
          END IF !global%error       
        END IF ! pGrid%soc%nCellMembs
                
! ----- Add stencil members and sort -------------------------------------------                
        
        pgrid%col(icg) = isoc
        
        DO icl = 1,rssize
          pgrid%soc(isoc)%cellMembs(offs+icl) = rs(icl)
        END DO ! icl
        
        pgrid%soc(isoc)%nCellMembs = pgrid%soc(isoc)%nCellMembs + rssize
        
        CALL quicksortinteger(pgrid%soc(isoc)%cellMembs(1:pgrid%soc(isoc)%nCellMembs), & 
                              pgrid%soc(isoc)%nCellMembs)     
                              
        EXIT colorloop                        
      END IF ! needNewColor      
    END DO colorloop

! ==============================================================================
!   Add new color
! ==============================================================================

    IF ( neednewcolor .EQV. .true. ) THEN
      IF ( pgrid%nSoc < pgrid%nSocMax ) THEN  
        pgrid%nSoc = pgrid%nSoc + 1
      ELSE 
! TEMPORARY
        WRITE(*,*) 'ERROR! About to exceed dimensions of soc!'
        stop
! END TEMPORARY      
      END IF ! nSoc

      pgrid%col(icg) = pgrid%nSoc
      
      IF ( rssize > SIZE(pgrid%soc(pgrid%nSoc)%cellMembs,1) ) THEN
        DEALLOCATE(pgrid%soc(pgrid%nSoc)%cellMembs,stat=errorflag)
        global%error = errorflag
        IF ( global%error /= err_none ) THEN 
          CALL errorstop(global,err_deallocate,__line__,'pGrid%soc%cellMembs')
        END IF ! global%error

        ALLOCATE(pgrid%soc(pgrid%nSoc)%cellMembs(2*rssize),stat=errorflag)
        global%error = errorflag
        IF ( global%error /= err_none ) THEN 
          CALL errorstop(global,err_allocate,__line__,'pGrid%soc%cellMembs')
        END IF ! global%error
      END IF ! rsSize

      DO icl = 1,rssize
        pgrid%soc(pgrid%nSoc)%cellMembs(icl) = rs(icl)
      END DO ! icl   
      
      pgrid%soc(pgrid%nSoc)%nCellMembs = rssize
      
      CALL quicksortinteger(pgrid%soc(pgrid%nSoc)%cellMembs(1:pgrid%soc(pgrid%nSoc)%nCellMembs), & 
                            pgrid%soc(pgrid%nSoc)%nCellMembs)         
    END IF ! needNewColor
  END DO ! icg

  IF ( global%myProcid == masterproc .AND. & 
       global%verbLevel > verbose_none ) THEN
    WRITE(stdout,'(A,3X,A,1X,I6)') solver_name,'Number of colors:',pgrid%nSoc
  END IF ! global%myProcid

! ******************************************************************************
! Deallocate temporary memory
! ******************************************************************************
  
  DEALLOCATE(rs,stat=errorflag)
  global%error = errorflag
  IF ( global%error /= err_none ) THEN 
    CALL errorstop(global,err_deallocate,__line__,'rs')
  END IF ! global%errorFlag
  
  DO isoc = 1,pgrid%nSocMax
    DEALLOCATE(pgrid%soc(isoc)%cellMembs,stat=errorflag)
    IF ( global%error /= err_none ) THEN
      CALL errorstop(global,err_deallocate,__line__,'pGrid%soc%cellMembs')
    END IF ! global%error
  END DO ! iSoc

  DEALLOCATE(pgrid%soc,stat=errorflag)
  global%error = errorflag
  IF ( global%error /= err_none ) THEN
    CALL errorstop(global,err_deallocate,__line__,'pGrid%soc')
  END IF ! global%error

  pgrid%nSoc    = 0
  pgrid%nSocMax = 0  
  
! ******************************************************************************
! End
! ******************************************************************************

  IF ( global%myProcid == masterproc .AND. & 
       global%verbLevel > verbose_none ) THEN
    WRITE(stdout,'(A,1X,A)') solver_name,'Building coloring done.' 
  END IF ! global%myProcid

  CALL deregisterfunction(global)

END SUBROUTINE rflu_col_buildcolorings






! ******************************************************************************
!
! Purpose: Create coloring.
!
! Description: None.
!
! Input:
!   pRegion     Pointer to region
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

SUBROUTINE rflu_col_createcoloring(pRegion)

  IMPLICIT NONE

! ******************************************************************************
! Declarations and definitions
! ******************************************************************************

! ==============================================================================
! Arguments
! ==============================================================================

  TYPE(t_region), POINTER :: pregion

! ==============================================================================
! Locals
! ==============================================================================

  INTEGER :: errorflag
  TYPE(t_global), POINTER :: global
  TYPE(t_grid), POINTER :: pgrid

! ******************************************************************************
! Start
! ******************************************************************************

  global => pregion%global

  CALL registerfunction(global,'RFLU_COL_CreateColoring', &
                        'RFLU_ModColoring.F90')

  pgrid => pregion%grid

! ******************************************************************************
! Allocate memory
! ******************************************************************************

  ALLOCATE(pgrid%col(pgrid%nCellsTot),stat=errorflag)
  global%error = errorflag
  IF ( global%error /= err_none ) THEN
    CALL errorstop(global,err_allocate,__line__,'pGrid%col')
  END IF ! global%error

! ******************************************************************************
! End
! ******************************************************************************

  CALL deregisterfunction(global)

END SUBROUTINE rflu_col_createcoloring








! ******************************************************************************
!
! Purpose: Destroy coloring.
!
! Description: None.
!
! Input:
!   pRegion     Pointer to region
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

SUBROUTINE rflu_col_destroycoloring(pRegion)

  IMPLICIT NONE

! ******************************************************************************
! Declarations and definitions
! ******************************************************************************

! ==============================================================================
! Arguments
! ==============================================================================

  TYPE(t_region), POINTER :: pregion

! ==============================================================================
! Locals
! ==============================================================================

  INTEGER :: errorflag
  TYPE(t_global), POINTER :: global
  TYPE(t_grid), POINTER :: pgrid

! ******************************************************************************
! Start
! ******************************************************************************

  global => pregion%global

  CALL registerfunction(global,'RFLU_COL_DestroyColoring', &
                        'RFLU_ModColoring.F90')

  pgrid => pregion%grid

! ******************************************************************************
! Destroy memory
! ******************************************************************************

  DEALLOCATE(pgrid%col,stat=errorflag)
  global%error = errorflag
  IF ( global%error /= err_none ) THEN
    CALL errorstop(global,err_deallocate,__line__,'pGrid%col')
  END IF ! global%error

! ******************************************************************************
! End
! ******************************************************************************

  CALL deregisterfunction(global)

END SUBROUTINE rflu_col_destroycoloring








! ******************************************************************************
!
! Purpose: Read coloring.
!
! Description: None.
!
! Input:
!   pRegion     Pointer to region
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

  SUBROUTINE rflu_col_readcoloring(pRegion)

    USE modbuildfilenames, ONLY: buildfilenamebasic

    IMPLICIT NONE
  
! ******************************************************************************
!   Declarations and definitions
! ******************************************************************************  

! ==============================================================================
!   Arguments
! ==============================================================================

    TYPE(t_region), POINTER :: pregion  
   
! ==============================================================================
!   Local variables
! ==============================================================================

    INTEGER :: errorflag,icg,ifile,loopcounter,ncellstot
    CHARACTER(CHRLEN) :: ifilename,sectionstring
    TYPE(t_grid), POINTER :: pgrid  
    TYPE(t_global), POINTER :: global
    
! ******************************************************************************
!   Start
! ******************************************************************************

    global => pregion%global

    CALL registerfunction(global,'RFLU_COL_ReadColoring',&
  'RFLU_ModColoring.F90')

    IF ( global%myProcid == masterproc .AND. & 
         global%verbLevel > verbose_none ) THEN
      WRITE(stdout,'(A,1X,A)') solver_name,'Reading coloring...' 
    END IF ! global%myProcid

    IF ( global%myProcid == masterproc .AND. & 
         global%verbLevel > verbose_none ) THEN     
      WRITE(stdout,'(A,3X,A,1X,I5.5)') solver_name,'Global region:', & 
                                       pregion%iRegionGlobal          
    END IF ! global%myProcid

! ==============================================================================
!   Open file
! ==============================================================================

    ifile = if_rnmb

    CALL buildfilenamebasic(global,filedest_indir,'.col', & 
                            pregion%iRegionGlobal,ifilename) 

    OPEN(ifile,file=ifilename,form="FORMATTED",status="OLD",iostat=errorflag)   
    global%error = errorflag        
    IF ( global%error /= err_none ) THEN 
      CALL errorstop(global,err_file_open,__line__,ifilename)
    END IF ! global%error

! ==============================================================================
!   Header and general information
! ==============================================================================

    IF ( global%myProcid == masterproc .AND. & 
         global%verbLevel > verbose_low ) THEN
      WRITE(stdout,'(A,3X,A)') solver_name,'Header information...'
    END IF ! global%myProcid

    READ(ifile,'(A)') sectionstring 
    IF ( trim(sectionstring) /= '# ROCFLU coloring file' ) THEN 
      CALL errorstop(global,err_invalid_marker,__line__,sectionstring) 
    END IF ! TRIM

! ==============================================================================
!   Dimensions
! ==============================================================================
  
    pgrid => pregion%grid  

    READ(ifile,'(A)') sectionstring 
    IF ( trim(sectionstring) /= '# Dimensions' ) THEN 
      CALL errorstop(global,err_invalid_marker,__line__,sectionstring)
    END IF ! TRIM

    READ(ifile,'(I8)') ncellstot

! ==============================================================================
!   Check dimensions (against those read from dimensions file)
! ==============================================================================

    IF ( ncellstot /= pgrid%nCellsTot ) THEN 
      CALL errorstop(global,err_dimens_invalid,__line__)
    END IF ! nCellsTot    
    
! ==============================================================================
!   Rest of file
! ==============================================================================

    loopcounter = 0

    DO ! set up infinite loop
      loopcounter = loopcounter + 1
    
      READ(ifile,'(A)') sectionstring
    
      SELECT CASE ( trim(sectionstring) ) 

! ------------------------------------------------------------------------------
!       Vertex renumbering
! ------------------------------------------------------------------------------

        CASE ( '# Coloring' ) 
          IF ( global%myProcid == masterproc .AND. & 
               global%verbLevel > verbose_low ) THEN
            WRITE(stdout,'(A,3X,A)') solver_name,'Coloring...'
          END IF ! global%myProcid 
              
          READ(ifile,'(10(I8))') (pgrid%col(icg),icg=1,pgrid%nCellsTot)
    
! ------------------------------------------------------------------------------
!       End marker
! ------------------------------------------------------------------------------ 
      
        CASE ( '# End' ) 
          IF ( global%myProcid == masterproc .AND. & 
               global%verbLevel > verbose_low ) THEN
            WRITE(stdout,'(A,3X,A)') solver_name,'End marker...'
          END IF ! global%myProcid  

          EXIT
      
! ------------------------------------------------------------------------------
!       Invalid section string
! ------------------------------------------------------------------------------ 
      
        CASE default
          IF ( global%myProcid == masterproc .AND. & 
               global%verbLevel > verbose_low ) THEN
            WRITE(stdout,'(3X,A)') sectionstring
          END IF ! global%myProcid      

          CALL errorstop(global,err_invalid_marker,__line__,sectionstring)
      END SELECT ! TRIM
  
! ==============================================================================
!     Guard against infinite loop - might be unnecessary because of read errors?
! ==============================================================================  

      IF ( loopcounter >= limit_infinite_loop ) THEN 
        CALL errorstop(global,err_infinite_loop,__line__)
      END IF ! loopCounter  
    END DO ! <empty>
   
! ==============================================================================
!   Close file
! ==============================================================================

    CLOSE(ifile,iostat=errorflag)
    global%error = errorflag      
    IF ( global%error /= err_none ) THEN 
      CALL errorstop(global,err_file_close,__line__,ifilename)
    END IF ! global%error

! ******************************************************************************
!   End
! ******************************************************************************

    IF ( global%myProcid == masterproc .AND. & 
         global%verbLevel > verbose_none ) THEN
      WRITE(stdout,'(A,1X,A)') solver_name,'Reading coloring done.' 
    END IF ! global%myProcid

    CALL deregisterfunction(global)
  
  END SUBROUTINE rflu_col_readcoloring








! ******************************************************************************
!
! Purpose: Recreate cell list.
!
! Description: None.
!
! Input:
!   global              Pointer to global data
!   nVertPerCell        Number of vertices per cell
!   nCellsMax           Maximum number of cells
!   x2v                 Connectivity array
!   x2cg                Cell mapping array
!
! Output: 
!   nCellsMax           Increased maximum number of cells
!   x2v                 Enlarged connectivity array
!   x2cg                Enlarged cell mapping array
!
! Notes: None.
!
! ******************************************************************************

  SUBROUTINE rflu_col_recreatecelllist(global,nVertPerCell,nCellsMax,x2v,x2cg)

    IMPLICIT NONE
      
! ******************************************************************************
!   Declarations and definitions
! ******************************************************************************

! ==============================================================================
!   Arguments
! ==============================================================================

    INTEGER, INTENT(IN) :: nvertpercell
    INTEGER, INTENT(INOUT) :: ncellsmax
    INTEGER, DIMENSION(:), POINTER :: x2cg
    INTEGER, DIMENSION(:,:), POINTER :: x2v
    TYPE(t_global), POINTER :: global

! ==============================================================================
!   Locals
! ==============================================================================

    INTEGER :: errorflag,icl,ivl,ncellsmaxold    
    INTEGER, DIMENSION(:), ALLOCATABLE:: x2cgtemp
    INTEGER, DIMENSION(:,:), ALLOCATABLE :: x2vtemp      

! ******************************************************************************
!   Start
! ******************************************************************************

    CALL registerfunction(global,'RFLU_COL_RecreateCellList',&
  'RFLU_ModColoring.F90')

! ******************************************************************************
!   Increase maximum number of cells
! ******************************************************************************

    ncellsmaxold =   ncellsmax 
    ncellsmax    = 2*ncellsmax

! ******************************************************************************
!   Copy existing arrays into larger arrays
! ******************************************************************************

! ==============================================================================
!   Connectivity array
! ==============================================================================

    ALLOCATE(x2vtemp(nvertpercell,ncellsmaxold),stat=errorflag)
    global%error = errorflag
    IF ( global%error /= err_none ) THEN 
      CALL errorstop(global,err_allocate,__line__,'x2vTemp')
    END IF ! global%error
          
    DO icl = 1,ncellsmaxold
      DO ivl = 1,nvertpercell
        x2vtemp(ivl,icl) = x2v(ivl,icl)
      END DO ! ivl
    END DO ! icl

    DEALLOCATE(x2v,stat=errorflag)
    global%error = errorflag
    IF ( global%error /= err_none ) THEN 
      CALL errorstop(global,err_deallocate,__line__,'x2v')
    END IF ! global%error

    ALLOCATE(x2v(nvertpercell,ncellsmax),stat=errorflag)
    global%error = errorflag
    IF ( global%error /= err_none ) THEN 
      CALL errorstop(global,err_allocate,__line__,'x2v')
    END IF ! global%error

    DO icl = 1,ncellsmaxold
      DO ivl = 1,nvertpercell
        x2v(ivl,icl) = x2vtemp(ivl,icl)
      END DO ! ivl
    END DO ! icl    

    DEALLOCATE(x2vtemp,stat=errorflag)
    global%error = errorflag
    IF ( global%error /= err_none ) THEN 
      CALL errorstop(global,err_deallocate,__line__,'x2vTemp')
    END IF ! global%error

! ==============================================================================
!   Cell mapping array
! ==============================================================================

    ALLOCATE(x2cgtemp(ncellsmaxold),stat=errorflag)
    global%error = errorflag
    IF ( global%error /= err_none ) THEN 
      CALL errorstop(global,err_allocate,__line__,'x2cgTemp')
    END IF ! global%error
          
    DO icl = 1,ncellsmaxold
      x2cgtemp(icl) = x2cg(icl)
    END DO ! icl

    DEALLOCATE(x2cg,stat=errorflag)
    global%error = errorflag
    IF ( global%error /= err_none ) THEN 
      CALL errorstop(global,err_deallocate,__line__,'x2cg')
    END IF ! global%error

    ALLOCATE(x2cg(ncellsmax),stat=errorflag)
    global%error = errorflag
    IF ( global%error /= err_none ) THEN 
      CALL errorstop(global,err_allocate,__line__,'x2cg')
    END IF ! global%error

    DO icl = 1,ncellsmaxold
      x2cg(icl) = x2cgtemp(icl)
    END DO ! icl    

    DEALLOCATE(x2cgtemp,stat=errorflag)
    global%error = errorflag
    IF ( global%error /= err_none ) THEN 
      CALL errorstop(global,err_deallocate,__line__,'x2cgTemp')
    END IF ! global%error

! ******************************************************************************
!   End
! ******************************************************************************

    CALL deregisterfunction(global)

  END SUBROUTINE rflu_col_recreatecelllist








! ******************************************************************************
!
! Purpose: Write coloring.
!
! Description: None.
!
! Input:
!   pRegion     Pointer to region
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

  SUBROUTINE rflu_col_writecoloring(pRegion)

    USE modbuildfilenames, ONLY: buildfilenamebasic

    IMPLICIT NONE
  
! ******************************************************************************
!   Declarations and definitions
! ******************************************************************************  

! ==============================================================================
!   Arguments
! ==============================================================================

    TYPE(t_region), POINTER :: pregion  
   
! ==============================================================================
!   Local variables
! ==============================================================================

    INTEGER :: errorflag,icg,ifile
    CHARACTER(CHRLEN) :: ifilename,sectionstring
    TYPE(t_grid), POINTER :: pgrid  
    TYPE(t_global), POINTER :: global
    
! ******************************************************************************
!   Start
! ******************************************************************************

    global => pregion%global

    CALL registerfunction(global,'RFLU_COL_WriteColoring',&
  'RFLU_ModColoring.F90')

    IF ( global%myProcid == masterproc .AND. & 
         global%verbLevel > verbose_none ) THEN
      WRITE(stdout,'(A,1X,A)') solver_name,'Writing coloring...'
    END IF ! global%myProcid

    IF ( global%myProcid == masterproc .AND. & 
         global%verbLevel > verbose_none ) THEN   
      WRITE(stdout,'(A,3X,A,1X,I5.5)') solver_name,'Global region:', & 
                                       pregion%iRegionGlobal          
    END IF ! global%myProcid 

! ==============================================================================
!   Open file
! ==============================================================================

    ifile = if_color

    CALL buildfilenamebasic(global,filedest_indir,'.col', & 
                            pregion%iRegionGlobal,ifilename) 

    OPEN(ifile,file=ifilename,form="FORMATTED",status="UNKNOWN", & 
         iostat=errorflag)   
    global%error = errorflag        
    IF ( global%error /= err_none ) THEN 
      CALL errorstop(global,err_file_open,__line__,ifilename)
    END IF ! global%error

! ==============================================================================
!   Header and general information
! ==============================================================================

    IF ( global%myProcid == masterproc .AND. & 
         global%verbLevel > verbose_low ) THEN   
      WRITE(stdout,'(A,3X,A)') solver_name,'Header information...'
    END IF ! global%myProcid

    sectionstring = '# ROCFLU coloring file'  
    WRITE(ifile,'(A)') trim(sectionstring)  

! ==============================================================================
!   Dimensions
! ==============================================================================
  
    pgrid => pregion%grid  

    IF ( global%myProcid == masterproc .AND. & 
         global%verbLevel > verbose_low ) THEN   
      WRITE(stdout,'(A,3X,A)') solver_name,'Dimensions...'
    END IF ! global%myProcid

    sectionstring = '# Dimensions'
    WRITE(ifile,'(A)') trim(sectionstring) 
    WRITE(ifile,'(I8)') pgrid%nCellsTot

! ==============================================================================
!   Coloring
! ==============================================================================

    IF ( global%myProcid == masterproc .AND. & 
         global%verbLevel > verbose_low ) THEN   
      WRITE(stdout,'(A,3X,A)') solver_name,'Cells...'
    END IF ! global%myProcid

    sectionstring = '# Coloring'  
    WRITE(ifile,'(A)') trim(sectionstring)      
    WRITE(ifile,'(10(I8))') (pgrid%col(icg),icg=1,pgrid%nCellsTot)    
   
! ==============================================================================
!   End marker
! ==============================================================================

    IF ( global%myProcid == masterproc .AND. & 
         global%verbLevel > verbose_low ) THEN 
      WRITE(stdout,'(A,3X,A)') solver_name,'End marker...'
    END IF ! global%myProcid

    sectionstring = '# End'
    WRITE(ifile,'(A)') trim(sectionstring) 

! ==============================================================================
!   Close file
! ==============================================================================

    CLOSE(ifile,iostat=errorflag)
    global%error = errorflag      
    IF ( global%error /= err_none ) THEN 
      CALL errorstop(global,err_file_close,__line__,ifilename)
    END IF ! global%error

! ******************************************************************************
!   End
! ******************************************************************************

    IF ( global%myProcid == masterproc .AND. & 
         global%verbLevel > verbose_none ) THEN
      WRITE(stdout,'(A,1X,A)') solver_name,'Writing coloring done.'
    END IF ! global%myProcid

    CALL deregisterfunction(global)
  
  END SUBROUTINE rflu_col_writecoloring








! ******************************************************************************
! End
! ******************************************************************************
  
END MODULE rflu_modcoloring

! ******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLU_ModColoring.F90,v $
! Revision 1.7  2008/12/06 08:44:20  mtcampbe
! Updated license.
!
! Revision 1.6  2008/11/19 22:17:31  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.5  2006/04/07 15:19:18  haselbac
! Removed tabs
!
! Revision 1.4  2005/09/22 17:10:31  hdewey2
! Modified coloring so the Jacobian is always colored based on the 1st order cell stencil.
!
! Revision 1.3  2005/08/24 01:36:15  haselbac
! Fixed bug and extended to second-order
!
! Revision 1.2  2005/08/19 02:35:26  haselbac
! Changed for cColors to col, modified existing and added I/O routines
!
! Revision 1.1  2005/08/17 20:04:52  hdewey2
! Initial revision
!
! ******************************************************************************